Вставьте и распечатайте канцтовары

Question

Я пытаюсь сделать это в течение нескольких часов, но я не могу понять, как получить изображение в качестве бланка в моем фоне в Excel 2010. Кажется, что во всех отношениях я просто не могу получить его распространение изверхний левый нижний правый угол.

Могу ли я сделать это с помощью макроса, или есть другой способ сделать это?

Answer 1

Этот фрагмент кода позволит вам выбрать изображение (вы уже можете иметь его и адаптировать этот код), он изменит размер изображения, чтобы он соответствовал принтере, и выровнял его по левому верхнему углу принтаре:

Option Explicit

Private Sub Test()
    Dim PicLocation As String
    Dim MyRange As Range, TargetCell As Range

    Set MyRange = Range(ActiveSheet.PageSetup.PrintArea)
    Set TargetCell = MyRange.Cells(1, 1)

    PicLocation = Application.GetSaveAsFilename("C:\", "Image Files (*.jpg),*.jpg", , "Specify Image Location")

    If PicLocation <> "False" Then
        ActiveSheet.Pictures.Insert(PicLocation).Select
    Else
        Exit Sub
    End If

    With Selection.ShapeRange
        .LockAspectRatio = msoTrue
        If .Width > .Height Then
            .Width = MyRange.Width
            If .Height > MyRange.Height Then .Height = MyRange.Height + ActiveSheet.PageSetup.HeaderMargin + ActiveSheet.PageSetup.BottomMargin
        Else
            .Height = MyRange.Height
            If .Width > MyRange.Width Then .Width = MyRange.Width + ActiveSheet.PageSetup.LeftMargin + ActiveSheet.PageSetup.RightMargin
        End If
        .Left = TargetCell.Left - ActiveSheet.PageSetup.LeftMargin
        .Top = TargetCell.Top - ActiveSheet.PageSetup.HeaderMargin
    End With

    With Selection
        .Placement = xlMoveAndSize
        .PrintObject = True
    End With
End Sub

Answer 2

См. Ссылку microsoft

Цитировать
"В Excel можно использовать изображение в качестве фона листа только для отображения. Фон листа не печатается и не сохраняется на отдельном листе или в элементе, который вы сохраняете как веб-страницу. Он сохраняется только когда вы публикуете всю книгу как веб-страницу.
Важно! Поскольку фон листа не печатается, его нельзя использовать в качестве водяного знака. Однако вы можете имитировать водяной знак, вставляя изображение в верхний или нижний колонтитул. "