Удалите ненужные теги с помощью XSL

Question

У меня есть какое-то неизвестное содержимое, появляющееся как описание, может быть, что-то вроде этого:

<description>
  <p>
    <span>
      <font>Hello</font>
    </span>
    World! 
    <a href="/index">Home</a>
  </p>
</description>

Возможен любой тег HTMLЯ не хочу все теги.Я хочу разрешить теги p, i, em, strong, b, ol, ul, li и a.Так, например, будет удален, но и останутся.Я предполагаю, что должен соответствовать тем, которые хочу (и убедиться, что нет ничего, что соответствует другим), но не могу понять, как это сделать.

Любая помощь?

Answer 1

Белый список эти элементы:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="*[not(self::description or self::p or self::i or 
                               self::em or self::strong or self::b or 
                               self::ol or self::ul or self::li or self::a)]"/>
</xsl:stylesheet>

Обратите внимание, что при этом удаляются нежелательные элементы и все, что находится под ними. Например, чтобы просто удалить сам элемент font, но разрешить его дочерние элементы, измените последний шаблон следующим образом:

<xsl:template match="*[not(self::description or self::p or self::i or 
                           self::em or self::strong or self::b or 
                           self::ol or self::ul or self::li or self::a)]"/>
    <xsl:apply-templates/>
</xsl:template>

Эквивалентное (и немного более чистое) решение:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:template match="@*|node()" priority="-3">
        <xsl:copy/>
    </xsl:template>
    <xsl:template match="description|p|i|em|strong|b|ol|ul|li|a">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="*"/>
</xsl:stylesheet>

Противоположный подход - черный список нежелательных элементов:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="font|span"/>
</xsl:stylesheet>

Опять же, добавьте apply-templates в окончательный шаблон, если вы хотите разрешить дочерние элементы пропущенных элементов.