Ошибка OpenOffice при экспорте из Calc с использованием фильтров xslt - PullRequest
Новая
       16

Ошибка OpenOffice при экспорте из Calc с использованием фильтров xslt

1 голос
/ 30 апреля 2011

У меня есть данные на основе строк в Calc, которые я хочу экспортировать в xml, используя фильтры xslt.Фильтры работают правильно, за исключением случаев, когда значения в двух смежных столбцах совпадают.Например, см. Данные ниже ... 

SrNo      Col2      Col3      Col4      Col5
1         PQR       123       567       LMN
2         OPQ       665       786       BCD
3         EUR       443       443       UFF
4         OLE       345       887       JAS
5         EJR       565       565       OEP

Для приведенных выше данных эта ошибка возникает только для строк 3 и 5. По какой-то причине фильтр пропускает col4 и принимает значение из col5.Для остальных данных экспорт работает отлично.Вот код xslt ... 

<row>
<col1><xsl:value-of select="table:table-cell[1]"/></col1>
<col2><xsl:value-of select="table:table-cell[2]"/></col2>
<col3><xsl:value-of select="table:table-cell[3]"/></col3>
<col4><xsl:value-of select="table:table-cell[4]"/></col4>
<col5><xsl:value-of select="table:table-cell[5]"/></col5>
</row>

Может кто-нибудь дать какие-либо комментарии по этому поводу?Это довольно странно, и я сильно застрял из-за этого.Кстати, я использую OpenOffice 3.1.1 (сборка 9420) с xslt 2.0.

Ответы [ 3 ]

2 голосов
/ 24 июля 2012

Это был отличный код Rohit;это определенно помогло направить меня в правильном направлении.Мне было трудно заставить работать код XSLT 2.0 в моей установке LibreOffice, поэтому я преобразовал код в XSLT 1.0 (именованные шаблоны вместо вызовов функций и расширение, позволяющее передавать узел в рекурсивную функцию).Если кому-то это нужно, мой код приведен ниже.Обратите внимание, что это не код общего назначения - вам нужно заменить мои поля своими собственными.

В этом конкретном примере таблица экспортируется в действительный файл .plist, который распознается XCode.Он был протестирован с LibreOffice 3.5, работающим в Vista. 

<?xml version="1.0" encoding="UTF-8"?>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0"
    xmlns:xt="http://www.jclark.com/xt"
    extension-element-prefixes="xt"
    xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0"
    xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0"
    exclude-result-prefixes="office table text">

    <!--xsl:output method = "xml" indent = "yes" encoding = "UTF-8" omit-xml-declaration = "no"/-->
    <xsl:output method = "xml" indent = "yes" encoding = "UTF-8" omit-xml-declaration = "no" doctype-system = "http://www.apple.com/DTDs/PropertyList-1.0.dtd" doctype-public = "-//Apple//DTD PLIST 1.0//EN" />

    <xsl:template name="getColumnValue">
        <xsl:param name="tableRow"/>
        <xsl:param name="colIndex"/>
        <xsl:param name="currentIndex"/>
        <xsl:choose>
            <xsl:when test="$currentIndex &lt; $colIndex">
                <xsl:variable name="repeatColumns" select="xt:node-set($tableRow)/table:table-cell[$currentIndex]/@table:number-columns-repeated"/>
                <xsl:choose>
                    <xsl:when test="$repeatColumns">
                        <xsl:choose>
                            <xsl:when test="$currentIndex + $repeatColumns - 1 &gt;= $colIndex">
                                <xsl:value-of select="xt:node-set($tableRow)/table:table-cell[$currentIndex]"/>
                            </xsl:when>
                            <xsl:otherwise>
                                <xsl:variable name = "recursiveResult">
                                    <xsl:call-template name="getColumnValue">
                                        <xsl:with-param name="tableRow" select="$tableRow"/>
                                        <xsl:with-param name="colIndex" select="$colIndex - $repeatColumns + 1"/>
                                        <xsl:with-param name="currentIndex" select="$currentIndex + 1"/>
                                    </xsl:call-template>
                                </xsl:variable>
                                <xsl:value-of select="$recursiveResult"/>
                            </xsl:otherwise>
                        </xsl:choose>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:variable name = "recursiveResult">
                            <xsl:call-template name="getColumnValue">
                                <xsl:with-param name="tableRow" select="$tableRow"/>
                                <xsl:with-param name="colIndex" select="$colIndex"/>
                                <xsl:with-param name="currentIndex" select="$currentIndex + 1"/>
                            </xsl:call-template>
                        </xsl:variable>
                        <xsl:value-of select="$recursiveResult"/>

                    </xsl:otherwise>
                </xsl:choose>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="xt:node-set($tableRow)/table:table-cell[$colIndex]"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <!-- By setting the PropertyValue "URL" in the properties used in storeToURL(), -->
    <!-- we can pass a single parameter to this stylesheet.                         -->
    <!-- Caveat: If we use the "URL" property in the stylesheet and call in OOo     -->
    <!-- from the menu "File" > "Export...", OOo assigns a target URL. And that     -->
    <!-- might not be what we want.                                                 -->
    <xsl:param name="targetURL"/>

    <xsl:variable name="exportDate">
        <xsl:choose>
            <xsl:when test="string-length(substring-before($targetURL,';'))=10">
                <xsl:value-of select="substring-before($targetURL,';')"/>
            </xsl:when>
            <xsl:when test="string-length($targetURL)=10">
                <xsl:value-of select="$targetURL"/>
            </xsl:when>
        </xsl:choose>
    </xsl:variable>

    <xsl:variable name="exportUser">
        <xsl:if test="string-length(substring-after($targetURL,';'))>0">
            <xsl:value-of select="substring-after($targetURL,';')"/>
        </xsl:if>
    </xsl:variable>

    <xsl:template match="/">
        <plist version="1.0">
            <dict>
                <key>Animations</key>
                <array>
                    <!-- Process all tables -->
                    <xsl:apply-templates select="//table:table"/>
                </array>
            </dict>
        </plist>
    </xsl:template>


    <xsl:template match="table:table">
        <!-- Process all table-rows after the column labels in table-row 1 -->
        <xsl:for-each select="table:table-row">
            <xsl:if test="position()>1">
                <dict>
                    <key>character</key>
                    <string>
                        <xsl:call-template name="getColumnValue"> <xsl:with-param name="colIndex" select="1"/> <xsl:with-param name="currentIndex" select="1"/> <xsl:with-param name="tableRow" select="."/> </xsl:call-template>
                    </string>

                    <key>animation</key>
                    <string>
                        <xsl:call-template name="getColumnValue"> <xsl:with-param name="colIndex" select="2"/> <xsl:with-param name="currentIndex" select="1"/> <xsl:with-param name="tableRow" select="."/> </xsl:call-template>
                    </string>

                    <key>cycle</key>
                    <xsl:variable name="cycleTmp">
                        <xsl:call-template name="getColumnValue"> <xsl:with-param name="colIndex" select="3"/> <xsl:with-param name="currentIndex" select="1"/> <xsl:with-param name="tableRow" select="."/> </xsl:call-template>
                    </xsl:variable>
                    <xsl:if test="$cycleTmp > 0">
                        <true/>
                    </xsl:if>
                    <xsl:if test="$cycleTmp = 0">
                        <false/>
                    </xsl:if>

                    <key>frames</key>
                    <integer>
                        <xsl:call-template name="getColumnValue"> <xsl:with-param name="colIndex" select="4"/> <xsl:with-param name="currentIndex" select="1"/> <xsl:with-param name="tableRow" select="."/> </xsl:call-template>
                    </integer>

                    <key>randomSpeedPercent</key>
                    <integer>
                        <xsl:call-template name="getColumnValue"> <xsl:with-param name="colIndex" select="5"/> <xsl:with-param name="currentIndex" select="1"/> <xsl:with-param name="tableRow" select="."/> </xsl:call-template>
                    </integer>

                    <key>spriteNameRoot</key>
                    <string>
                        <xsl:call-template name="getColumnValue"> <xsl:with-param name="colIndex" select="6"/> <xsl:with-param name="currentIndex" select="1"/> <xsl:with-param name="tableRow" select="."/> </xsl:call-template>
                    </string>

                    <key>spriteSheetName</key>
                    <string>
                        <xsl:call-template name="getColumnValue"> <xsl:with-param name="colIndex" select="7"/> <xsl:with-param name="currentIndex" select="1"/> <xsl:with-param name="tableRow" select="."/> </xsl:call-template>
                    </string>

                    <key>anchorX</key>
                    <integer>
                        <xsl:call-template name="getColumnValue"> <xsl:with-param name="colIndex" select="11"/> <xsl:with-param name="currentIndex" select="1"/> <xsl:with-param name="tableRow" select="."/> </xsl:call-template>
                    </integer>

                    <key>anchorY</key>
                    <integer>
                        <xsl:call-template name="getColumnValue"> <xsl:with-param name="colIndex" select="12"/> <xsl:with-param name="currentIndex" select="1"/> <xsl:with-param name="tableRow" select="."/> </xsl:call-template>
                    </integer>

                </dict>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>
0 голосов
/ 01 июля 2018

Решение Марселя выглядит сложным, но отлично работает и не так сложно адаптируется.

Итак, еще раз, для всех: вы в основном копируете и вставляете весь шаблон в xsl: 

<xsl:template name="getColumnValue"> ... </>

Затем замените всю стандартную строку таблицы: (которая не работает) на 

<xsl:call-template name="getColumnValue"> 
    <xsl:with-param name="colIndex" select="1"/> 
    <xsl:with-param name="currentIndex" select="1"/> 
    <xsl:with-param name="tableRow" select="."/> 
</xsl:call-template>

Обязательно настройте значения "colIndex", но оставьте currentIndex равным 1!Наконец, добавьте к своей строке xt строки заголовка. 

xmlns:xt="http://www.jclark.com/xt"
extension-element-prefixes="xt"

Отлично, Марсель!

0 голосов
/ 04 мая 2011

Проблема связана с атрибутом номер-столбца-повторения для таблицы: элемент ячейки таблицы в базовой структуре данных листа.Для получения более подробной информации, пожалуйста, обратитесь к http://user.services.openoffice.org/en/forum/viewtopic.php?f=45&t=29674 и http://user.services.openoffice.org/en/forum/viewtopic.php?f=9&t=11865.

Хотя последняя ссылка утверждает, что разрешила проблему, решение не совсем то, что я искал.Мне потребовалось простое решение на основе индексов, которое позволяет более гибкую генерацию XML.Вот то, что я пытался выработать.

Я использовал xslt 2.0 для использования пользовательских функций.Вот таблица стилей ... 

<xsl:output method="xml" indent="yes" encoding="UTF-8" omit-xml-declaration="no"/>

<xsl:function name="my:getColumnValue">
    <xsl:param name="tableRow" as="node()"/>
    <xsl:param name="colIndex"/>
    <xsl:param name="currentIndex"/>
    <xsl:choose>
        <xsl:when test="$currentIndex &lt; $colIndex">
            <xsl:variable name="repeatColumns" select="$tableRow/table:table-cell[$currentIndex]/@table:number-columns-repeated"/>
            <xsl:choose>
                <xsl:when test="$repeatColumns">
                    <xsl:choose>
                        <xsl:when test="$currentIndex + $repeatColumns - 1 &gt;= $colIndex"><xsl:value-of select="$tableRow/table:table-cell[$currentIndex]"/></xsl:when>
                        <xsl:otherwise><xsl:value-of select="my:getColumnValue($tableRow, $colIndex - $repeatColumns + 1, $currentIndex + 1)"/></xsl:otherwise>
                    </xsl:choose>
                </xsl:when>
                <xsl:otherwise><xsl:value-of select="my:getColumnValue($tableRow, $colIndex, $currentIndex + 1)"/></xsl:otherwise>
            </xsl:choose>
        </xsl:when>
        <xsl:otherwise><xsl:value-of select="$tableRow/table:table-cell[$colIndex]"/></xsl:otherwise>
    </xsl:choose>
</xsl:function>

<xsl:template match="//table:table">
    <Tests>
        <!-- Process all table rows -->
        <xsl:variable name="colCount" select="count(table:table-row[1]/table:table-cell)"/>
        <xsl:for-each select="table:table-row">
            <xsl:if test="position() > 1">
            <Test>
                <SrNo><xsl:value-of select="my:getColumnValue(.,1,1)"/></SrNo>
                <Name><xsl:value-of select="my:getColumnValue(.,2,1)"/></Name>
                <Age><xsl:value-of select="my:getColumnValue(.,3,1)"/></Age>
                <Height><xsl:value-of select="my:getColumnValue(.,4,1)"/></Height>
                <Address><xsl:value-of select="my:getColumnValue(.,5,1)"/></Address>
            </Test>
            </xsl:if>
        </xsl:for-each>
    </Tests>
</xsl:template>

Приведенные выше теги являются просто заполнителями.Пожалуйста, замените их на соответствующие в вашем xslt.Это решение ограничено числом рекурсивных вызовов, разрешенных процессором xslt.

Если xslt 1.0 поддерживает отправку узла в качестве параметров, то мы можем попытаться заменить вышеуказанный udf, чтобы получить решение на основе шаблона.Если вы найдете какие-либо ошибки, дайте мне знать.

...