Подстроки в xsl

Question

Привет! Я конвертирую один XML в другой XML с использованием XSL.

Проблема, с которой я сталкиваюсь, заключается в значении тега 10feb2011 то есть <date>10feb2011</date>.

Мне нужен вывод:

 <date>10</date>
 <month>feb</month>
 <year>2011</year> 

, поэтому я использовал substring функцию, но не смог заставить ее работать.

Мой XML выглядит как

<ArrivalDateTime>
  <Date>20feb2011<Date>
</ArrivalDateTime>

Должен быть преобразован в этот формат

 <ArrivalDateTime>
   <dayOfMonth>10</dayOfMonth> 
   <month>feb</month> 
   <year>2011</year> 
 </ArrivalDateTime>

Ниже XSL, который я написал

<?xml version="1.0" encoding="ISO-8859-1"?>
<!-- Edited by XMLSpy® -->
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:template match="/">        
<xsl:text><![CDATA[<ArrivalDateTime>]]></xsl:text>          
<xsl:text><![CDATA[<dayOfMonth>]]></xsl:text>
<xsl:value-of select='substring("<xsl:value-of select="/ArrivalDateTime/Date"/>",1,2)'/>
<xsl:text><![CDATA[</dayOfMonth>]]></xsl:text>
<xsl:text><![CDATA[<month>]]></xsl:text>
<xsl:value-of select='substring("<xsl:value-of select="/ArrivalDateTime/Date"/>",3,3)'/>
<xsl:text><![CDATA[</month>]]></xsl:text>
<xsl:text><![CDATA[<year>]]></xsl:text>
<xsl:value-of select='substring("<xsl:value-of select="/ArrivalDateTime/Date"/>",5,4)'/>
<xsl:text><![CDATA[</year>]]></xsl:text>
<xsl:text><![CDATA[</ArrivalDateTime>]]></xsl:text></xsl:template>
</xsl:stylesheet>

Answer 1

Ваш XSLT выглядит слишком сложным. Просто создайте узлы XML следующим образом:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/">
    <ArrivalDateTime>
      <dayOfMonth>
        <xsl:value-of select="substring(/ArrivalDateTime/Date,1,2)"/>
      </dayOfMonth>
      <month>
        <xsl:value-of select="substring(/ArrivalDateTime/Date,3,3)"/>
      </month>
      <year>
        <xsl:value-of select="substring(/ArrivalDateTime/Date,5,4)"/>
      </year>
    </ArrivalDateTime>
  </xsl:template>
</xsl:stylesheet>

Вы не должны использовать секции CDATA для создания узлов XML в вашем выходном документе. Это не нужно и потенциально опасно, поскольку позволяет генерировать недопустимый XML.

Обратите внимание, что внутри выражений XPath, таких как атрибуты select, вы должны написать действительный XPath. XML-теги здесь запрещены.

Лучше всего начать изучение учебника по XSLT.

Answer 2

Ваш синтаксис подстроки не совсем правильный. Вам нужно использовать 6,4 (а не 5,4) для подстроки года. Также вам не нужно использовать xsl:text для создания тегов XML.

Попробуйте вместо этого:

<xsl:template match="/">
  <ArrivalDateTime>
    <dayOfMonth>
      <xsl:value-of select="substring(/ArrivalDateTime/Date,1,2)"/>
    </dayOfMonth>
    <month>
      <xsl:value-of select="substring(/ArrivalDateTime/Date,3,3)"/>
    </month>
    <year>
      <xsl:value-of select="substring(/ArrivalDateTime/Date,6,4)"/>
    </year>
  </ArrivalDateTime>
</xsl:template>

Альтернатива:

Вы даже можете использовать переменную для хранения даты, которая немного точнее:

<xsl:template match="/">
  <xsl:variable name="mydate" select="/ArrivalDateTime/Date" />
  <ArrivalDateTime>
    <dayOfMonth>
      <xsl:value-of select="substring($mydate,1,2)"/>
    </dayOfMonth>
    <month>
      <xsl:value-of select="substring($mydate,3,3)"/>
    </month>
    <year>
      <xsl:value-of select="substring($mydate,6,4)"/>
    </year>
  </ArrivalDateTime>
</xsl:template>

Answer 3

Я понимаю, что эта тема старая и, вероятно, нет необходимости добавлять другой ответ.

Однако я не могу не сказать, что предыдущие ответы, хотя и технически правильные для данного фрагмента XML, не будут работать, если этот фрагмент XML будет частью более крупного документа. Другими словами, эти решения совпадают на корневом узле "/" и, следовательно, будут работать ТОЛЬКО, когда ArrivalDateTime является корневым узлом документа. Реально, это, вероятно, никогда не будет иметь место.

Рекурсивная копия была бы более адаптируемым решением:

    <?xml version="1.0"?>



    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="node()|@*|text()">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*|text()"/>
    </xsl:copy>
    </xsl:template>

    <xsl:template match="Date">
    <dayOfMonth>
        <xsl:value-of select="substring(., 1, 2)"/>
    </dayOfMonth>
    <month>
        <xsl:value-of select="substring(., 3, 3)"/>
    </month>
    <year>
        <xsl:value-of select="substring(., 6)"/>
    </year>
    </xsl:template>

   </xsl:stylesheet>

Answer 4

У вас правильная идея, но все немного перемешалось. Похоже, вы ожидаете, что некоторые части XSLT будут оценены, поскольку он выводит «текст».

В вашем XSLT вы создаете узлы , которые будут сериализованы как XML.

Это преобразование даст желаемый результат.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
<xsl:output indent="yes" />
    <xsl:template match="/">
        <ArrivalDateTime>
            <dayOfMonth><xsl:value-of select="substring(/ArrivalDateTime/Date,1,2)"/></dayOfMonth> 
            <month><xsl:value-of select="substring(/ArrivalDateTime/Date,3,3)"/></month> 
            <year><xsl:value-of select="substring(/ArrivalDateTime/Date,6,4)"/></year> 
        </ArrivalDateTime>
    </xsl:template>
</xsl:stylesheet>