Как определить, работает ли конкретная Delphi IDE? - PullRequest
Новая
       51

Как определить, работает ли конкретная Delphi IDE?

5 голосов
/ 04 февраля 2012

Я работаю над установщиком компонентов (только для Delphi XE2) и хотел бы определить, работает ли Delphi XE2 IDE. Как бы вы обнаружили это?

P.S. Я знаю имя класса окна TAppBuilder, но мне нужно определить и версию IDE.

Ответы [ 2 ]

7 голосов
/ 04 февраля 2012

Это шаги, чтобы определить, работает ли Delphi XE2

1) Сначала прочитайте расположение файла bds.exe из записи App в разделе реестра \Software\Embarcadero\BDS\9.0, который можно найти в корневом ключе HKEY_CURRENT_USER или HKEY_LOCAL_MACHINE.

2) Затем, используя функцию CreateToolhelp32Snapshot , вы можете проверить, существует ли исполняемый файл с таким же именем.

3) Наконец, используя PID последней обработанной записи, вы можете определить полный путь к файлу Exe (используя функцию GetModuleFileNameEx), а затем снова сравнить имена.

Проверьте этот пример кода 

{$APPTYPE CONSOLE}

{$R *.res}

uses

  Registry,
  PsAPI,
  TlHelp32,
  Windows,
  SysUtils;

function ProcessFileName(dwProcessId: DWORD): string;
var
  hModule: Cardinal;
begin
  Result := '';
  hModule := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, False, dwProcessId);
  if hModule <> 0 then
    try
      SetLength(Result, MAX_PATH);
      if GetModuleFileNameEx(hModule, 0, PChar(Result), MAX_PATH) > 0 then
        SetLength(Result, StrLen(PChar(Result)))
      else
        Result := '';
    finally
      CloseHandle(hModule);
    end;
end;

function IsAppRunning(const FileName: string): boolean;
var
  hSnapshot      : Cardinal;
  EntryParentProc: TProcessEntry32;
begin
  Result := False;
  hSnapshot := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  if hSnapshot = INVALID_HANDLE_VALUE then
    exit;
  try
    EntryParentProc.dwSize := SizeOf(EntryParentProc);
    if Process32First(hSnapshot, EntryParentProc) then
      repeat
        if CompareText(ExtractFileName(FileName), EntryParentProc.szExeFile) = 0 then
          if CompareText(ProcessFileName(EntryParentProc.th32ProcessID),  FileName) = 0 then
          begin
            Result := True;
            break;
          end;
      until not Process32Next(hSnapshot, EntryParentProc);
  finally
    CloseHandle(hSnapshot);
  end;
end;

function RegReadStr(const RegPath, RegValue: string; var Str: string;
  const RootKey: HKEY): boolean;
var
  Reg: TRegistry;
begin
  try
    Reg := TRegistry.Create;
    try
      Reg.RootKey := RootKey;
      Result      := Reg.OpenKey(RegPath, True);
      if Result then
        Str := Reg.ReadString(RegValue);
    finally
      Reg.Free;
    end;
  except
    Result := False;
  end;
end;

function RegKeyExists(const RegPath: string; const RootKey: HKEY): boolean;
var
  Reg: TRegistry;
begin
  try
    Reg := TRegistry.Create;
    try
      Reg.RootKey := RootKey;
      Result      := Reg.KeyExists(RegPath);
    finally
      Reg.Free;
    end;
  except
    Result := False;
  end;
end;


function GetDelphiXE2LocationExeName: string;
Const
 Key = '\Software\Embarcadero\BDS\9.0';
begin
  Result:='';
    if RegKeyExists(Key, HKEY_CURRENT_USER) then
    begin
      RegReadStr(Key, 'App', Result, HKEY_CURRENT_USER);
      exit;
    end;

    if RegKeyExists(Key, HKEY_LOCAL_MACHINE) then
      RegReadStr(Key, 'App', Result, HKEY_LOCAL_MACHINE);
end;


Var
 Bds : String;

begin
  try
     Bds:=GetDelphiXE2LocationExeName;
     if Bds<>'' then
     begin
       if  IsAppRunning(Bds) then
        Writeln('The Delphi XE2 IDE Is running')
       else
        Writeln('The Delphi XE2 IDE Is not running')
     end
     else
     Writeln('The Delphi XE2 IDE Is was not found');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

Дополнительные ресурсы. Detecting installed delphi versions

1 голос
/ 02 июня 2012

Проверьте DebugHook <> 0. Недостатком является то, что в настоящее время, если ваше приложение построено с пакетами, DebugHook вернет 0. Но обычно это был бы очень элегантный и простой тест. Отлично работает в D2009, я только что заметил, что в XE2 есть ошибка зависимости пакета (http://qc.embarcadero.com/wc/qcmain.aspx?d=105365).

...