Clojure макрос для замены шаблона строки - PullRequest
Новая
       5

Clojure макрос для замены шаблона строки

2 голосов
/ 26 мая 2011

Это мой первый макрос Clojure - я супер-нуб.

Вчера я опубликовал и уточнил функцию замены шаблонов строк. Несколько человек предположили, что ключи могут быть заменены во время компиляции. Вот моя первая попытка: 

(defn replace-templates*
  "Return a String with each occurrence of a substring of the form {key}
   replaced with the corresponding value from a map parameter.
   @param str the String in which to do the replacements
   @param m a map of template->value
   @thanks kotarak /4623355/prodolzhenie-zamena-shablona-prostoi-stroki-v-scala-i-clojure
     follow-up-to-simple-string-template-replacement-in-scala-and-clojure"
  [^String text m]
  (let [builder (StringBuilder.)]
    (loop [text text]
      (cond
        (zero? (count text))
        (.toString builder)

        (.startsWith text "{")
        (let [brace (.indexOf text "}")]
          (if (neg? brace)
            (.toString (.append builder text))
            (if-let [[_ replacement] (find m (subs text 1 brace))]
              (do
                (.append builder replacement)
                (recur (subs text (inc brace))))
              (do
                (.append builder "{")
                (recur (subs text 1))))))

        :else
        (let [brace (.indexOf text "{")]
          (if (neg? brace)
            (.toString (.append builder text))
            (do
              (.append builder (subs text 0 brace))
              (recur (subs text brace)))))))))

(def foo* 42)
(def m {"foo" foo*})

(defmacro replace-templates
  [text m]
  (if (map? m)
    `(str
      ~@(loop [text text acc []]
        (cond
          (zero? (count text))
          acc

          (.startsWith text "{")
          (let [brace (.indexOf text "}")]
            (if (neg? brace)
              (conj acc text)
              (if-let [[_ replacement] (find m (subs text 1 brace))]
                (recur (subs text (inc brace)) (conj acc replacement))
                (recur (subs text 1) (conj acc "{")))))

          :else
          (let [brace (.indexOf text "{")]
            (if (neg? brace)
              (conj acc text)
              (recur (subs text brace) (conj acc (subs text 0 brace))))))))
    `(replace-templates* ~text m)))

(macroexpand '(replace-templates "this is a {foo} test" {"foo" foo*}))
;=> (clojure.core/str "this is a " foo* " test")
(println (replace-templates "this is a {foo} test" {"foo" foo*}))
;=> this is a 42 test
(macroexpand '(replace-templates "this is a {foo} test" m))
;=> (user/replace-templates* "this is a {foo} test" user/m)
(println (replace-templates "this is a {foo} test" m))
;=> this is a 42 test

Есть ли лучший способ написать этот макрос? В частности, расширенная версия каждого значения не получает квалификацию пространства имен.

Ответы [ 2 ]

1 голос
/ 27 мая 2011

Я бы попробовал уменьшить количество повторений.Я настроил функцию, чтобы использовать ваш макро-подход к аккумулятору, и пусть replace-templates* сделает все остальное через (apply str ...).Таким образом можно повторно использовать функцию в макросе. 

(defn extract-snippets
  [^String text m]
  (loop [text     text
         snippets []]
    (cond
      (zero? (count text))
      snippets

      (.startsWith text "{")
      (let [brace (.indexOf text "}")]
        (if (neg? brace)
          (conj snippets text)
          (if-let [[_ replacement] (find m (subs text 1 brace))]
            (recur (subs text (inc brace)) (conj snippets replacement))
            (recur (subs text 1)           (conj snippets \{)))))

        :else
        (let [brace (.indexOf text "{")]
          (if (neg? brace)
            (conj snippets text)
            (recur (subs text brace) (conj snippets (subs text 0 brace))))))))

(defn replace-templates*
  [text m]
  (apply str (extract-snippets text m)))

(defmacro replace-templates
  [text m]
  (if (map? m)
    `(apply str ~(extract-snippets text m))
    `(replace-templates* ~text ~m)))

Примечание: в макросе вы не ставили m в кавычки.Так что это работает только потому, что раньше вы это делали.Это не было бы с (let [m {"a" "b"}] (replace-templates "..." m)).

0 голосов
/ 26 мая 2011

Измените (defn m {"foo" foo*}) на (def m {"foo" foo*}), и похоже, что оно работает.

...