Ряд за каждый третий элемент

Question

Я хотел бы иметь контейнер вокруг каждого третьего элемента - однако, я не могу заставить его работать, я пытаюсь сделать это так:

<xsl:when test="$type != ''">
            <xsl:variable name="query" select="$currentPage/* [@isDoc and string(umbracoNaviHide) != '1' and type = $type ]"/>
            <xsl:if test="count($query) &gt; 0">
                <section class="brochures-{$section-css-name}">
                    <xsl:choose>
                        <xsl:when test="$section-css-name = 'portrait' or region = $region">
                            <h2>Business</h2>
                        </xsl:when>
                        <xsl:when test="$section-css-name = 'landscape' or region = $region">
                            <h2>Panorama</h2>
                        </xsl:when>
                        <xsl:when test="$section-css-name = 'quadrat' or region = $region">
                            <h2>Image</h2>
                        </xsl:when>
                    </xsl:choose>
                    <xsl:if test="position() = 1 or position() mod 3 = 0 ">
                        <div class="row">
                            <div class="case-shadow">&nbsp;<xsl:comment/>
                            </div>
                            <xsl:for-each select="$query">
                                <xsl:variable name="externalUrl" select="externalUrl"/>
                                <xsl:if test="$externalUrl != ''">
                                    <article class="brochure">
                                        <a href="{$externalUrl}/MailView/" target="_blank" class="replaceURL">
                                            <xsl:if test="$type = 60">
                                                <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="160" height="228" alt="" class="reflect"/>
                                            </xsl:if>
                                            <xsl:if test="$type = 61">
                                                <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="228" height="160" alt="" class="reflect"/>
                                            </xsl:if>
                                            <xsl:if test="$type = 62">
                                                <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="160" height="160" alt="" class="reflect"/>
                                            </xsl:if>
                                            <p>
                                                <xsl:value-of select="headline"/>
                                            </p>
                                        </a>
                                    </article>
                                </xsl:if>
                            </xsl:for-each>
                        </div>
                    </xsl:if>
                </section>
            </xsl:if>
        </xsl:when>

Я бы хотел, чтобы вывод HTMLbe:

<section class="brochures-portrait">
<h2>Business</h2>
<div class="row">
    <div class="case-shadow">&nbsp;<!----></div>
    <article class="brochure">
    </article>
    <article class="brochure">
    </article>
    <article class="brochure">
    </article>
</div>
<div class="row">
<div class="case-shadow">&nbsp;<!----></div>
    <article class="brochure">
    </article>
    <article class="brochure">
    </article>
</div>  
</section>

Тем не менее, я получаю только 1 во всех моих брошюрах: (

---

Хорошо, спасибо, но я не совсем уверен, как интегрировать это с этим:

<xsl:template match="/">
    <xsl:variable name="chosenregion">
        <xsl:value-of select="umbraco.library:RequestQueryString('region')"/>
    </xsl:variable>
    <xsl:if test="$currentPage/showRegionNavgation = '1'">
        <nav class="region-sort">
            <ul>
                <li class="grey-gradient">
                    <xsl:if test="$chosenregion = ''">
                        <xsl:attribute name="class">selected</xsl:attribute>
                    </xsl:if>
                    <a href="?">All</a>
                </li>
                <li class="grey-gradient">
                    <xsl:if test="$chosenregion = '76'">
                        <xsl:attribute name="class">selected</xsl:attribute>
                    </xsl:if>
                    <a href="?region=76">North</a>
                </li>
                <li class="grey-gradient">
                    <xsl:if test="$chosenregion = '77'">
                        <xsl:attribute name="class">selected</xsl:attribute>
                    </xsl:if>
                    <a href="?region=77">Mid</a>
                </li>
                <li class="grey-gradient last">
                    <xsl:if test="$chosenregion = '78'">
                        <xsl:attribute name="class">selected</xsl:attribute>
                    </xsl:if>
                    <a href="?region=78">South</a>
                </li>
            </ul>
        </nav>
    </xsl:if>

    <xsl:call-template name="brochure">
        <xsl:with-param name="type">60</xsl:with-param>
        <xsl:with-param name="region">
            <xsl:value-of select="umbraco.library:RequestQueryString('region')"/>
        </xsl:with-param>
        <xsl:with-param name="section-css-name">portrait</xsl:with-param>
    </xsl:call-template>
    <xsl:call-template name="brochure">
        <xsl:with-param name="type">61</xsl:with-param>
        <xsl:with-param name="region">
            <xsl:value-of select="umbraco.library:RequestQueryString('region')"/>
        </xsl:with-param>
        <xsl:with-param name="section-css-name">landscape</xsl:with-param>
    </xsl:call-template>
    <xsl:call-template name="brochure">
        <xsl:with-param name="type">62</xsl:with-param>
        <xsl:with-param name="region">
            <xsl:value-of select="umbraco.library:RequestQueryString('region')"/>
        </xsl:with-param>
        <xsl:with-param name="section-css-name">quadrat</xsl:with-param>
    </xsl:call-template>
</xsl:template>
<xsl:template name="brochure">
    <xsl:param name="type"/>
    <xsl:param name="section-css-name"/>
    <xsl:param name="region"/>
    <xsl:choose>
        <xsl:when test="$region != ''">
            <xsl:variable name="query" select="$currentPage/* [@isDoc and string(umbracoNaviHide) != '1' and type = $type and region = $region ]"/>
            <xsl:if test="count($query) &gt; 0">
                <section class="brochures-{$section-css-name}">
                    <xsl:choose>
                        <xsl:when test="$section-css-name = 'portrait' or region = $region">
                            <h2>
                                <xsl:value-of select="umbraco.library:GetDictionaryItem('Business')"/>
                            </h2>
                        </xsl:when>
                        <xsl:when test="$section-css-name = 'landscape' or region = $region">
                            <h2>
                                <xsl:value-of select="umbraco.library:GetDictionaryItem('Panorama')"/>
                            </h2>
                        </xsl:when>
                        <xsl:when test="$section-css-name = 'quadrat' or region = $region">
                            <h2>
                                <xsl:value-of select="umbraco.library:GetDictionaryItem('Image')"/>
                            </h2>
                        </xsl:when>
                    </xsl:choose>
                    <div class="case-shadow">&nbsp;<xsl:comment/>
                    </div>
                    <xsl:for-each select="$query">
                        <xsl:variable name="externalUrl" select="externalUrl"/>
                        <xsl:if test="$externalUrl != ''">
                            <article class="brochure">
                                <a href="{$externalUrl}/MailView/" target="_blank" class="replaceURL">
                                    <xsl:if test="$type = 60">
                                        <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="176" height="248" alt="" class="reflect"/>
                                    </xsl:if>
                                    <xsl:if test="$type = 61">
                                        <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="242" height="170" alt="" class="reflect"/>
                                    </xsl:if>
                                    <xsl:if test="$type = 62">
                                        <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="176" height="175" alt="" class="reflect"/>
                                    </xsl:if>
                                    <p>
                                        <xsl:value-of select="headline"/>
                                    </p>
                                </a>
                            </article>
                        </xsl:if>
                    </xsl:for-each>
                </section>
            </xsl:if>
        </xsl:when>
        <xsl:when test="$type != ''">
            <xsl:variable name="query" select="$currentPage/* [@isDoc and string(umbracoNaviHide) != '1' and type = $type ]"/>
            <xsl:if test="count($query) &gt; 0">
                <section class="brochures-{$section-css-name}">
                    <xsl:choose>
                        <xsl:when test="$section-css-name = 'portrait' or region = $region">
                            <h2>Business</h2>
                        </xsl:when>
                        <xsl:when test="$section-css-name = 'landscape' or region = $region">
                            <h2>Panorama</h2>
                        </xsl:when>
                        <xsl:when test="$section-css-name = 'quadrat' or region = $region">
                            <h2>Image</h2>
                        </xsl:when>
                    </xsl:choose>
                    <div class="case-shadow">&nbsp;<xsl:comment/>
                    </div>
                    <xsl:for-each select="$query">
                        <xsl:choose>
                            <xsl:when test="position() = 1 or position() mod 3 = 0">
                                <div class="row">
                                    <xsl:variable name="externalUrl" select="externalUrl"/>
                                    <xsl:if test="$externalUrl != ''">
                                        <article class="brochure">
                                            <a href="{$externalUrl}/MailView/" target="_blank" class="replaceURL">
                                                <xsl:if test="$type = 60">
                                                    <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="160" height="228" alt="" class="reflect"/>
                                                </xsl:if>
                                                <xsl:if test="$type = 61">
                                                    <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="228" height="160" alt="" class="reflect"/>
                                                </xsl:if>
                                                <xsl:if test="$type = 62">
                                                    <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="160" height="160" alt="" class="reflect"/>
                                                </xsl:if>
                                                <p>
                                                    <xsl:value-of select="headline"/>
                                                </p>
                                            </a>
                                        </article>
                                    </xsl:if>
                                </div>
                            </xsl:when>
                            <xsl:otherwise>
                                <xsl:variable name="externalUrl" select="externalUrl"/>
                                <xsl:if test="$externalUrl != ''">
                                    <article class="brochure">
                                        <a href="{$externalUrl}/MailView/" target="_blank" class="replaceURL">
                                            <xsl:if test="$type = 60">
                                                <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="160" height="228" alt="" class="reflect"/>
                                            </xsl:if>
                                            <xsl:if test="$type = 61">
                                                <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="228" height="160" alt="" class="reflect"/>
                                            </xsl:if>
                                            <xsl:if test="$type = 62">
                                                <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="160" height="160" alt="" class="reflect"/>
                                            </xsl:if>
                                            <p>
                                                <xsl:value-of select="headline"/>
                                            </p>
                                        </a>
                                    </article>
                                </xsl:if>
                            </xsl:otherwise>
                        </xsl:choose>
                    </xsl:for-each>
                </section>
            </xsl:if>
        </xsl:when>
        <xsl:otherwise>
            <xsl:variable name="query" select="$currentPage/* [@isDoc and string(umbracoNaviHide) != '1' and type = $type and region = $region ]"/>
            <xsl:if test="count($query) &gt; 0">
                <section class="brochures-{$section-css-name}">
                    <xsl:choose>
                        <xsl:when test="$section-css-name = 'portrait' or region = $region">
                            <h2>Business</h2>
                        </xsl:when>
                        <xsl:when test="$section-css-name = 'landscape' or region = $region">
                            <h2>Panorama</h2>
                        </xsl:when>
                        <xsl:when test="$section-css-name = 'quadrat' or region = $region">
                            <h2>Image</h2>
                        </xsl:when>
                    </xsl:choose>
                    <div class="case-shadow">&nbsp;<xsl:comment/>
                    </div>
                    <xsl:for-each select="$query">
                        <xsl:variable name="externalUrl" select="externalUrl"/>
                        <xsl:if test="$externalUrl != ''">
                            <article class="brochure">
                                <a href="{$externalUrl}/MailView/" target="_blank" class="replaceURL">
                                    <xsl:if test="$type = 60">
                                        <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="176" height="248" alt="" class="reflect"/>
                                    </xsl:if>
                                    <xsl:if test="$type = 61">
                                        <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="242" height="170" alt="" class="reflect"/>
                                    </xsl:if>
                                    <xsl:if test="$type = 62">
                                        <img src="{$externalUrl}/MailView/pagedata/frontpage.jpg" width="176" height="175" alt="" class="reflect"/>
                                    </xsl:if>
                                    <p>
                                        <xsl:value-of select="headline"/>
                                    </p>
                                </a>
                            </article>
                        </xsl:if>
                    </xsl:for-each>
                </section>
            </xsl:if>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Answer 1

Вместо того, чтобы перебирать все свои элементы и определять положение каждого из них, вместо этого по очереди, вы должны попытаться сопоставить соответствующий элемент в 1-й, 4-й, 7-й (и т. Д.) Позиции.

Например, предположим, что ваш входной XML был следующим

<brochures>
   <brochure>Brochure 1</brochure>
   <brochure>Brochure 2</brochure>
   <brochure>Brochure 3</brochure>
   <brochure>Brochure 4</brochure>
   <brochure>Brochure 5</brochure>
</brochures>

Вы бы получили каждый третий элемент, как так

<xsl:apply-templates select="brochure[position() mod 3 = 1]" mode="first"/>

После размещения в таких строках вы можете просто выписать свой div, а затем сопоставить три строки, требуемые в этой группе.

<div class="row">
   <xsl:apply-templates select="self::*|following-sibling::*[position() &lt; 3]"/>
</div>

Вот полный XSLT. Обратите внимание, что я параметризовал количество строк на деление, чтобы сделать его более настраиваемым.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:param name="rows" select="3" />

   <xsl:template match="/brochures">
      <section>
         <xsl:apply-templates select="brochure[position() mod $rows = 1]" mode="first"/>
      </section>
   </xsl:template>

   <xsl:template match="brochure" mode="first">
      <div class="row">
         <xsl:apply-templates select="self::*|following-sibling::*[position() &lt; $rows]"/>
      </div>
   </xsl:template>

   <xsl:template match="brochure">
      <article class="brochure"/>
   </xsl:template>
</xsl:stylesheet>

(Обратите внимание на использование режима для различения двух шаблонов, соответствующих элементу брошюра )

При применении к приведенному выше образцу XML возвращается следующее

<section>
  <div class="row">
    <article class="brochure" />
    <article class="brochure" />
    <article class="brochure" />
  </div>
  <div class="row">
    <article class="brochure" />
    <article class="brochure" />
   </div>
</section>

Надеюсь, это даст вам достаточно информации, чтобы адаптировать ее к вашему собственному XML!