NullPointerException в методе сокращения Clojure

Question

Я борюсь с NPE в моей первой программе Clojure и мне нужна помощь.

call-elem - это структура, которая содержит: -

• :id, aстрока типа some.packagename.SomeClass.someMethod
• :calls (дочерние элементы), вектор других call-elem структур

определяется следующим образом:

(defstruct call-struct :id :calls)

(defn- class-name [call]
  (let [id (call :id)]
    (.substring id 0 (.lastIndexOf id "."))))

(defn- method-name [call]
  (let [id (call :id)]
    (.substring id (inc (.lastIndexOf id ".")))))

Iтакже есть метод foo, который принимает class-map и call-elem в качестве аргументов.class-map - карта от class-name до method-map.method-map - это карта method-name к списку variation s.Каждый variation - это карта с ключами :class-name, :method-name и :calls.:calls - список других вариантов.Функция foo должна возвращать вектор с двумя элементами: -

• первый элемент - карта классов с новыми записями, соответствующими call-elem и его дочерним элементам
• Второй элемент - это карта вариантов, соответствующая аргументу call-elem

Вот код:

(declare foo' add-new-variation)

(defn foo [class-map call-elem]
  (let [children (call-elem :calls)
        class-name (class-name call-elem)
        method-name (method-name call-elem)]
    (if (empty? children)
      (let [new-variation {:class-name class-name
                           :method-name method-name
                           :calls []}
            new-class-map (add-new-variation class-map 
                                             class-name method-name 
                                             new-variation)]
        [new-class-map new-variation])
      (let [[new-class-map child-variations-list] 
            (reduce #(foo' %1 %2) (class-map '()) children)
            new-variation {:class-name class-name
                           :method-name method-name
                           :calls child-variations-list}
            new-class-map' (add-new-variation new-class-map 
                                              class-name method-name 
                                              new-variation)]
        [new-class-map' new-variation]))))

(defn foo' [[class-map variations-list] call-elem]
  (let [[new-class-map new-variation] (foo class-map call-elem)]
    [new-class-map (cons new-variation variations-list)]))

(defn add-new-variation [class-map class-name method-name variation]
  (let [method-map (if (contains? class-map class-name)
                     (class-map class-name) {})
        variations-list (if (contains? method-map method-name)
                          (method-map method-name) [])
        new-variations-list (conj variations-list variation)
        new-method-map (assoc method-map method-name new-variations-list)]
    (assoc class-map class-name new-method-map)))

Когда я пытаюсь запустить следующий код:

(try
  (let [call-elem 
        (struct call-struct "Class1.method1" 
                [(struct call-struct "Class2.method1" [])])]
    (second (foo {} call-elem)))
  (catch Exception ex
         (.printStackTrace ex)))

Я получаю следующий результат:

{:class-name "Class1",
 :method-name "method1",
 :calls ({:class-name "Class2", :method-name "method1", :calls []})}

Но когда я пытаюсь запустить следующий код, увеличивая количество вызовов еще на один уровень, я получаю NullPointerException:

(try
  (let [call-elem 
        (struct call-struct "Class1.method1" 
                [(struct call-struct "Class2.method1"
                         [(struct call-struct "Class3.method1" [])])])]
    (second (foo {} call-elem)))
  (catch Exception ex
         (.printStackTrace ex)))

Вот трассировка стека:

java.lang.NullPointerException
    at first.simple$foo.invoke(NO_SOURCE_FILE:46)
    at first.simple$foo_SINGLEQUOTE_.invoke(NO_SOURCE_FILE:55)
    at first.simple$foo$fn__1986.invoke(NO_SOURCE_FILE:46)
    at clojure.lang.ArrayChunk.reduce(ArrayChunk.java:58)
    at clojure.core.protocols$fn__5565.invoke(protocols.clj:30)
    at clojure.core.protocols$fn__5543$G__5538__5552.invoke(protocols.clj:11)
    at clojure.core$reduce.invoke(core.clj:5995)
    at first.simple$foo.invoke(NO_SOURCE_FILE:46)
    at first.simple$eval2010.invoke(NO_SOURCE_FILE:6)
    at clojure.lang.Compiler.eval(Compiler.java:6465)
    at clojure.lang.Compiler.eval(Compiler.java:6431)
    at clojure.core$eval.invoke(core.clj:2795)
    at clooj.repl$create_clojure_repl$repl_thread_fn__578$fn__589.invoke(repl.clj:147)
    at clojure.main$repl$read_eval_print__5967.invoke(main.clj:244)
    at clojure.main$repl$fn__5972.invoke(main.clj:265)
    at clojure.main$repl.doInvoke(main.clj:265)
    at clojure.lang.RestFn.invoke(RestFn.java:1523)
    at clooj.repl$create_clojure_repl$repl_thread_fn__578.invoke(repl.clj:145)
    at clojure.lang.AFn.run(AFn.java:24)
    at java.lang.Thread.run(Thread.java:680)

Answer 1

Давайте подробнее рассмотрим reduce в foo.Я подозреваю, что вы пытаетесь передать коллекцию из двух элементов в качестве начального значения аккумулятора reduce.Однако использование скобок без кавычек приводит к тому, что (class-map '()) рассматривается как выражение для оценки.Что еще хуже, это допустимо, поскольку class-map является clojure.lang.PersistentArrayMap, который реализует IFn.

В результате вместо создания списка из двух элементов вы вызываете (class-map '()),скорее всего, возвращает nil, так как в class-map нет клавиши '().После этого в foo' вы пытаетесь связать nil с [class-map variations-list].Boom.Исключение нулевого указателя.

Определение второго аргумента reduce как вектора должно решить проблему.

--- before  2011-12-27 12:52:43.052218334 +0100
+++ after   2011-12-27 12:52:56.785477270 +0100
@@ -13,7 +13,7 @@
                                              new-variation)]
         [new-class-map new-variation])
       (let [[new-class-map child-variations-list]
-            (reduce #(foo' %1 %2) (class-map '()) children)
+            (reduce #(foo' %1 %2) [class-map '()] children)
             new-variation {:class-name class-name
                            :method-name method-name
                            :calls child-variations-list}