Проверка DNS с использованием Perl и Net :: DNS - PullRequest
Новая
       24

Проверка DNS с использованием Perl и Net :: DNS

3 голосов
/ 12 февраля 2012

Итак, в книге выданых есть небольшой скрипт (см. Стр. 173), целью которого является итеративная проверка DNS-серверов на предмет того, возвращают ли они один и тот же адрес для данного имени хоста. Однако решение, данное в книге, работает только тогда, когда хост имеет статический IP-адрес. Как бы я написал этот скрипт, если бы хотел, чтобы он работал с хостами, с которыми связано несколько адресов?

Вот код: 

#!/usr/bin/perl
use Data::Dumper;
use Net::DNS;

my $hostname = $ARGV[0];
# servers to check
my @servers = qw(8.8.8.8 208.67.220.220 8.8.4.4);

my %results;
foreach my $server (@servers) {
    $results{$server} 
        = lookup( $hostname, $server );
}

my %inv = reverse %results; # invert results - it should have one key if all
                           # are the same
if (scalar keys %inv > 1) { # if it has more than one key
    print "The results are different:\n";
    print Data::Dumper->Dump( [ \%results ], ['results'] ), "\n";
}

sub lookup {
    my ( $hostname, $server ) = @_;

    my $res = new Net::DNS::Resolver;
    $res->nameservers($server);
    my $packet = $res->query($hostname);

    if ( !$packet ) {
        warn "$server not returning any data for $hostname!\n";
        return;
    }
    my (@results);
    foreach my $rr ( $packet->answer ) {
        push ( @results, $rr->address );
    }
    return join( ', ', sort @results );
}

1 Ответ

0 голосов
/ 15 февраля 2012

Проблема, с которой я столкнулся, заключалась в том, что я получал эту ошибку, вызывая код на имени хоста, который возвращал несколько адресов, например www.google.com:

. 
***  WARNING!!!  The program has attempted to call the method
***  "address" for the following RR object:
***
***  www.google.com.    86399   IN  CNAME   www.l.google.com.
***
***  This object does not have a method "address".  THIS IS A BUG
***  IN THE CALLING SOFTWARE, which has incorrectly assumed that
***  the object would be of a particular type.  The calling
***  software should check the type of each RR object before
***  calling any of its methods.
***
***  Net::DNS has returned undef to the caller.

Эта ошибка означала, что я пытался вызвать метод адреса для объекта rr типа CNAME. Я хочу вызывать адресный метод только для rr объектов типа 'A'. В приведенном выше коде у меня нет проверок, чтобы убедиться, что я вызываю адрес для объектов типа «А». Я добавил эту строку кода (следующий, если не один), и он работает: 

my (@results);
foreach my $rr ( $packet->answer ) {
    next unless $rr->type eq "A";
    push ( @results, $rr->address );
}

Эта строка кода пропускает следующий адрес, полученный из $packet->answer, если тип объекта rr не равен "A".

...