Динамическое выражение «соответствует» в XSLT - PullRequest
Новая
       15

Динамическое выражение «соответствует» в XSLT

1 голос
/ 18 мая 2011

Я пытаюсь создать функцию xslt, которая динамически «совпадает» для элемента. В функции я передам два параметра - item () * и строку с разделителями-запятыми. Я токенизирую строку с разделителями-запятыми в операторе <xsl:for-each> select и затем делаю следующее: 

select="concat('$di:meta[matches(@domain,''', current(), ''')][1]')"

Вместо оператора select, выполняющего xquery, он просто возвращает строку.

Как мне заставить его выполнить xquery?

Заранее спасибо!

1 Ответ

1 голос
/ 18 мая 2011

Проблема в том, что вы слишком много оборачиваете выражением в функции concat(). Когда это вычисляется, он возвращает строку, которая будет выражением XPath, а не вычисляет выражение XPath, которое использует динамическую строку для выражения соответствия REGEX.

Вы хотите использовать: 

 <xsl:value-of select="$di:meta[matches(@domain
                                        ,concat('.*('
                                                ,current()
                                                ,').*')
                                        ,'i')][1]" />

Несмотря на то, что теперь вы оцениваете каждый термин отдельно, вместо того, чтобы иметь каждый из этих терминов в одном шаблоне регулярных выражений и выбираете первый, теперь он будет возвращать первый результат из каждого совпадения, а не первый из последовательность совпадающих предметов. Это может или не может быть то, что вы хотите.

Если вам нужен первый элемент из последовательности совпадающих элементов, вы можете сделать что-то вроде этого: 

<!--Create a variable and assign a sequence of matched items -->
<xsl:variable name="matchedMetaSequence" as="node()*">
 <!--Iterate over the sequence of names that we want to match on -->
 <xsl:for-each select="tokenize($csvString,',')">
  <!--Build the sequence(list) of matched items, 
      snagging the first one that matches each value -->
  <xsl:sequence select="$di:meta[matches(@domain
                       ,concat('.*('
                               ,current()
                               ,').*')
                       ,'i')][1]" />
 </xsl:for-each>
</xsl:variable>
<!--Return the first item in the sequence from matching on 
    the list of domain regex fragments -->
<xsl:value-of select="$matchedMetaSequence[1]" />

Вы также можете поместить это в пользовательскую функцию, например так: 

<xsl:function name="di:findMeta">
 <xsl:param name="meta" as="element()*" />
 <xsl:param name="names" as="xs:string" />

 <xsl:for-each select="tokenize(normalize-space($names),',')">
  <xsl:sequence select="$meta[matches(@domain
                                      ,concat('.*('
                                              ,current()
                                              ,').*')
                                      ,'i')][1]" />
 </xsl:for-each>
</xsl:function>

, а затем используйте его так: 

 <xsl:value-of select="di:findMeta($di:meta,'foo,bar,baz')[1]"/>
...