Отображение XML в XML с использованием XSLT - PullRequest
Новая
       1

Отображение XML в XML с использованием XSLT

5 голосов
/ 30 августа 2011

Я новичок в XSLT и пытаюсь отобразить один XML в другой XML с помощью xslt, вот мой первый XML 

<root>
    <record>
        <element name="LoginId">a</element>
        <element name="name">Admin Manager</element>
        <element name="password">12345</element>
        <element name="Age">28</element>
        <element name="Sex">M</element>
    </record>
    <record>
        <element name="LoginId">b</element>
        <element name="name">HR exec</element>
        <element name="password">pass1</element>
        <element name="Age">26</element>
        <element name="Sex">F</element>
    </record>
    <record>
        <element name="LoginId">c</element>
        <element name="name">PR Manager</element>
        <element name="password">pass2</element>
        <element name="Age">27</element>
        <element name="Sex">M</element>
    </record>
</root>

Мне нужно преобразовать этот XML в следующий 

<?xml version="1.0" encoding="UTF-8"?>
<final>
    <test>
        <UID>a</UUID>
        <Name>HR manager</Name>
        <Groups>admingroup</Groups>
        <Password>12345</Password>
    </test>
    <test>
        <UID>b</UUID>
        <Name>HR exec</Name>
        <Groups>admingroup</Groups>
        <Password>pass1</Password>
    </test>
    <test>
        <UID>c</UUID>
        <Name>PR manager</Name>
        <Groups>admingroup</Groups>
        <Password>pass2</Password>
    </test>
</final>

я пытался следовать xslt для преобразования 

<?xml version="1.0" encoding="UTF-8" ?> 
- <xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
- <xsl:template match="/">
- <test>
- <xsl:for-each select="root/record">
  <xsl:apply-templates select="element" /> 
  </xsl:for-each>
  </test>
  </xsl:template>
- <xsl:template match="element">
- <test>
  <Employee /> 
- <UID>
  <xsl:value-of select="@LoginId" /> 
  </UID>
- <xsl:choose>
- <xsl:when test="@name = ''">
- <Name>
  <xsl:text>demo employee</xsl:text> 
  </Name>
  </xsl:when>
- <xsl:otherwise>
- <Name>
  <xsl:value-of select="@name" /> 
  </Name>
  </xsl:otherwise>
  </xsl:choose>
- <Groups>
  <xsl:text>admingroup</xsl:text> 
  </Groups>
- <Password>
  <xsl:value-of select="@password" /> 
  </Password>
  </test>
  </xsl:template>
  </xsl:transform>

, но этот xslt генерирует следующий вывод XML 

<?xml version="1.0" encoding="UTF-8"?>
<impex>
    <final>
        <Employee />
        <UID />
        <Name>LoginId</Name>
        <Groups>admingroup</Groups>
        <Password />
    </final>

total 15 <final></final> with similar output

я могу сделать это легко в Java, но кое-как это сделать в xslt иЕдинственная проблема, с которой я сталкиваюсь, - это повторение тега <element> с различными значениями атрибута

, любая помощь в этом отношении будет очень полезна для меня

Ответы [ 3 ]

2 голосов
/ 31 августа 2011

Даже если у вас уже есть превосходное решение, предложенное ответом @ Martin (+1), я исправлю здесь ваше преобразование, чтобы показать вам, где вы ошиблись.Это может помочь вам узнать немного больше о том, как работает XSLT (и XPath). 

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output indent="yes"/>

    <xsl:template match="/">
        <final>
                <xsl:apply-templates select="root/record" /> 
        </final>
    </xsl:template>

    <xsl:template match="record">
        <test>
            <Employee /> 
            <UID>
                <xsl:value-of select="element[@name='LoginId']" /> 
            </UID>
            <xsl:choose>
                <xsl:when test="element[@name='name']=''">
                    <Name>
                        <xsl:text>demo employee</xsl:text> 
                    </Name>
                </xsl:when>
                <xsl:otherwise>
                    <Name>
                        <xsl:value-of select="element[@name='name']"/> 
                    </Name>
                </xsl:otherwise>
            </xsl:choose>
            <Groups>
                <xsl:text>admingroup</xsl:text> 
            </Groups>
            <Password>
                <xsl:value-of select="element[@name='password']" /> 
            </Password>
        </test>
    </xsl:template>

</xsl:transform>

Обратите внимание, что подход xsl:choose является правильным, даже если обычно предпочтительным способом XSLT являются правила шаблона: 

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output indent="yes"/>

    <xsl:template match="/">
        <final>
            <xsl:apply-templates select="root/record" /> 
        </final>
    </xsl:template>

    <xsl:template match="record">
        <test>
            <Employee /> 
            <UID>
                <xsl:value-of select="element[@name='LoginId']" /> 
            </UID>
            <Name>
                <xsl:apply-templates select="element[@name='name']"/>
            </Name>
            <Groups>
                <xsl:text>admingroup</xsl:text> 
            </Groups>
            <Password>
                <xsl:value-of select="element[@name='password']" /> 
            </Password>
        </test>
    </xsl:template>

    <xsl:template match="element[@name='name'][.='']">
            <xsl:text>demo employee</xsl:text> 
    </xsl:template>

    <xsl:template match="element[@name='name'][.!='']">
            <xsl:value-of select="."/> 
    </xsl:template>

</xsl:transform>
2 голосов
/ 30 августа 2011

Я бы подошел к этому так: 

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>

  <xsl:template match="root">
    <final>
      <xsl:apply-templates/>
    </final>
  </xsl:template>

  <xsl:template match="record">
    <test>
      <xsl:apply-templates select="element[@name = ('LoginId', 'name')]"/>
      <Groups>admingroup</Groups>
      <xsl:apply-templates select="element[@name = 'password']"/>
    </test>
  </xsl:template>

  <xsl:template match="element[@name = 'LoginId']">
    <UID>
      <xsl:value-of select="."/>
    </UID>
  </xsl:template>

  <xsl:template match="element[@name = 'name']">
    <Name>
      <xsl:value-of select="."/>
    </Name>
  </xsl:template>

  <xsl:template match="element[@name = 'password']">
    <Password>
      <xsl:value-of select="."/>
    </Password>
  </xsl:template>

</xsl:stylesheet>

Таким образом, Saxon 9.3 генерирует следующий результат из вашего образца ввода:

0 голосов
/ 07 января 2015

Использовать схему источника для схемы назначения с картами преобразования. XSLT лучше подходит для преобразования XML в другие форматы для представления данных.

Оформить заказ BizTalk

...