В Аде, как я мог сделать подтип записей?

Question

если у меня есть такой тип записи:

  type ABC is record
       A : Integer;
       B : Integer;
  end record;

Как я могу создать подтип ABC с двумя целочисленными типами, диапазон которых указан?

Answer 1

Не отвечая на ваш вопрос как таковой (как говорит NWS, вы не можете этого сделать), если вместо A и B являются целыми числами, вы можете сделать следующее:

package Record_Subtypes is

   type Int_Data is array (Integer range <>) of Integer;

   type ABC (X_Min, X_Max, Y_Min, Y_Max : Integer) is record
      A : Int_Data (X_Min .. X_Max);
      B : Int_Data (Y_Min .. Y_Max);
   end record;

   subtype ABC_4_4 is ABC(X_Min => 1, X_Max => 4,
                          Y_Min => 1, Y_Max => 4);

   subtype ABC_1_7_3_12 is ABC (X_Min => 1, X_Max => 7,
                                Y_Min => 3, Y_Max => 12);
end Record_Subtypes;

В полях записи A и B используется подтип индекса, предоставленный дискриминантами записи.

Это хороший прием, который я использовал время от времени, полезный при чтении строк переменной длины изинтерфейс (такой как сокет), где количество байтов для чтения предоставляется через заголовок фиксированного размера;или в случае записи варианта с дискриминантом перечисления я могу подтипить запись в конкретный вариант.

Answer 2

Вы также можете использовать универсальный, как это:

generic
   type Number is range <>;
package Int_Record is
   type ABC is record
      A, B : Number;
   end record;
end Int_Record;

Если вы хотите разные диапазоны для A и B, вам придется использовать два общих параметра.

Использование будет выглядеть так:

procedure Foo is
   subtype My_Int is Integer range 1 .. 3;
   package My_Int_Record is new Int_Record (Number => My_Int);
   X : My_Int_Record.ABC;
begin
   X.A := 2; -- okay
   X.B := 4; -- error!
end Foo;

Answer 3

В Ada 2012 теперь у нас есть Dynamic_Predicate, с помощью которого мы можем наложить ограничения на подтипы следующим образом:

type ABC is record
    A : Integer;
    B : Integer;
  end record;

subtype XYZ is ABC
  with dynamic_predicate => 
  ((XYZ.A in Positive) and
   (XYZ.B not in Positive)) or else raise Constraint_Error;

Answer 4

Дано:

type ABC is record
   A : Integer;
   B : Integer;
end record;

Вы можете использовать:

type XYZ is record
   A : Positive;  -- A is subtype of ABC.A
   B : Natural;   -- B is subtype of ABC.B
end record;

  function convert(Input: ABC) return XYZ is
  begin
     return Result : XYZ:= ( A => Input.A, B => Input.B );
  -- Put your exception handling here.
  end convert;