Перегрузка оператора Delphi 'in' на множестве - PullRequest
Новая
       11

Перегрузка оператора Delphi 'in' на множестве

11 голосов
/ 08 ноября 2011

В Delphi XE2 я пытаюсь перегрузить оператор in для записи, чтобы я мог проверить, является ли значение, представленное записью, частью набора.Мой код выглядит так: 

type
  MyEnum = (value1, value2, value3);
  MySet = set of MyEnum;
  MyRecord = record
    Value: MyEnum;
    class operator In(const A: MyRecord; B: MySet): Boolean;
  end;

class operator MyRecord.In(const A: MyRecord; B: MySet): Boolean;
begin
  Result := A.Value in B;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  R: MyRecord;
  S: MySet;
begin
  R.Value := value1;
  S := [value1, value2];
  Button1.Caption := BoolToStr(R in S);
end;

Код не компилируется.Для оператора R in S компилятор говорит: Несовместимые типы MyRecord и MyEnum.

Как перегрузить оператор In на MyRecord, чтобы R in S оценил Trueв приведенном коде?

Ответы [ 2 ]

5 голосов
/ 08 ноября 2011

Чтобы оператор in работал, правильный операнд должен иметь тип записи, поскольку это оператор множества, а не бинарный оператор.В вашем случае это левый операнд.

Таким образом, будет работать следующее: 

type
  MyRecord = record
    Value: MyEnum;
    class operator In(const A: MyRecord; const B: MySet): Boolean;
  end;

  MyRecord2 = record
    Value: MySet;
    class operator In(const A: MyRecord; const B: MyRecord2): Boolean;
    class operator In(const A: MyEnum; const B: MyRecord2): Boolean;
  end;

class operator MyRecord.In(const A: MyRecord; const B: MySet): Boolean;
begin
  Result := A.Value in B;
end;

class operator MyRecord2.In(const A: MyRecord; const B: MyRecord2): Boolean;
begin
  Result := A.Value in B.Value;
end;

class operator MyRecord2.In(const A: MyEnum; const B: MyRecord2): Boolean;
begin
  Result := A in B.Value;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  R: MyRecord;
  R2: MyRecord2;
begin
  R.Value := value1;
  R2.Value := [value1, value2];

  if R in R2 then;
  if value1 in R2 then;
end;
1 голос
/ 09 ноября 2011

Ну, вы можете почти сделать это, но вы можете не захотеть.AFAIK, операторы класса работают только с тем классом (или записью), в котором они определены, поэтому и R, и S в вашем коде должны быть TMyRecord.При некотором неуместном использовании неявного приведения мы получаем следующее: 

unit Unit2;
interface
type
  MyEnum = (value1, value2, value3);
  MySet = set of MyEnum;
  MyRecord = record
    Value: MyEnum;
    ValueSet: MySet;
    class operator Implicit(A: MyEnum): MyRecord;
    class operator Implicit(A: MySet): MyRecord;
    class operator In (Left,Right:MyRecord): Boolean;
  end;

implementation

class operator MyRecord.Implicit(A: MyEnum): MyRecord;
begin
  Result.Value := A;
end;

class operator MyRecord.Implicit(A: MySet): MyRecord;
begin
  Result.ValueSet := A;
end;

class operator MyRecord.In(Left, Right: MyRecord): Boolean;
begin
  Result:= left.Value in Right.ValueSet;
end;
end.

Теперь скомпилируется и даже сработает следующее: 

procedure TForm1.Button1Click(Sender: TObject);
var
  R: MyRecord;
  S: MyRecord;
begin
  R.Value := value1;
  S := [value1,value2,value3];
  Button1.Caption := BoolToStr(R In S,true);
end;

Что, я уверен, мы все сделаемсогласитесь, гораздо элегантнее, чем «BoolToStr (R.Value в S)».Однако следующее также скомпилирует, но даст неверный результат: 

procedure TForm1.Button1Click(Sender: TObject);
var
  R: MyRecord;
  S: MyRecord;
begin
  R.Value := value1;
  S := [value1,value2,value3];
  Button1.Caption := BoolToStr(S In R,true);
end;

Так что, как прокомментировал Дорин, лучше просто оставить унылое, старое BoolToStr (R.Value в S).Если, конечно, вам платят за строку кода.И бонус за исправление ошибок.

...