Как загрузить и отобразить изображения TIFF в элементе управления TImage? - PullRequest
Новая
       12

Как загрузить и отобразить изображения TIFF в элементе управления TImage?

4 голосов
/ 21 октября 2011

В настоящее время я работаю над пробной версией Delphi XE2. Я хочу загружать и отображать изображения TIFF в элементе управления TImage без использования сторонних компонентов / библиотек.

Я попробовал приведенный ниже код, но он не проснулся для меня. 

Procedure TForm1.Button1Click(Sender: TObject); 
Var 
     OleGraphic               : TOleGraphic; 
     fs                       : TFileStream; 
     Source                   : TImage; 
     BMP                      : TBitmap; 
Begin 
     Try 
          OleGraphic := TOleGraphic.Create; 

          fs := TFileStream.Create('c:\testtiff.dat', fmOpenRead Or fmSharedenyNone); 
          OleGraphic.LoadFromStream(fs); 

          Source := Timage.Create(Nil); 
          Source.Picture.Assign(OleGraphic); 

          BMP := TBitmap.Create; 
          bmp.Width := Source.Picture.Width; 
          bmp.Height := source.Picture.Height; 
          bmp.Canvas.Draw(0, 0, source.Picture.Graphic); 

          image1.Picture.Bitmap := bmp;
     Finally 
          fs.Free; 
          OleGraphic.Free; 
          Source.Free; 
          bmp.Free; 
     End; 
End;

Пожалуйста, совет.

Ответы [ 3 ]

6 голосов
/ 21 октября 2011 
     tiff := TWICImage.Create;
     tiff.LoadFromFile(Filename);
     ABitmap.Assign(tiff);
4 голосов
/ 05 ноября 2015

Вы можете использовать GDI+: 

uses ..., ActiveX, GDIPAPI, GDIPOBJ, GDIPUTIL;

function LoadImageFromFile(const FileName: string; Bmp: TBitmap): Boolean;
var
  GPImage: TGPImage;
  encoderClsid: TGUID;
  MemStream: TMemoryStream;
begin
  Result := False;
  GPImage := TGPImage.Create(FileName);
  try
    if GPImage.GetLastStatus = Ok then
    begin
      MemStream := TMemoryStream.Create;
      try
        GetEncoderClsid('image/bmp', encoderClsid);
        if GPImage.Save(TStreamAdapter.Create(MemStream), encoderClsid) = Ok then
        begin
          MemStream.Position := 0;
          Bmp.LoadFromStream(MemStream);
          Result := True;
        end;
      finally
        MemStream.Free;
      end;
    end;
  finally
    GPImage.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  LoadImageFromFile('D:\ML_10222.tif', Image1.Picture.Bitmap);
end;

Я также хочу упомянуть Synopse TSynPicture (GDI + обертка): https://stackoverflow.com/a/6251810/937125

РЕДАКТИРОВАТЬ: GDI + TGPImage также поддерживает несколько кадров / страниц TIFF:

Чтобы получить количество кадров, используйте: 

GPImage.GetFrameCount(GDIPAPI.FrameDimensionPage);

Для установки активного кадра используйте: 

GPImage.SelectActiveFrame(GDIPAPI.FrameDimensionPage, Index);

Обратите внимание, что TSynPicture также поддерживает несколько кадров.

3 голосов
/ 22 октября 2011

Как сказано в моем комментарии, если расширение файла является стандартным расширением TIFF, код для открытия файла тривиален: 

image1.Picture.LoadFromFile(MyTiffFile);

Если нет, следуйте ответу dwrbudr.

Вот пример: 

procedure LoadBitmapFromFile( aImage : TImage; tiffFilename : String);
var
  tiffIm : TWICImage;
  ext : String;
begin
  ext := SysUtils.ExtractFileExt(tiffFilename);
  if (ext = '.tif') or (ext = '.tiff')
    then aImage.Picture.LoadFromFile(tiffFilename)
    else begin
      tiffIm:= TWICImage.Create;
      try
        tiffIm.LoadFromFile(tiffFilename);
        aImage.Picture.Bitmap.Assign(tiffIm);
      finally
        tiffIm.Free;
      end;
    end;
end;

См. Также TWICImage, который работает для XP SP3 и выше.

...