Позиционная группировка: xslt преобразование html - PullRequest
Новая
       1

Позиционная группировка: xslt преобразование html

2 голосов
/ 30 августа 2011

У меня есть следующий html-файл, и я хочу запустить преобразование, чтобы все теги h1, h2, h3 были преобразованы в соответствующие div.h2 всегда будет вложенным div для h1, и если есть 2 тега h2, у него должны быть собственные div.Точно так же h3 всегда будет вложенным делителем h2. 

<body>
   <p> this is a text</p>
   <a href="http://yahoo.com">click here</a>
   <h3>this is heading 3</h3>
   <p>text for heading 3</p>
    <h1>
      heading 1
   </h1>
     this is a text for heading 1
     <a href="link"> This is a link </a>
  <h2>
       this is heading 2

  </h2>
          this is a text for heading 2
  <h2>
          this is heading 2 again
  </h2>
         this is a text for heading 2 again
  </body>

"Вывод вышеупомянутого должен быть таким: 

<body>
   <p> this is a text</p>
   <a href="http://yahoo.com">click here</a>
   <div>
    <heading>this is heading 3</heading>
   <p>text for heading 3</p>
    <div>

 <div>
  <heading>
    heading 1
  </heading>
  this is a text for heading 1
  <a href="link"> This is a link </a>
  <div>
    <heading>
           this is heading 2
      </heading>
     this is a text for heading 2
 </div>
 <div>
    <heading>
          this is heading 2 again
    </heading>
          this is a text for heading 2 again
  </div>
</div>
</body>

Любая помощь будет оценена.в asp.net, но хочу преобразовать это в xslt.

1 Ответ

0 голосов
/ 30 августа 2011

Вот таблица стилей XSLT 2.0: 

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:mf="http://example.com/mf"
  exclude-result-prefixes="xs mf"
  version="2.0">

  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>

  <xsl:function name="mf:group" as="node()*">
    <xsl:param name="nodes" as="node()*"/>
    <xsl:param name="level" as="xs:integer"/>
    <xsl:param name="max-level" as="xs:integer"/>
    <xsl:choose>
      <xsl:when test="$level le $max-level">
        <xsl:for-each-group select="$nodes" group-starting-with="*[local-name() eq concat('h', $level)]">
          <xsl:choose>
            <xsl:when test="self::*[local-name() eq concat('h', $level)]">
              <div>
                <xsl:apply-templates select="."/>
                <xsl:sequence select="mf:group(current-group() except ., $level + 1, $max-level)"/>
              </div>
            </xsl:when>
            <xsl:otherwise>
              <xsl:apply-templates select="current-group()"/>
            </xsl:otherwise>
          </xsl:choose>
        </xsl:for-each-group>
      </xsl:when>
      <xsl:otherwise>
        <xsl:apply-templates select="$nodes"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:function>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@*, node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*[h1]">
    <xsl:copy>
      <xsl:sequence select="mf:group(node(), 1, 3)"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="h1 | h2 | h3">
    <heading>
      <xsl:apply-templates/>
    </heading>
  </xsl:template>

</xsl:stylesheet>

При применении с саксонским 9.3 ко входу 

<body>
 <h1>
    heading 1
 </h1>
     this is a text for heading 1
     <a href="link"> This is a link </a>
  <h2>
       this is heading 2

  </h2>
          this is a text for heading 2
  <h2>
          this is heading 2 again
  </h2>
         this is a text for heading 2 again
</body>

Я получаю следующий вывод 

<body>
   <div>
      <heading>
    heading 1
 </heading>
     this is a text for heading 1
     <a href="link"> This is a link </a>
      <div>
         <heading>
       this is heading 2

  </heading>
          this is a text for heading 2
  </div>
      <div>
         <heading>
          this is heading 2 again
  </heading>
         this is a text for heading 2 again
</div>
   </div>
</body>

Я не тестировал XSLT с другими более сложными входными данными, поэтому протестируйте себя и сообщите, если у вас возникнут какие-либо проблемы.

...