Как заполнить многоугольник цветом, отличным от границы?

Question

Мне нужно нарисовать многоугольник, который имеет граничные линии одним цветом, и залить интерьер другим цветом.Есть простой способ сделать это ?В настоящее время я рисую два полигона, один для цвета интерьера и 1 для границы.Я думаю, что должно быть лучше сделать это.Спасибо за вашу помощь.

       glColor3d (1, 1., .7);
        glPolygonMode(GL_FRONT_AND_BACK, GL_FILL);
        glBegin(GL_TRIANGLES);
                glVertex3f(-0.8f, 0.0f, 0.0f);
                glVertex3f(-0.6f, 0.0f, 0.0f);
                glVertex3f(-0.7f, 0.2f, 0.0f);
        glEnd();

        glPolygonMode(GL_FRONT_AND_BACK, GL_LINE);
        glColor3d (.5, .5, .7);
        glBegin(GL_TRIANGLES);
                glVertex3f(-0.8f, 0.0f, 0.0f);
                glVertex3f(-0.6f, 0.0f, 0.0f);
                glVertex3f(-0.7f, 0.2f, 0.0f);
        glEnd();

Спасибо всем за ответ на мой вопрос.Я довольно новичок в openGL и искал простой ответ на простой вопрос.Ответ, кажется, не так прост и, вероятно, может потребовать изучения семестра.

Answer 1

Более современный подход - реализовать это с помощью геометрических шейдеров. Это будет работать для OpenGL 3.2 и выше как часть основных функций или для OpenGL 2.1 с расширением GL_EXT_geometry_shader4.

Эта статья имеет всю соответствующую теорию: Каркасный чертеж на основе шейдера . Также приводится пример реализации простейшего метода в GLSL.

Вот мой собственный пример, в основном порт их реализации для OpenGL 3.3, ограниченный треугольными примитивами:

Вершинный шейдер: (замените входные данные тем, что вы используете для передачи данных вершин в матрицы m, v и p)

#version 330

layout(location = 0) in vec4 position;
layout(location = 1) in mat4 mv;

out Data
{
    vec4 position;
} vdata;

uniform mat4 projection;

void main()
{
    vdata.position = projection * mv * position;
}

Геометрия шейдера:

#version 330
layout(triangles) in;
layout(triangle_strip, max_vertices = 3) out;

in Data
{
    vec4 position;
} vdata[3];

out Data
{
    noperspective out vec3 dist;
} gdata;

void main()
{
    vec2 scale = vec2(500.0f, 500.0f); // scaling factor to make 'd' in frag shader big enough to show something
    vec2 p0 = scale * vdata[0].position.xy/vdata[0].position.w;
    vec2 p1 = scale * vdata[1].position.xy/vdata[1].position.w;
    vec2 p2 = scale * vdata[2].position.xy/vdata[2].position.w;

    vec2 v0 = p2-p1;
    vec2 v1 = p2-p0;
    vec2 v2 = p1-p0;
    float area = abs(v1.x*v2.y - v1.y*v2.x);

    gdata.dist = vec3(area/length(v0),0,0);
    gl_Position = vdata[0].position;
    EmitVertex();

    gdata.dist = vec3(0,area/length(v1),0);
    gl_Position = vdata[1].position;
    EmitVertex();

    gdata.dist = vec3(0,0,area/length(v2));
    gl_Position = vdata[2].position;
    EmitVertex();

    EndPrimitive();
}

Вершинный шейдер: (замените цвета тем, что вам нужно!)

#version 330

in Data
{
    noperspective in vec3 dist;
} gdata;

out vec4 outputColor;

uniform sampler2D tex;

const vec4 wireframeColor = vec4(1.0f, 0.0f, 0.0f, 1.0f);
const vec4 fillColor = vec4(1.0f, 1.0f, 1.0f, 1.0f);

void main()
{
    float d = min(gdata.dist.x, min(gdata.dist.y, gdata.dist.z));
    float I = exp2(-2*d*d);
    outputColor = mix(fillColor, wireframeColor, I);
}

Answer 2

Вы можете переключать режим заливки между полигонами, линиями и точками, используя glPolygonMode.

Чтобы нарисовать линии многоугольника другим цветом, вы можете сделать следующее:

glPolygonMode(GL_FRONT_AND_BACK,GL_FILL);
draw_mesh( fill_color );
glPolygonMode(GL_FRONT_AND_BACK,GL_LINE);
glEnable(GL_POLYGON_OFFSET_LINE);
glPolygonOffset(-1.f,-1.f);
draw_mesh( line_color );

Может потребоваться смещение линии, поскольку OpenGL не гарантирует, что края полигонов будут растеризованы точно в тех же пикселях, что и линии. Таким образом, без явного смещения вы можете и до линий, скрытых полигонами, из-за неудачного теста глубины.

Answer 3

Я думаю, вы должны увидеть этот ответ: Заполните и обведите

сначала нарисуйте свой треугольник, используя glPolygonMode (GL_FRONT_AND_BACK, GL_FILL) и используйте нужный цвет. затем нарисуйте треугольник снова, используя glPolygonMode (GL_FRONT_AND_BACK, GL_LINE) с использованием вашего цвета контура.

Answer 4

Есть 2 способа сделать это:

• тот, который вы делаете в данный момент (2 полигона, один немного больше другого или нарисованный после)

• текстура

Насколько мне известно, нет никаких других возможностей, и с точки зрения производительности эти 2 возможности, особенно первая, пока вы только цвета,очень быстро.