Как правильно передать параметр XSLT в XmlDataSource? - PullRequest
Новая
       21

Как правильно передать параметр XSLT в XmlDataSource?

0 голосов
/ 18 мая 2011

Я верю, что у меня весь код правильный, но я не могу заставить его работать. GridView имеет allowSorting = true. Таким образом, теоретически, когда я нажимаю на заголовок столбца, xml в сетке должен сортироваться по этому столбцу. XML отображается в GridView, но не сортируется вообще. Я в тупике.

DST_Test.Xml 

<?xml version="1.0" encoding="utf-8" ?>
<root>
    <data name="Test1.Text" xml:space="preserve">
        <value>Please Pick Bare Pump</value>
        <comment>Tab - Pump Configuration</comment>
    </data>
    <data name="Test2.Text" xml:space="preserve">
        <value>Complete</value>
        <comment>A07</comment>
    </data>
    <data name="Test3.Text" xml:space="preserve">
        <value>Confirmed</value>
        <comment>A01</comment>
    </data>
</root>

DataSrcTransform.xslt 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">

    <xsl:param name="sortby"></xsl:param>

    <xsl:output method="xml" indent="yes"/>

    <!--<xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>-->
    <xsl:template match="root">
        <root>
            <xsl:apply-templates select="data">
                <xsl:sort select="$sortby"/>
            </xsl:apply-templates>
        </root>
    </xsl:template>
    <xsl:template match="data">
        <data>
            <xsl:attribute name="ctrlname">
                <xsl:value-of select="@name"/>
            </xsl:attribute>
            <xsl:attribute name="value">
                <xsl:value-of select="value" />
            </xsl:attribute>
            <xsl:attribute name="comment">
                <xsl:value-of select="comment" />
            </xsl:attribute>
        </data>
    </xsl:template>
</xsl:stylesheet>

Код-за 

Protected Sub Page_PreRender(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.PreRender

        If Not IsPostBack Then
            XmlDataSource1.DataFile = "~/App_LocalResources/DST_Test.xml"
            XmlDataSource1.XPath = "//data"
            XmlDataSource1.TransformFile = xsltFileName
            GridView1.DataSource = XmlDataSource1
            GridView1.DataBind()
        End If
End Sub

Protected Sub GridView1_Sorting(ByVal sender As Object, ByVal e As GridViewSortEventArgs) Handles GridView1.Sorting

        Select Case e.SortExpression

            Case "ctrlname"
                sortAttr = "@name"
            Case "value"
                sortAttr = "value"
            Case "comment"
                sortAttr = "comment"
        End Select

        Dim xslTrnsform As System.Xml.Xsl.XsltArgumentList = New System.Xml.Xsl.XsltArgumentList
        xslTrnsform.AddParam("sortby", "", sortAttr)
        XmlDataSource1.EnableCaching = False
        XmlDataSource1.TransformArgumentList = xslTrnsform
        XmlDataSource1.DataFile = "~/App_LocalResources/DST_Test.xml"
        XmlDataSource1.XPath = "//data"
        XmlDataSource1.TransformFile = xsltFileName
        GridView1.DataSource = XmlDataSource1
        GridView1.DataBind()
End Sub

HTML 

<div>
            <asp:GridView ID="GridView1" runat="server"  AllowPaging="True" AllowSorting="True" 
                PageSize="25"
                AutoGenerateColumns="False">
                <Columns>
                    <asp:BoundField DataField="ctrlname" HeaderText="ctrlname" 
                        SortExpression="ctrlname" />
                    <asp:BoundField DataField="value" HeaderText="value" SortExpression="value" />
                    <asp:BoundField DataField="comment" HeaderText="comment" 
                        SortExpression="comment" />
                </Columns>
            </asp:GridView>
</div>
<asp:XmlDataSource ID="XmlDataSource1" runat="server">            
</asp:XmlDataSource>

1 Ответ

1 голос
/ 18 мая 2011

Я не знаю о других сторонах, но я уверен, что у вас есть проблема в XSL, которая неправильно сортирует данные. Попробуйте использовать этот XSL (по умолчанию сортировка по комментарию): 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">

    <xsl:output method="xml" indent="yes"/>

    <xsl:param name="sortby" select="'comment'"/>

    <xsl:template match="root">
        <root>
            <xsl:apply-templates select="data">
                <xsl:sort select="*[name()=$sortby]" order="ascending"/>
            </xsl:apply-templates>
        </root>
    </xsl:template>

    <xsl:template match="data">
        <data>
            <xsl:attribute name="ctrlname">
                <xsl:value-of select="@name"/>
            </xsl:attribute>
            <xsl:attribute name="value">
                <xsl:value-of select="value" />
            </xsl:attribute>
            <xsl:attribute name="comment">
                <xsl:value-of select="comment" />
            </xsl:attribute>
        </data>
    </xsl:template>
</xsl:stylesheet>

Отредактировано теперь, чтобы включить порядок сортировки в качестве параметра (по возрастанию): 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">

    <xsl:output method="xml" indent="yes"/>

    <xsl:param name="sortby" select="'comment'"/>
  <xsl:param name="order" select="'ascending'"/>

    <xsl:template match="root">
        <root>
            <xsl:apply-templates select="data">
                <xsl:sort select="*[name()=$sortby]" order="{$order}"/>
            </xsl:apply-templates>
        </root>
    </xsl:template>

    <xsl:template match="data">
        <data>
            <xsl:attribute name="ctrlname">
                <xsl:value-of select="@name"/>
            </xsl:attribute>
            <xsl:attribute name="value">
                <xsl:value-of select="value" />
            </xsl:attribute>
            <xsl:attribute name="comment">
                <xsl:value-of select="comment" />
            </xsl:attribute>
        </data>
    </xsl:template>
</xsl:stylesheet>

Пояснение:

  • *[name()=$sortby] выбирает все узлы-потомки, чье имя равно нашему параметру $sortby
  • order="{$order}" используется для установки значения атрибута заказа с помощью параметра. Значение может быть ascending или descending.

Обратите внимание, что сортировка выполняется по умолчанию, предполагая text тип данных.

...