Преобразование Xslt в xsl-fo - PullRequest
Новая
       2

Преобразование Xslt в xsl-fo

6 голосов
/ 25 февраля 2012

Я хочу сделать xslt-преобразование в xsl-fo, но я не совсем уверен, что смогу это сделать. Я пытаюсь преобразовать список XML в список xsl-fo. Может кто-нибудь сказать мне, где я могу искать, я гуглю в течение долгого времени, если примеров не так много. Мой XML такой: 

 <p>TEXT</p>
 <ul>
   <li>Item1</li>
   <li>Item2</li>
 </ul>
 <p>ANOTHERTEXT</p>

Я пытаюсь использовать шаблоны для этого преобразования, но мои шаблоны не работают, чтобы получить xsl-fo. Может кто-нибудь сказать мне, работают ли шаблоны в этом преобразовании. Если они работают, можете показать мне пример, я никого не найду. Моя цель - получить PDF-файл

Спасибо

Это часть моего XML-документа. Я получил некоторые части исходного кода в HTML, и теперь я изменяю HTML на XML, и сейчас пытаюсь преобразовать XML (без списка) в XSL-FO с помощью XSLT. Моя проблема в том, что я не могу применить шаблоны для этого преобразования. Моя последняя цель - получить PDF-файл FOP.

Спасибо

UPDATE

Это мой XML: 

<Memoria>
  <name>TITLE</name>
  <Index>INDEX 2010</Index>
  <Seccion>
     <name>INFORMATION</name>
     <Contenido>
       <p>TEXT</p>
       <ul>
     <li>ITEM1</li>
     <li>ITEM2</li>
      </ul>
      <p>ANOTHER</p>
    </Contenido>
  </Seccion>
</Memoria>

Я проверяю ваше решение Спасибо всем

Ответы [ 2 ]

6 голосов
/ 26 февраля 2012

Если у вас возникли проблемы с неработающими шаблонами, возможно, это проблема пространства имен.Вам следует обновить вопрос более точным примером вашего XML.

Вот пример.

Ввод XML (исправлено, чтобы быть правильно сформированным) 

<root>
  <p>TEXT</p>
  <ul>
    <li>Item1</li>
    <li>Item2</li>
  </ul>
  <p>ANOTHERTEXT</p>  
</root>

XSLT 1.0 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/root">
    <fo:root>
      <fo:layout-master-set>
        <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
          <fo:region-body margin="1in" margin-top="1.5in" margin-bottom="1.5in"/>
        </fo:simple-page-master>
      </fo:layout-master-set>
      <fo:page-sequence master-reference="my-page">
        <fo:flow flow-name="xsl-region-body">
          <xsl:apply-templates/>
        </fo:flow>
      </fo:page-sequence>
    </fo:root>
  </xsl:template>

  <xsl:template match="p">
    <fo:block>
      <xsl:apply-templates/>
    </fo:block>
  </xsl:template>

  <xsl:template match="ul">
    <fo:list-block padding="4pt">
      <xsl:apply-templates/>
    </fo:list-block>
  </xsl:template>

  <xsl:template match="li">
    <fo:list-item>
      <fo:list-item-label end-indent="label-end()">
        <fo:block>&#x02022;</fo:block>
      </fo:list-item-label>
      <fo:list-item-body start-indent="body-start()">
        <fo:block>
          <xsl:apply-templates/>
        </fo:block>
      </fo:list-item-body>
    </fo:list-item>    
  </xsl:template>
</xsl:stylesheet>

XSL-FO-вывод 

<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:layout-master-set>
      <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
         <fo:region-body margin="1in" margin-top="1.5in" margin-bottom="1.5in"/>
      </fo:simple-page-master>
   </fo:layout-master-set>
   <fo:page-sequence master-reference="my-page">
      <fo:flow flow-name="xsl-region-body">
         <fo:block>TEXT</fo:block>
         <fo:list-block padding="4pt">
            <fo:list-item>
               <fo:list-item-label end-indent="label-end()">
                  <fo:block>•</fo:block>
               </fo:list-item-label>
               <fo:list-item-body start-indent="body-start()">
                  <fo:block>Item1</fo:block>
               </fo:list-item-body>
            </fo:list-item>
            <fo:list-item>
               <fo:list-item-label end-indent="label-end()">
                  <fo:block>•</fo:block>
               </fo:list-item-label>
               <fo:list-item-body start-indent="body-start()">
                  <fo:block>Item2</fo:block>
               </fo:list-item-body>
            </fo:list-item>
         </fo:list-block>
         <fo:block>ANOTHERTEXT</fo:block>
      </fo:flow>
   </fo:page-sequence>
</fo:root>

Выход Apache FOP

enter image description here

0 голосов
/ 25 февраля 2012

Во-первых, убедитесь, что у вас есть файл xhtml (не так далее).Затем примените преобразование xslt для создания файла fo, затем передайте его в fop, и появится pdf.

Фрагмент стиля xslt fo: 

  <xsl:template match="html:body">
    <fo:page-sequence master-reference="all-pages">
      <fo:title>
        <xsl:value-of select="/html:html/html:head/html:title"/>
      </fo:title>
      <fo:static-content flow-name="page-header">
        <fo:block  font-weight="bold" font-size="16pt" space-before.conditionality="retain" xsl:use-attribute-sets="page-header"><!--  space-before="{$page-header-margin}"  -->
          <xsl:if test="$title-print-in-header = 'true'">
            <xsl:value-of select="/html:html/html:head/html:title"/>
          </xsl:if>
        </fo:block>
      </fo:static-content>
    </fo:page-sequence>
  </xsl:template>

Проверка http://www.w3schools.com/xslfo/default.asp для синтаксиса xslfo.

См. http://xmlgraphics.apache.org/fop/trunk/running.html для получения информации о запуске fop;загрузка fop.jar должна быть поблизости.

Запуск из vba, например, следующим образом: 

Set shell = CreateObject("WScript.Shell")
    cmd = "java -Dfop.home=" & baseDir & " -cp " & baseDir & "build\fop.jar org.apache.fop.cli.Main -fo " & foName & " -pdf " & pdfName
Call shell.Run(cmd, vbWindowFrame, True)

(аналогично командной строке)

...