пролог распечатать факт как цель или начальный

Question

Я новичок в прологе, и я хотел бы напечатать начальный и целевой факт, как показано ниже

initial([8,1,3,7,0,2,6,5,4]).

goal([1,2,3,8,0,4,7,6,5]).

=============

= 8 = 1 = 3 =

=============

= 7 = 0 = 2 =

=============

= 6 = 5 = 4 =

=============

Не могли бы вы помочь мне сделать это?

Answer 1

простой жестко закодированный способ:

pretty_print([A, B, C, D, E, F, G, H, I]) :-
    write(=============), nl, nl,
    write('= '), write(A), write(' = '), write(B), write(' = '), write(C), write(' ='), nl, nl,
    write(=============), nl, nl,
    write('= '), write(D), write(' = '), write(E), write(' = '), write(F), write(' ='), nl, nl,
    write(=============), nl, nl,
    write('= '), write(G), write(' = '), write(H), write(' = '), write(I), write(' ='), nl, nl,
    write(=============), nl, nl.

с форматом:

pretty_print(L) :-
    format('=============~n
= ~w = ~w = ~w =~n
=============~n
= ~w = ~w = ~w =~n
=============~n
= ~w = ~w = ~w =~n
=============', L).

с некоторой функциональной помощью:

length_(A, B) :- length(B, A).
pretty_print(L) :-
    length(Rows, 3),
    maplist(length_(3), Rows),
    append(Rows, L),
    maplist(format('=============~n~n= ~w = ~w = ~w =~n~n'), Rows),
    write(=============), nl.

с модулем лямбда :

pretty_print(L) :-
    length(Rows, 3),
    maplist(\X^length(X, 3), Rows),
    append(Rows, L),
    maplist(format('=============~n~n= ~w = ~w = ~w =~n~n'), Rows),
    write(=============), nl.

Использование:

?- initial(X), pretty_print(X).

или

?- goal(X), pretty_print(X).