Как я могу узнать, виден ли элемент управления Delphi в данный момент? - PullRequest
Новая
       24

Как я могу узнать, виден ли элемент управления Delphi в данный момент?

9 голосов
/ 14 марта 2009

Мне нужен способ, чтобы пользовательский элемент управления (произошедший от TCustomControl) мог определить, виден ли он в данный момент. Я не говорю о .Visible собственности; Я имею в виду, действительно ли это отображается на экране в данный момент. Кто-нибудь знает, как это сделать?

Ответы [ 3 ]

16 голосов
/ 16 марта 2009

Несколько лет назад у меня возникла такая же проблема с формой: я искал способ определить, действительно ли форма видна (даже частично) пользователю.
В частности, когда он должен был быть видимым, а Показ был Истинным, но окно фактически было полностью позади другого.
Вот код, он может быть адаптирован для WinControl ... 

{----------------------------------------------------------}
function IsMyFormCovered(const MyForm: TForm): Boolean;
var
   MyRect: TRect;
   MyRgn, TempRgn: HRGN;
   RType: Integer;
   hw: HWND;
begin
  MyRect := MyForm.BoundsRect;            // screen coordinates
  MyRgn := CreateRectRgnIndirect(MyRect); // MyForm not overlapped region
  hw := GetTopWindow(0);                  // currently examined topwindow
  RType := SIMPLEREGION;                  // MyRgn type

// From topmost window downto MyForm, build the not overlapped portion of MyForm
  while (hw<>0) and (hw <> MyForm.handle) and (RType <> NULLREGION) do
  begin
    // nothing to do if hidden window
    if IsWindowVisible(hw) then
    begin
      GetWindowRect(hw, MyRect);
      TempRgn := CreateRectRgnIndirect(MyRect);// currently examined window region
      RType := CombineRgn(MyRgn, MyRgn, TempRgn, RGN_DIFF); // diff intersect
      DeleteObject( TempRgn );
    end; {if}
    if RType <> NULLREGION then // there's a remaining portion
      hw := GetNextWindow(hw, GW_HWNDNEXT);
  end; {while}

  DeleteObject(MyRgn);
  Result := RType = NULLREGION;
end;

function IsMyFormVisible(const MyForm : TForm): Boolean;
begin
  Result:= MyForm.visible and
           isWindowVisible(MyForm.Handle) and
           not IsMyFormCovered(MyForm);
end;
2 голосов
/ 14 марта 2009

Не могли бы вы присоединить код к событию OnPaint? Это вызывается очень часто, и я думаю, что вызывается только тогда, когда элемент управления действительно будет нарисован (например, виден так, как вы хотите).

1 голос
/ 14 марта 2009

Я думаю, что именно для этого TWinControl.Showing. Я не уверен, насколько это надежно.

...