Как я могу получить доступ к локальным переменным каталога в моих основных режимах? - PullRequest
Новая
       43

Как я могу получить доступ к локальным переменным каталога в моих основных режимах?

9 голосов
/ 28 февраля 2011

Я определил файл .dir-locals.el со следующим содержимым: 

((python-mode . ((cr/virtualenv-name . "saas"))))

В моем .emacs у меня есть следующая функция для извлечения этого значения и предоставления пути virtualenv: 

(defun cr/virtualenv ()
  (cond (cr/virtualenv-name (format "%s/%s" virtualenv-base cr/virtualenv-name))
        ((getenv "EMACS_VIRTUAL_ENV") (getenv "EMACS_VIRTUAL_ENV"))
        (t "~/.emacs.d/python")))

Наконец, в моем списке подключений режима python у меня есть эта функция подключения: 

(add-hook 'python-mode-hook 'cr/python-mode-shell-setup)

(defun cr/python-mode-shell-setup ()
  (message "virtualenv-name is %s" cr/virtualenv-name)
  (let ((python-base (cr/virtualenv)))
    (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
           (setq python-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command-args '( "-colors" "NoColor")))
          (t
           (setq python-python-command (concat python-base "/bin/python"))
           (setq py-python-command (concat python-base "/bin/python"))
           (setq py-python-command-args nil)))))

Когда я открываю новый файл Python, сообщение, зарегистрированное cr/python-mode-shell-setup, указывает, что cr/virtualenv-name - это nil.Однако, когда я Ch v имя, вместо этого я получаю "saas".

Очевидно, здесь есть проблема порядка загрузки;Есть ли способ, чтобы мои операторы ловушки режима реагировали на локальные переменные каталога?

1 Ответ

16 голосов
/ 01 марта 2011

Это происходит потому, что normal-mode вызывает (set-auto-mode) и (hack-local-variables) в этом порядке.

Однако hack-local-variables-hook запускается после обработки локальных переменных, что позволяет использовать некоторые решения:

  1. Во-первых, Emacs должен запускать новую «ловушку локальных переменных» для каждого основного режима: 

    (add-hook 'hack-local-variables-hook 'run-local-vars-mode-hook)
(defun run-local-vars-mode-hook ()
  "Run a hook for the major-mode after the local variables have been processed."
  (run-hooks (intern (concat (symbol-name major-mode) "-local-vars-hook"))))

(add-hook 'python-mode-local-vars-hook 'cr/python-mode-shell-setup)

    (Ваша исходная функция может использоваться без изменений при таком подходе.)

  2. Второй вариант - использовать необязательный аргумент LOCAL для add-hook, который делает указанную функцию локальной для буфера.При таком подходе вы могли бы написать свой хук следующим образом: 

    (add-hook 'python-mode-hook 'cr/python-mode-shell-setup)

(defun cr/python-mode-shell-setup ()
  (add-hook 'hack-local-variables-hook
            (lambda () (message "virtualenv-name is %s" cr/virtualenv-name)
              (let ((python-base (cr/virtualenv)))
                (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
                       (setq python-python-command (concat python-base "/bin/ipython"))
                       (setq py-python-command (concat python-base "/bin/ipython"))
                       (setq py-python-command-args '( "-colors" "NoColor")))
                      (t
                       (setq python-python-command (concat python-base "/bin/python"))
                       (setq py-python-command (concat python-base "/bin/python"))
                       (setq py-python-command-args nil)))))
            nil t)) ; buffer-local hack-local-variables-hook

    т.е. python-mode-hook запускается первым и регистрирует анонимную функцию с помощью hack-local-variables-hook только для текущего буфера;и эта функция затем вызывается после обработки локальных переменных.

  3. Комментарий Lindydancer предлагает третий подход.Это не так чисто, как два других, но оказалось интересным независимо.Мне не понравилась идея вызова (hack-local-variables) дважды, но я вижу, что если вы установите буфер local-enable-local-variables локально, это помешает (hack-local-variables) делать что-либо, поэтому вы могли бы сделайте это: 

    (defun cr/python-mode-shell-setup ()
  (report-errors "File local-variables error: %s"
    (hack-local-variables)))
  (set (make-local-variable 'local-enable-local-variables) nil)
  (let ((python-base (cr/virtualenv)))
    ...))

    Очевидно, что это немного изменяет нормальную последовательность выполнения, поэтому возможны побочные эффекты.Меня беспокоило, что если тот же основной режим установлен локальной переменной comment в файле, это может привести к бесконечной рекурсии, но на самом деле это не проблема.

    Комментарии заголовка локальной переменной (например, -*- mode: foo -*-) обрабатываются (set-auto-mode), так что все в порядке;но комментарий mode: foo Local Variables: кажется, что это будет проблемой, так как он обрабатывается (hack-local-variables), и поэтому, если режим установлен таким образом, я думал, что это вызовет рекурсию.

    На практике ябыл в состоянии вызвать проблему, используя простую функцию в качестве «режима», которая не делала ничего, кроме попыток запустить свои ловушки;однако тестирование в «правильном» режиме не показало проблемы, так что это, вероятно, безопасно в реальности.Я не стал вдаваться в подробности (так как два других решения намного чище, чем этот), но я думаю, что механизм ловушек с отложенным режимом, вероятно, объясняет это?

...