Как сделать целочисленное (подписанное или беззнаковое) деление на ARM?

Question

Я работаю над Cortex-A8 и Cortex-A9 в частности.Я знаю, что некоторые архитектуры не имеют целочисленного деления, но как лучше всего это сделать, кроме как преобразовать в число с плавающей точкой, разделить, преобразовать в целое число?Или это действительно лучшее решение?

Ура!=)

Answer 1

Деление на постоянное значение выполняется быстро, например, путем умножения на 64 бита и сдвига вправо, например, так:

LDR     R3, =0xA151C331
UMULL   R3, R2, R1, R3
MOV     R0, R2,LSR#10

здесь R1 делится на 1625. Вычисление выполняется следующим образом: 64bitreg (R2: R3) = R1 * 0xA151C331, то в результате верхнее 32-битное правое смещение на 10:

R1*0xA151C331/2^(32+10) = R1*0.00061538461545751488 = R1/1624.99999980

Вы можете рассчитать свои собственные константы из этой формулы:

x / N ==  (x*A)/2^(32+n)   -->       A = 2^(32+n)/N

выберите наибольшее n, для которого A <2 ^ 32 </p>

Answer 2

Некоторые копии-макароны из другого места для целочисленного деления: в основном, 3 инструкции на бит.Со этого сайта, хотя я видел его и во многих других местах. На этом сайте также есть хорошая версия, которая в целом может быть быстрее.

@ Entry  r0: numerator (lo) must be signed positive
@        r2: deniminator (den) must be non-zero and signed negative
idiv:
        lo .req r0; hi .req r1; den .req r2
        mov hi, #0 @ hi = 0
        adds lo, lo, lo
        .rept 32 @ repeat 32 times
          adcs hi, den, hi, lsl #1
          subcc hi, hi, den
          adcs lo, lo, lo
        .endr
        mov pc, lr @ return
@ Exit   r0: quotient (lo)
@        r1: remainder (hi)

Answer 3

Компилятор обычно включает в свою библиотеку разделение, например, gcclib. Я извлек их из gcc и использую их напрямую:

https://github.com/dwelch67/stm32vld/, затем stm32f4d / adventure / gcclib

плавать и обратно, вероятно, не лучшее решение. Вы можете попробовать и посмотреть, как быстро это ... Это умножение, но можно легко разделить его:

https://github.com/dwelch67/stm32vld/, затем stm32f4d / float01 / vectors.s

Я не рассчитал время, чтобы увидеть, насколько быстро / медленно. Понятно, что я использую cortex-m выше, а вы говорите о cortex-a, разных концах спектра, аналогичных инструкциях с плавающей запятой и gcc lib. так же легко построить для руки. На самом деле с gcc все должно работать просто автоматически, вам не нужно делать это так, как я. Как и другим компиляторам, вам не нужно делать это так, как я делал это в описанной выше приключенческой игре.

Answer 4

Я написал свою собственную процедуру для выполнения неподписанного деления, поскольку я не мог найти неподписанную версию в Интернете. Мне нужно было разделить 64-битное значение на 32-битное, чтобы получить 32-битный результат.

Внутренний цикл не так эффективен, как приведенное выше решение со знаком, но он поддерживает арифметику без знака. Эта процедура выполняет 32-разрядное деление, если верхняя часть числителя (hi) меньше знаменателя (den), в противном случае выполняется полное 64-разрядное деление (hi: lo / den). Результат в lo.

  cmp     hi, den                   // if hi < den do 32 bits, else 64 bits
  bpl     do64bits
  REPT    32
    adds    lo, lo, lo              // shift numerator through carry
    adcs    hi, hi, hi
    subscc  work, hi, den           // if carry not set, compare        
    subcs   hi, hi, den             // if carry set, subtract
    addcs   lo, lo, #1              // if carry set, and 1 to quotient
  ENDR

  mov     r0, lo                    // move result into R0
  mov     pc, lr                    // return

do64bits:
  mov     top, #0
  REPT    64
    adds    lo, lo, lo              // shift numerator through carry
    adcs    hi, hi, hi
    adcs    top, top, top
    subscc  work, top, den          // if carry not set, compare        
    subcs   top, top, den           // if carry set, subtract
    addcs   lo, lo, #1              // if carry set, and 1 to quotient
  ENDR
  mov     r0, lo                    // move result into R0
  mov     pc, lr                    // return

Может быть добавлена ​​дополнительная проверка граничных условий и степени 2. Полную информацию можно найти на http://www.idwiz.co.za/Tips%20and%20Tricks/Divide.htm

Answer 5

Я написал следующие функции для ARM GNU ассемблера.Если у вас нет ЦП с поддержкой компьютера udiv/sdiv, просто отрежьте первые несколько строк до метки «0:» в любой функции.

.arm
.cpu    cortex-a7
.syntax unified

.type   udiv,%function
.globl  udiv
udiv:   tst     r1,r1
        bne     0f
        udiv    r3,r0,r2
        mls     r1,r2,r3,r0
        mov     r0,r3
        bx      lr
0:      cmp     r1,r2
        movhs   r1,r2
        bxhs    lr
        mvn     r3,0
1:      adds    r0,r0
        adcs    r1,r1
        cmpcc   r1,r2
        subcs   r1,r2
        orrcs   r0,1
        lsls    r3,1
        bne     1b
        bx      lr
.size   udiv,.-udiv

.type   sdiv,%function
.globl  sdiv
sdiv:   teq     r1,r0,ASR 31
        bne     0f
        sdiv    r3,r0,r2
        mls     r1,r2,r3,r0
        mov     r0,r3
        bx      lr
0:      mov     r3,2
        adds    r0,r0
        and     r3,r3,r1,LSR 30
        adcs    r1,r1
        orr     r3,r3,r2,LSR 31
        movvs   r1,r2
        ldrvc   pc,[pc,r3,LSL 2]
        bx      lr
        .int    1f
        .int    3f
        .int    5f
        .int    11f
1:      cmp     r1,r2
        movge   r1,r2
        bxge    lr
        mvn     r3,1
2:      adds    r0,r0
        adcs    r1,r1
        cmpvc   r1,r2
        subge   r1,r2
        orrge   r0,1
        lsls    r3,1
        bne     2b
        bx      lr
3:      cmn     r1,r2
        movge   r1,r2
        bxge    lr
        mvn     r3,1
4:      adds    r0,r0
        adcs    r1,r1
        cmnvc   r1,r2
        addge   r1,r2
        orrge   r0,1
        lsls    r3,1
        bne     4b
        rsb     r0,0
        bx      lr
5:      cmn     r1,r2
        blt     6f
        tsteq   r0,r0
        bne     7f
6:      mov     r1,r2
        bx      lr
7:      mvn     r3,1
8:      adds    r0,r0
        adcs    r1,r1
        cmnvc   r1,r2
        blt     9f
        tsteq   r0,r3
        bne     10f
9:      add     r1,r2
        orr     r0,1
10:     lsls    r3,1
        bne     8b
        rsb     r0,0
        bx      lr
11:     cmp     r1,r2
        blt     12f
        tsteq   r0,r0
        bne     13f
12:     mov     r1,r2
        bx      lr
13:     mvn     r3,1
14:     adds    r0,r0
        adcs    r1,r1
        cmpvc   r1,r2
        blt     15f
        tsteq   r0,r3
        bne     16f
15:     sub     r1,r2
        orr     r0,1
16:     lsls    r3,1
        bne     14b
        bx      lr

Есть две функции, udiv для целочисленного деления без знака и sdiv для целочисленного деления со знаком.Они оба ожидают 64-битного дивиденда (со знаком или без знака) в r1 (старшее слово) и r0 (младшее слово) и 32-битный делитель в r2.Они возвращают частное в r0 и остаток в r1, таким образом, вы можете определить их в C header как extern, возвращающее 64-битное целое число, и затем замаскировать частное и остаток.Ошибка (деление на 0 или переполнение) указывается остатком, имеющим абсолютное значение, большее или равное абсолютному значению делителя.Алгоритм деления со знаком использует различение регистра по признакам как дивиденд, так и делитель;сначала он не преобразуется в положительные целые числа, поскольку это не может правильно определить все условия переполнения.