Как выполнить код Javascript из Groovy и получить результаты в виде карты? - PullRequest
Новая
       27

Как выполнить код Javascript из Groovy и получить результаты в виде карты?

3 голосов
/ 14 июня 2011

Как я могу получить результаты выполненного JavaScript-кода из Groovy?Я попробовал следующее, но я всегда получаю строку «мир».Я бы ожидал объект или карту. 

import javax.script.ScriptEngineManager
import javax.script.SimpleBindings

def manager = new ScriptEngineManager()
manager.getEngineByName("JavaScript").eval("""
    {hello: name}
""", [name:'world'] as SimpleBindings)

Ответы [ 2 ]

3 голосов
/ 13 декабря 2016

Легко!

Вы можете сопоставить объект с переменной и вернуть это ... 

import javax.script.*

def bindings = [name:'world']

def response = new ScriptEngineManager()
    .getEngineByName('javascript')
    .eval("var r = {hello:name}; r;", bindings as SimpleBindings)

println response.hello // -> world

Или вы можете отслеживать response объект карты и обновитьчто ... 

import javax.script.*

def bindings = [name:'world',response:[:]]

new ScriptEngineManager()
    .getEngineByName('javascript')
    .eval("var r = {hello:name}; response.data = r;", bindings as SimpleBindings)

println bindings.response.data.hello // -> world

Отличная версия: 2.4.5

Версия Java: 1.8.0_60

2 голосов
/ 14 июня 2011

Это немного сложно (и единственное решение, которое я могу найти, - это использовать внутренний класс sun.com): - / 

import javax.script.ScriptEngineManager
import javax.script.SimpleBindings
import sun.org.mozilla.javascript.internal.NativeObject

// A Category to parse NativeObject into a Map
class NativeObjectParser {
  static Map asMap( NativeObject jsobj ) {
    jsobj.allIds.inject( [:] ) { map, key ->
      def value = jsobj.get( key, jsobj )
      // Handle nested maps
      map << [ (key):value instanceof NativeObject ? value.asMap() : value ]
    }
  }
}

// Your code as you had it before (apart from the JS defines a var, and returns that var object)
def manager = new ScriptEngineManager()
def ret = manager.getEngineByName("JavaScript").eval("""
    var r = { 'hello': name }
    r
""", [ name:'world' ] as SimpleBindings )

// Do the unwrapping
def map = use( NativeObjectParser ) {
  ret.asMap()
}

println map

Это распечатывает: 

[hello:world]

Не чувствует себя очень чистым способом выполнения действий (и, вероятно, потребует некоторой работы, если у вас есть карта массивов, например)

Но лучшее, что я могу найти: - /

...