Perl вычисляет средние оценки для любого файла, начинающегося с "class"

Question

Я пишу Perl-скрипт для домашней работы, который принимает любые файлы, начинающиеся с «class», и распечатывает название класса и среднее значение для каждого ученика в файле.

INPUT:

$cat class1
Sam 90, 95, 82
Max 88, 90, 86
Alex 85, 92, 90
$cat class2
Student1 87, 91, 86
Student2 84, 89, 88
Student3 84, 90, 93

ВЫВОД:

*****class1*****
Sam: 89
Max: 88
Alex: 89
*****class2*****
Student1: 88
Student2: 87
Student3: 89

Текущая попытка в сценарии:

#!/usr/bin/perl

@gradefiles = <class*>;

foreach (@gradefiles){
    print "****".$_."****\n";
    my %grades;
    my %average;
    open(DATA, $_) || die "Can't open $_: $!\n";
    while (<DATA>){
            my ($student, @vals) = split(/\t/);
            $grades{$student} = \@vals;
    }
    keys %grades;
    while(my($k, $v) = each %grades){
            my @igrades = split(',',$v);
            my $total = 0;
            foreach (@igrades){
                    $total += $_;
            }
            my $length = @igrades;
            my $avg = $total / $length;

            $average{$k} = \$avg;
    }

    keys %average;
    while(my($k, $v) = each %average){
            print $k." ".$v."\n";
    }
}

ТЕКУЩИЙ ВЫХОД:

****class1****
Sam 90, 95, 82
SCALAR(0x2036100)
Alex 85, 92, 90
SCALAR(0x202ab38)
Max 88, 90, 86
SCALAR(0x2034710)
****class2****
Student3 84, 90, 93
SCALAR(0x2034740)
Student2 84, 89, 88
SCALAR(0x2034728)
Student1 87, 91, 86
SCALAR(0x202a298)

===== UPDATE ==== мой новый код

    #!/usr/bin/perl

@gradefiles = <class*>;

foreach (@gradefiles){
    print "****".$_."****\n";
    my %grades;
    my %average;
    open(DATA, $_) || die "Can't open $_: $!\n";
    while (<DATA>){
            my ($student, @vals) = split(/\t/);
            $grades{$student} = @vals;
    }

    for my $name (keys %grades){
            my @igrades = split(',',$grades{$name});
            my $total = 0;
            for my $grade (@igrades){
                    $total += $grade;
            }
            my $length = @igrades;
            my $avg = $total / $length;

            $average{$name} = $avg;
    }

    for my $name (keys %average){
            print $name.": ".$average{$name}."\n";
    }
}

Мой новый вывод:

****class1****
Sam 90, 95, 82
: 0
Alex 85, 92, 90
: 0
Max 88, 90, 86
: 0
****class2****
Student3 84, 90, 93
: 0
Student2 84, 89, 88
: 0
Student1 87, 91, 86
: 0

РАБОЧИЙ СЦЕНАРИЙ

 #!/usr/bin/perl

@gradefiles = <class*>;

foreach (@gradefiles){
    print "****".$_."****\n";
    my %grades;
    my %average;
    open(DATA, $_) || die "Can't open $_: $!\n";
    while (<DATA>){
            my ($student, $vals) = split(/\t/);
            $grades{$student} = $vals;
    }

    for my $name (keys %grades){
            my @igrades = split(',',$grades{$name});
            my $total = 0;

            for my $grade (@igrades){
                    $total += $grade;
            }
            my $length = @igrades;

            my $avg = $total / $length;

            $average{$name} = $avg;
    }

    for my $name (keys %average){
            print $name.": ".$average{$name}."\n";
    }
}

Answer 1

Я думаю, вы несколько усложняете ситуацию.Вам не нужны никакие хеши, которые вы создаете.

#!/usr/bin/perl

use strict;
use warnings;
use 5.010; # For 'say'

foreach my $class (<class*>) {
  say "****$class****";

  # Three-arg open, lexical filehandle. Modern Perl best practice    
  open my $data, '<', $class or die "Can't open $class: $!\n";

  while (<$data>) {
    my ($student, @data) = split /[\s,]+/;
    say "$student: ", avg(@data);
  }
}

sub avg {
  my $total;
  $total += $_ for @_;

  return $total / @_;
}

Answer 2

Вы делаете это:

$average{$k} = \$avg;

Который хранит ссылку на скаляр. Таким образом, когда вы печатаете $average{$k}, вы распечатываете ссылку на скаляр, который равен SCALAR(0x202a298). Измените строку на:

$average{$k} = $avg;

... и все должно работать.