XSLT группа на полчаса - PullRequest
Новая
       38

XSLT группа на полчаса

4 голосов
/ 19 февраля 2011

Учитывая этот XML: 

<root>
  <row>
    <time>08:00</time>
    <sales>800</sales>
  </row>
  <row>
    <time>08:15</time>
    <sales>815</sales>
  </row>
  <row>
    <time>08:30</time>
    <sales>830</sales>
  </row>
  <row>
    <time>08:45</time>
    <sales>845</sales>
  </row>
  <row>
    <time>11:00</time>
    <sales>1100</sales>
  </row>
  <row>
    <time>11:45</time>
    <sales>1145</sales>
  </row>
  <row>
    <time>14:15</time>
    <sales>1415</sales>
  </row>
  <row>
    <time>14:30</time>
    <sales>1430</sales>
  </row>
</root>

Я пытаюсь найти способ преобразования XSLT, суммируя продажи с 30-минутными интервалами.Я могу суммировать по часовым интервалам по 60 минут, используя метод MUENCHIAN, но я не могу использовать его в течение 30 минут, так как для этого мне нужна пользовательская функция (но я не могу использовать XSLT 2.0 или пользовательские функции .Net).Пожалуйста, помогите!

Ожидаемый результат такой: 

30 minute
08:00 $1600  
08:30 $1675 
11:00 $1100 
11:30 $1145 
14:00 $1415 
14:30 $1430

Ответы [ 2 ]

6 голосов
/ 19 февраля 2011

Решение 1.

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="krowsInHalfHour" match=
  "row[not((substring-after(time,':')+30) mod 30 = 0)]"
  use="generate-id(
        preceding-sibling::row
          [60*substring-before(time,':')
          +
           substring-after(time,':')
          >=
           60*substring-before(current()/time,':')
          +
           substring-after(current()/time,':')

          -
           substring-after(current()/time,':') mod 30

          ]
             [1]
                   )
  "/>

 <xsl:template match=
  "row[(substring-after(time,':')+30) mod 30 = 0
     or
      not(
       60*substring-before(preceding-sibling::row[1]/time,':')
          +
           substring-after(preceding-sibling::row[1]/time,':')
       >=
          60*substring-before(time,':')
          +
           substring-after(time,':')

          -
           substring-after(time,':') mod 30
          )
      ]
  ">
  <xsl:variable name="vPrevStartMins" select=
  "60*substring-before(time,':')
  +
   substring-after(time,':')

  -
   substring-after(time,':') mod 30
  "/>
  <xsl:value-of select=
   "concat('&#xA;',floor($vPrevStartMins div 60),
           ':', concat(substring('0',($vPrevStartMins mod 60 >0)+1),
                       $vPrevStartMins mod 60
                       )
           )
   "/>
  <xsl:text> $</xsl:text>
  <xsl:value-of select=
  "sum(sales
      |
       key('krowsInHalfHour',generate-id())/sales)"/>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

при применении к предоставленному документу XML: 

<root>
    <row>
        <time>08:00</time>
        <sales>800</sales>
    </row>
    <row>
        <time>08:15</time>
        <sales>815</sales>
    </row>
    <row>
        <time>08:30</time>
        <sales>830</sales>
    </row>
    <row>
        <time>08:45</time>
        <sales>845</sales>
    </row>
    <row>
        <time>11:00</time>
        <sales>1100</sales>
    </row>
    <row>
        <time>11:45</time>
        <sales>1145</sales>
    </row>
    <row>
        <time>14:15</time>
        <sales>1415</sales>
    </row>
    <row>
        <time>14:30</time>
        <sales>1430</sales>
    </row>
</root>

дает требуемый, правильный результат: 

8:00 $1615
8:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

Решение 2 : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" >
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <my:halfHours>
  <t>00:00</t><t>00:30</t><t>01:00</t><t>01:30</t>
  <t>02:00</t><t>02:30</t><t>03:00</t><t>03:30</t>
  <t>04:00</t><t>04:30</t><t>05:00</t><t>05:30</t>
  <t>06:00</t><t>06:30</t><t>07:00</t><t>07:30</t>
  <t>08:00</t><t>08:30</t><t>09:00</t><t>09:30</t>
  <t>10:00</t><t>10:30</t><t>11:00</t><t>11:30</t>
  <t>12:00</t><t>12:30</t><t>13:00</t><t>13:30</t>
  <t>14:00</t><t>14:30</t><t>15:00</t><t>15:30</t>
  <t>16:00</t><t>16:30</t><t>17:00</t><t>17:30</t>
  <t>18:00</t><t>18:30</t><t>19:00</t><t>19:30</t>
  <t>20:00</t><t>20:30</t><t>21:00</t><t>21:30</t>
  <t>22:00</t><t>22:30</t><t>23:00</t><t>23:30</t>
  <t>24:00</t>
 </my:halfHours>

 <xsl:variable name="vhalfHrs" select=
  "document('')/*/my:halfHours/*"/>

 <xsl:template match="row">
  <xsl:variable name="vStart" select=
  "$vhalfHrs[translate(.,':','')
            >
             translate(current()/time,':','')
             ][1]
                 /preceding-sibling::*[1]
  "/>

  <xsl:variable name="vprecRow" select=
   "preceding-sibling::*[1]"/>

  <xsl:if test=
   "not(translate($vprecRow/time,':','')
       >=
       translate($vStart,':','')
       )">
   <xsl:value-of select="concat('&#xA;',$vStart, ' $')"/>
   <xsl:value-of select=
   "sum(sales|following-sibling::*
          [not(translate(time,':','')
              >=
               translate($vStart/following-sibling::*,':','')
               )
          ]
            /sales
        )
   "/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразованиеПрименительно к тому же XML-документу снова будет получен нужный, правильный результат : 

08:00 $1615
08:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

Объяснение :

  1. Впеременная $vhalfHrs содержит элементы, значения которых являются временем начала каждого получасового периода в течение дня.

  2. В шаблоне, который соответствует каждому row, переменная $vStartустанавливается в это получасовое время запуска, в которое попадает time текущего узла (row).

  3. Переменная $vprecRow устанавливается впредыдущий брат (row) текущего row.

  4. Если время предыдущего row не позднее времени начала полчаса (в $vStart ), then the current row` - это файлпервый в этом получасовом периоде.

  5. Мы выводим время начального получасового периода.

  6. Мы вычисляем и выводим суммувсе элементы row, для которых time находится в тот же период получаса.Они следуют за братьями и сестрами текущего row, и их time не больше и не равно началу следующего получасового периода.

Решение 3 (XSLT 2.0): 

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output method="text"/>

 <xsl:template match="/*">
  <xsl:for-each-group select="row" group-adjacent=
  "(xs:integer(substring-before(time,':'))*60
   +
    xs:integer(substring-after(time,':'))
    )
    idiv 30
  ">
   <xsl:variable name="vStartMinutes"
        select="current-grouping-key()*30"/>
   <xsl:value-of separator="" select=
   "'&#xA;',
     format-number($vStartMinutes idiv 60, '00'), ':',
     format-number($vStartMinutes mod 60,'00'),
     ' $',
     sum(current-group()/sales/xs:integer(.))
   "/>
  </xsl:for-each-group>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к тому же XML-документу, что и выше,требуется тот же самый, правильный результат : 

08:00 $1615
08:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

Пояснение :

  1. Мы используем <xsl:for-each-group>с атрибутом group-adjacent , установленным как выражение, вычисляющее положение периода 1/2 часа, в котором находится row/time.

  2. Интенсивное использование стандартных функций current-group() и current-grouping-key().

3 голосов
/ 19 февраля 2011

Без предшествующей оси эта таблица стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kRowByHalfHour"
             match="row"
             use="floor((substring(time,1,2)*60+substring(time,4))div 30)"/>
    <xsl:template match="row[count(.|key('kRowByHalfHour',
                                         floor((substring(time,1,2) * 60
                                                 + substring(time,4)) div 30)
                                     )[1]
                             )=1
                         ]">
        <xsl:variable name="vKey"
             select="floor((substring(time,1,2)*60+substring(time,4))div 30)"/>
        <xsl:value-of
             select="concat(format-number(floor($vKey * 30 div 60),'00'),':',
                            format-number(($vKey * 30) mod 60,'00'),' $',
                            sum(key('kRowByHalfHour',$vKey)/sales),'&#xA;'
                     )"/>
    </xsl:template>
    <xsl:template match="text()"/>
</xsl:stylesheet>

Выход: 

08:00 $1615
08:30 $1675
11:00 $1100
11:30 $1145
14:00 $1415
14:30 $1430

Редактировать 2 : Еще лучшее значение ключа с нормализованным временем, позволяющим параметризацию (с помощью функции document() или двухфазного преобразования): если мы возьмем вычисление ключа в качестве меры сложности, это будет O (N)

...