Как я могу интегрировать все тексты из столбца в форме в текстовом поле Microsoft Access VBA MS-доступ

Question

как я могу интегрировать все тексты из столбца в форме в текстовое поле?

этот код может добавить весь текст из таблицы в текстовое поле в форме

Set db = CurrentDb
Set rs = db.OpenRecordset("names")
For i = 1 To rs.RecordCount

text1.SetFocus
text1.Text = text1.Text & " " & rs(1)

rs.MoveNext

Next i

Есть ли способ добавить весь текст из полей в форме в текстовое поле в той же форме?

Answer 1

Замените ваш sub com1_Click следующим блоком. Надеюсь это поможет . , ,

Private Sub com1_Click()
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim strNames As String
    Dim strSQL As String

    ' Following line gets the query of the form
    strSQL = Me.RecordSource
    ' Alternatively, you can replace this line with your own select query
    ' For eg.
    ' strSQL = "Select * from Table1 Where [_ID] In (1,2)"


    Set db = CurrentDb
    Set rs = db.OpenRecordset(strSQL)

    strNames = ""

    'Following loop is for going through all the records
    While Not rs.EOF
        'Following line is for collecting values of Name1 Field of your table
        strNames = strNames & " " & rs("Name1")
        rs.MoveNext
    Wend

    ' Populating the textbox with values collected from your table
    text3 = Trim(strNames)

    ' Final cleanup
    rs.Close
    Set rs = Nothing
    Set db = Nothing
End Sub

Answer 2

Переберите все элементы управления в форме и поместите его в строковую переменную (или текстовое поле).

Dim cControl As Control
Dim sNames As String
sNames = ""
For Each cControl In Me.Controls
    If TypeName(cControl) = "TextBox" Then
        sNames = sNames + " " + cControl
    End If
Next cControl