сортировка массива по первому числу, найденному в каждом элементе

Question

Я ищу помощь в сортировке массива, где каждый элемент состоит из «числа, затем строки, затем числа».Я бы хотел отсортировать по первой части числа элементов массива по убыванию (чтобы я сначала перечислил более высокие числа), а также перечислить текст и т. Д.

все еще новичок, поэтому альтернативытакже добро пожаловать

use strict;
use warnings;

my @arr = map {int( rand(49) + 1) } ( 1..100 ); # build an array of 100 random numbers between 1 and 49

my @count2;

foreach my $i (1..49) {

    my @count = join(',', @arr) =~ m/$i,/g; # maybe try to make a string only once then search trough it... ???
my $count1 = scalar(@count); # I want this $count1 to be the number of times each of the numbers($i) was found within the string/array.

    push(@count2, $count1 ." times for ". $i); # pushing a "number then text and a number / scalar, string, scalar" to an array.
}

#for (@count2) {print "$_\n";}
# try to add up all numbers in the first coloum to make sure they == 100

 #sort @count2 and print the top 7
@count2 = sort {$b <=> $a} @count2; # try to stop printout of this, or sort on =~ m/^anumber/ ??? or just on the first one or two \d

foreach my $i (0..6) {
 print $count2[$i] ."\n"; # seems to be sorted right anyway
}

Answer 1

Принимая ваши требования как есть. Вам, вероятно, лучше не встраивать информацию о количестве в строку. Однако я приму это как учебное упражнение.

Обратите внимание, я торгую память для краткости и вероятной скорости, используя хэш для подсчета.

Однако сортировку можно оптимизировать с помощью преобразования Шварца .

РЕДАКТИРОВАТЬ: создать массив результатов, используя только цифры, которые были нарисованы

#!/usr/bin/perl

use strict; use warnings;

my @arr = map {int( rand(49) + 1) } ( 1..100 );

my %counts;
++$counts{$_} for @arr;

my @result = map sprintf('%d times for %d', $counts{$_}, $_),
             sort {$counts{$a} <=> $counts{$b}} keys %counts;

print "$_\n" for @result;

Однако я бы, наверное, сделал что-то вроде этого:

#!/usr/bin/perl

use strict; use warnings;
use YAML;

my @arr;
$#arr = 99; #initialize @arr capacity to 100 elements 

my %counts;

for my $i (0 .. 99) {
    my $n = int(rand(49) + 1); # pick a number
    $arr[ $i ] = $n;           # store it
    ++$counts{ $n };           # update count
}

# sort keys according to counts, keys of %counts has only the numbers drawn
# for each number drawn, create an anonymous array ref where the first element
# is the number drawn, and the second element is the number of times it was drawn
# and put it in the @result array

my @result = map  [$_, $counts{$_}],
             sort {$counts{$a} <=> $counts{$b} }
             keys %counts;

print Dump \@result;

Answer 2

Сначала сохраните ваши данные в массиве, а не в строке:

# inside the first loop, replace your line with the push() with this one:
push(@count2, [$count1, $i]; 

Затем вы можете легко отсортировать по первому элементу каждого подмассива:

my @sorted = sort { $b->[0] <=> $a->[0] } @count2;

А когда вы ее напечатаете, создайте строку:

printf "%d times for %d\n", $sorted[$i][0], $sorted[$i][1];

См. Также: http://perldoc.perl.org/perlreftut.html, perlfaq4