создание хеша из переменных для использования в Perl JSON кодирования / декодирования

Question

Я пытаюсь создать тестовый модуль для проверки кодировки JSON. у меня возникли проблемы с созданием переменных, которые будут правильно выводиться с JSON кодирования / декодирования. если я использую только $ cat_1 в массиве @cats, он будет работать нормально. однако, используя оба, он выводит «HASH (...», как вы можете видеть ниже.

use strict;
use JSON;
use Data::Dump qw( dump );

my $cat_1 = {'name' => 'cat1', 'age' => '6', 'weight' => '10 kilos', 'type' => 'siamese'};
my $cat_2 = {'name' => 'cat2', 'age' => '10', 'weight' => '13 kilos', 'type' => 'siamese'};

my @cats;
push(@cats, $cat_1);
push(@cats, $cat_2);

my $dog_1 = {'name' => 'dog1', 'age' => '7', 'weight' => '20 kilos', 'type' => 'siamese'};
my $dog_2 = {'name' => 'dog2', 'age' => '5', 'weight' => '15 kilos', 'type' => 'siamese'};

my @dogs;
push(@dogs, $dog_1);
push(@dogs, $dog_2);

my $pets = {'cats' => @cats, 'dogs' => @dogs};

my $a = { 'id' => '123',    'name' => 'Joe Smith',  'city' => "Chicago", 'pets' => $pets    };

my $json = JSON->new->allow_nonref;
my $encoded = $json->encode($a);
my $decoded = $json->decode( $encoded );

print "\ndump cat_1\n";
dump $cat_1;
print "\ndump cats\n";
dump @cats;

print "\n\nOriginal\n";
dump $a;
print "\n\n";

print "Encoded\n";
print $encoded;
print "\n\n";

print "Decoded\n";
dump $decoded;
print "\n\n";

выход

dump cat_1
{ age => 10, name => "cat1", type => "siamese", weight => "10 kilos" }

dump cats
(
  { age => 10, name => "cat1", type => "siamese", weight => "10 kilos" },
  { age => 10, name => "cat2", type => "siamese", weight => "3 kilos" },
)


Original
{
  city => "Chicago",
  id => 123,
  name => "Joe Smith",
  pets => {
    "cats" => { age => 10, name => "cat1", type => "siamese", weight => "10 kilos" },
    "HASH(0x176c3170)" => "dogs",
    "HASH(0x1785f2d0)" => { age => 10, name => "dog2", type => "siamese", weight => "3 kilos" },
  },
}


Encoded
{"city":"Chicago","pets":{"HASH(0x1785f2d0)":{"weight":"3     kilos","name":"dog2","type":"siamese","age":"10"},"cats":{"weight":"10 kilos","name":"cat1","type":"siamese","age":"10"},"HASH(0x176c3170)":"dogs"},"name":"Joe Smith","id":"123"}

Decoded
{
  city => "Chicago",
  id => 123,
  name => "Joe Smith",
  pets => {
    "cats" => { age => 10, name => "cat1", type => "siamese", weight => "10 kilos" },
    "HASH(0x176c3170)" => "dogs",
    "HASH(0x1785f2d0)" => { age => 10, name => "dog2", type => "siamese", weight => "3     kilos" },
  },
}

Answer 1

Эта строка

my $pets = {'cats' => @cats, 'dogs' => @dogs};

- это красный флаг.Это действительно Perl, но он не делает то, что вы ожидаете.Perl сгладит ваши списки в этой конструкции, поэтому, если @cats содержит ($cat_1,$cat_2) и @dogs содержит ($dog_1,$dog_2), ваше выражение будет проанализировано как

my $pets = { 'cats', $cat_1, $cat_2, 'dogs', $dog_1, $dog_2 };

, что похоже на

my $pets = { 'cats' => $cat_1, $cat_2 => 'dogs', $dog_1 => $dog_2 }

с хеш-ссылками $cat_2 и $dog_1, которые преобразуются в строку для хеширования.

Хеш-значения должны быть скалярными, а не массивами.Но ссылки на массивы в порядке.Попробуйте:

my $pets = {'cats' => \@cats, 'dogs' => \@dogs};

Answer 2

Проблема в создании $ pets:

my $pets = {'cats' => @cats, 'dogs' => @dogs};

Примерно эквивалентно:

my $pets = {'cats', {name => 'cat1', ...}, {name => 'cat2', ...}, 
            'dogs', {name => 'dog1', ...}, {name => 'dog2, ...} };

Что совпадает с:

my $pets = {
            'cats'                 => {name => 'cat1', ...}, 
            {name => 'cat2'},      => 'dogs', 
            {name => 'dog1', ...}, => {name => 'dog2} 
           };

Вы хотите использовать ArrayRefs:

my $pets = {'cats' => \@cats, 'dogs' => \@dogs};

Что такое:

my $pets = {
    'cats' => [
        {name => 'cat1', ...},
        {name => 'cat2', ...}, 
    ],      
    'dogs' => [ 
        {name => 'dog1', ...},
        {name => 'dog2', ...},  
    ],
}; 

Именно так вы можете объявить всю структуру данных сразу.