Суммирование чисел с запятой в качестве десятичного разделителя в XSLT? - PullRequest
Новая
       19

Суммирование чисел с запятой в качестве десятичного разделителя в XSLT?

2 голосов
/ 15 марта 2009

У меня есть XML-файл, в котором число разделено запятыми 

<foo>
  <bar val="1,23"/>
  <bar val="4,56"/>
  <bar val="7,89"/>
</foo>

Я бы хотел сделать сумму по /foo/bar/@val значениям в XSLT, но я немного застрял в форматировании Кто-нибудь знает, какой будет правильный синтаксис?

Ответы [ 3 ]

6 голосов
/ 15 марта 2009

Я предполагаю, что значение, указанное в атрибуте "val", - это число, которое содержит запятую вместо десятичной точки.

Возможно несколько решений :

I. XSLT 1.0

Это преобразование: 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 >
  <xsl:output method="text"/>
<!--                                           -->  
    <xsl:template match="foo">
      <xsl:variable name="vrtfBars">
        <xsl:for-each select="bar">
          <bar val="{translate(@val, ',', '.')}"/>
        </xsl:for-each>
      </xsl:variable>
<!--                                           -->
      <xsl:value-of select=
       "sum(ext:node-set($vrtfBars)/*/@val)"/>
    </xsl:template>
</xsl:stylesheet>

при применении к первоначально предоставленному документу XML : 

<foo>
    <bar val="1,23"/>
    <bar val="4,56"/>
    <bar val="7,89"/>
</foo>

дает желаемый результат : 

13.68

II. XSLT 2.0

Это преобразование : 

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 exclude-result-prefixes="f xs"
 >
 <xsl:output method="text"/>
<!--                                           -->
 <xsl:template match="foo">
  <xsl:sequence select=
   "sum(bar/@val/number(translate(., ',', '.')))" 
   />
 </xsl:template>
</xsl:stylesheet>

при применении к одному и тому же XML-документу дает тот же правильный результат :

13,68

III. FXSL 2.x

Это преобразование : 

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:f="http://fxsl.sf.net/"
 xmlns:my="my:fun"
 exclude-result-prefixes="my f xs"
 >
   <xsl:import href="../f/func-transform-and-sum.xsl"/>
<!--                                           -->
 <xsl:output method="text"/>
<!--                                           -->
 <xsl:template match="foo">
  <xsl:sequence select=
   "sum(
        f:transform-and-sum(my:makeNum(), bar/@val )
        )" 
   />
 </xsl:template>
<!--                                           -->
 <xsl:function name="my:makeNum" as="xs:double">
   <xsl:param name="psNum" as="xs:string"/>
<!--                                           -->
   <xsl:sequence select="number(translate($psNum, ',', '.'))"/>
 </xsl:function>
<!--                                           -->
 <xsl:function name="my:makeNum" as="element()">
   <my:makeNum/>
 </xsl:function>
<!--                                           -->
 <xsl:template match="my:makeNum" as="xs:double" mode="f:FXSL">
   <xsl:param name="arg1" as="xs:string"/>
<!--                                           -->
   <xsl:sequence select="my:makeNum($arg1)"/>
 </xsl:template>
</xsl:stylesheet>

при применении к одному и тому же XML-документу дает тот же правильный результат :

* +1054 * 13,68

Последнее решение является более гибким и может успешно использоваться, когда перед суммированием требуется более сложное преобразование значений.

3 голосов
/ 16 марта 2009

Предполагая то же самое, что и Dimitre, вы подразумеваете, что запятая используется как десятичный разделитель, а не как разделитель для списка целых чисел.

Pure XSLT 1.0 без расширения набора узлов EXSLT: 

<xsl:template match="foo">
  <xsl:call-template name="sum">
    <xsl:with-param name="node" select="bar[1]"/>
  </xsl:call-template>
</xsl:template>

<xsl:template name="sum">
  <xsl:param name="node"/>
  <xsl:param name="sum" select="0"/>
  <xsl:choose>
    <xsl:when test="$node">
      <xsl:call-template name="sum">
        <xsl:with-param name="node" select="$node/following-sibling::bar[1]"/>
        <xsl:with-param name="sum" select="$sum + translate($node/@val, ',', '.')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$sum"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>
2 голосов
/ 15 марта 2009

Я чувствую, что говорю это много, но стоит повторить: весь смысл XML в том, что он предоставляет данные в легко разбираемой форме. XML, содержащий данные, которые не могут быть проанализированы как XML, не имеет смысла; если это вообще возможно, вы должны либо исправить свой XML, либо использовать другой формат.

...