XSL - обновить или создать атрибут при копировании - PullRequest
Новая
       14

XSL - обновить или создать атрибут при копировании

2 голосов
/ 04 октября 2011

У меня есть XML-документ, для которого я хочу сгенерировать уникальные идентификаторы.Некоторые узлы уже могут иметь атрибут, и в этом случае его необходимо заменить.Я хочу, чтобы все узлы в документе имели атрибут.

Пример документа будет 

<root>
<anode uid='123'/>
<anode/>
</root>

Я использую следующую таблицу стилей 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" omit-xml-declaration="yes"/>

    <xsl:template match="*">
        <xsl:copy>
            <xsl:attribute name="uid">
                <xsl:value-of select="generate-id(.)"/>
            </xsl:attribute>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

И получаюследующий вывод.Это близко к тому, что я хочу, но как я могу предотвратить создание существующего идентификатора как текстового узла? 

<root uid="id515559">
<anode uid="id515560">123</anode>
<anode uid="id515562"/>
</root>

Я смотрел на XSLT: Как изменить значение атрибута во время? но я не смог получить это для создания новых атрибутов.

Если это имеет значение, я использую lxml для обработки таблицы стилей.

Ответы [ 3 ]

1 голос
/ 04 октября 2011

Все, что вам нужно сделать, это добавить шаблон, соответствующий существующему атрибуту uid , и игнорировать его ... 

<xsl:template match="@uid" />

Итак, с помощью этой таблицы стилей ... 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:output method="xml" omit-xml-declaration="yes"/>

   <xsl:template match="*">
      <xsl:copy>
         <xsl:attribute name="uid">
            <xsl:value-of select="generate-id(.)"/>
         </xsl:attribute>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>

   <xsl:template match="@uid" />
</xsl:stylesheet>

При применении к вашему образцу XML вывод будет следующим: 

<root uid="IDAEQLT">
   <anode uid="IDA3XLT"></anode>
   <anode uid="IDA0XLT"></anode>
</root>
0 голосов
/ 04 октября 2011

Ответ не так уж и экстремален, как добавление нового совпадения для переопределения @uid.Вам просто нужно удалить select из вашего xsl:apply-templates.

Ваша таблица стилей с удаленным select: 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" omit-xml-declaration="yes"/>

    <xsl:template match="*">
        <xsl:copy>
            <xsl:attribute name="uid">
                <xsl:value-of select="generate-id(.)"/>
            </xsl:attribute>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

производит следующий вывод (@uid будет варьироваться): 

<root uid="d0e1">
  <anode uid="d0e3"/>
  <anode uid="d0e5"/>
</root>
0 голосов
/ 04 октября 2011

Правило Встроенный шаблон применяется к входу @uid по строке: 

<xsl:apply-templates select="@*|node()"/>

Шаблон по умолчанию для атрибута копирует текст, ведя себя так, как будто вы определили шаблон таким образом: 

<xsl:template match="text()|@*">
  <xsl:value-of select="."/>
</xsl:template>

Чтобы это не применялось, либо измените атрибут apply-templates select, чтобы он не применялся к атрибутам, либо определите новый пустой шаблон для любого атрибута, например: 

<xsl:template match="@*" />

Вы можете даже быть более конкретным, используя аналогичный шаблон, чтобы игнорировать только атрибуты uid, таким образом: 

<xsl:template match="@uid" />
...