XSL-FO - как продолжить числа в двух списках? - PullRequest
Новая
       29

XSL-FO - как продолжить числа в двух списках?

3 голосов
/ 08 сентября 2011

Кто-нибудь знает, как этого добиться с помощью преобразования XSL-FO? Детали вопроса должны быть ясны из кодов ниже.

Input:

<section>
    <title>Section 1</title>
    <orderedlist>
        <listitem><para>item 1.1</para></listitem>
        <listitem>
            <para>item 1.2</para>
            <orderedlist>
                <listitem><para>item a</para></listitem>
                <listitem><para>item b</para></listitem>
            </orderedlist>
        </listitem>
    </orderedlist>
</section>
<section>
    <title>Section 2</title>
    <orderedlist>
        <listitem><para>item 2.1</para></listitem>
        <listitem><para>item 2.2</para></listitem>
    </orderedlist>
</section>

Desired output:

Section 1
1. item 1.1
2. item 1.2
   a. item a
   b. item b

Section 2
3. item 2.1
4. item 2.2

Here is the XSL file for lists:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:fo="http://www.w3.org/1999/XSL/Format">

    <!-- templates for lists - supports numbered and itemized types -->
    <!-- the maximum depth is currently 2 -->
    <xsl:template match="orderedlist">
        <fo:list-block start-indent="0.5cm" space-before="0.2cm"
            provisional-distance-between-starts="0.7cm">
            <xsl:apply-templates />
        </fo:list-block>
    </xsl:template>
    <xsl:template match="orderedlist//orderedlist">
        <fo:list-block start-indent="1.2cm" provisional-distance-between-starts="0.7cm"
            padding-top="-0.2cm" padding-bottom="0.2cm">
            <xsl:apply-templates />
        </fo:list-block>
    </xsl:template>
    <xsl:template match="itemizedlist">
        <fo:list-block start-indent="0.5cm" space-before="0.2cm"
            provisional-distance-between-starts="0.7cm">
            <xsl:apply-templates />
        </fo:list-block>
    </xsl:template>
    <xsl:template match="itemizedlist//itemizedlist">
        <fo:list-block start-indent="1.2cm" provisional-distance-between-starts="0.7cm"
            padding-top="-0.2cm" padding-bottom="0.2cm">
            <xsl:apply-templates />
        </fo:list-block>
    </xsl:template>
    <xsl:template match="orderedlist/listitem">
        <fo:list-item margin-top="0.1cm">
            <fo:list-item-label end-indent="label-end()">
                <fo:block>
                    <xsl:number count="listitem" format="1." />
                </fo:block>
            </fo:list-item-label>
            <fo:list-item-body start-indent="body-start()">
                <fo:block>
                    <xsl:apply-templates />
                </fo:block>
            </fo:list-item-body>
        </fo:list-item>
    </xsl:template>
    <xsl:template match="orderedlist//orderedlist/listitem">
        <fo:list-item>
            <fo:list-item-label end-indent="label-end()">
                <fo:block>
                    <xsl:number count="listitem" format="a." />
                </fo:block>
            </fo:list-item-label>
            <fo:list-item-body start-indent="body-start()">
                <fo:block>
                    <xsl:apply-templates />
                </fo:block>
            </fo:list-item-body>
        </fo:list-item>
    </xsl:template>
    <xsl:template match="itemizedlist/listitem">
        <fo:list-item margin-top="0.1cm">
            <fo:list-item-label end-indent="label-end()">
                <fo:block>&#8226;</fo:block>
            </fo:list-item-label>
            <fo:list-item-body start-indent="body-start()">
                <fo:block>
                    <xsl:apply-templates />
                </fo:block>
            </fo:list-item-body>
        </fo:list-item>
    </xsl:template>
    <xsl:template match="itemizedlist//itemizedlist/listitem">
        <fo:list-item>
            <fo:list-item-label end-indent="label-end()">
                <fo:block>&#8226;</fo:block>
            </fo:list-item-label>
            <fo:list-item-body start-indent="body-start()">
                <fo:block>
                    <xsl:apply-templates />
                </fo:block>
            </fo:list-item-body>
        </fo:list-item>
    </xsl:template>
</xsl:stylesheet>

Ответы [ 2 ]

1 голос
/ 11 сентября 2011

Предполагается, что вы вводите выборку (добавлены секции самый верхний элемент, чтобы образец был правильно сформирован): 

<sections>
<section>
    <title>Section 1</title>
    <orderedlist>
        <listitem><para>item 1.1</para></listitem>
        <listitem>
            <para>item 1.2</para>
            <orderedlist>
                <listitem><para>item a</para></listitem>
                <listitem><para>item b</para></listitem>
            </orderedlist>
        </listitem>
    </orderedlist>
</section>
<section>
    <title>Section 2</title>
    <orderedlist>
        <listitem><para>item 2.1</para></listitem>
        <listitem><para>item 2.2</para></listitem>
    </orderedlist>
</section>
</sections>

в данном списке первого уровня, который вы можете использовать: 

count(
    preceding-sibling::listitem 
    | 
    ../../preceding-sibling::section/orderedlist/listitem) 
    + 1

Например: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:fo="http://www.w3.org/1999/XSL/Format">
    <xsl:output indent="yes"/>

    <xsl:template match="sections">
        <fo:block>
            <xsl:apply-templates select="section"/>
        </fo:block>
    </xsl:template>

    <xsl:template match="section">
        <fo:list-block>
            <xsl:apply-templates select="title | orderedlist/listitem"/>
        </fo:list-block>
    </xsl:template>

    <xsl:template match="title">
        <fo:list-item>
            <xsl:value-of select="."/>
        </fo:list-item>
    </xsl:template>

    <xsl:template match="listitem">
        <fo:list-item>
            <xsl:number 
                value="count(
                preceding-sibling::listitem 
                | 
                ../../preceding-sibling::section/orderedlist/listitem) 
                + 1" format="1.&#x20;"/>
        </fo:list-item>
    </xsl:template>
</xsl:stylesheet>

производит: 

<fo:block xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:list-block>
      <fo:list-item>Section 1</fo:list-item>
      <fo:list-item>1. </fo:list-item>
      <fo:list-item>2. </fo:list-item>
   </fo:list-block>
   <fo:list-block>
      <fo:list-item>Section 2</fo:list-item>
      <fo:list-item>3. </fo:list-item>
      <fo:list-item>4. </fo:list-item>
   </fo:list-block>
</fo:block>
0 голосов
/ 10 сентября 2011

Есть ли у вас особая причина не использовать DocBook и таблицы стилей DocBook-XSL ?Это дало бы вам много «бесплатно» (возможно, вы уже это знаете).

В DocBook то, что вы просите, уже реализовано.В <orderedlist> имеется атрибут continuation, который указывает, продолжается ли нумерация в списке с предыдущего списка.Это поддерживается в таблицах стилей DocBook-XSL для вывода FO (посмотрите fo / lists.xsl и common / common.xsl, чтобы увидеть, как это делается).

...