проблема с получением данных только с одной функции печати на странице php и передачей на flash

Question

Я пытаюсь взять переменную со страницы php и отправить ее на флэш-память, чтобы затем использовать в ссылке.

У меня проблемы при выборе ОДНОЙ переменной из функции печати, код поможет объяснить:

PHP страница

<?
print"fbook=facebook";
print"tweet=twitter-test";
print"utube=youtube-test";
?>

Flash-код

var loader:URLLoader = new URLLoader();
loader.addEventListener(Event.COMPLETE,onLoaded);
loader.load(new URLRequest("../SC/FLA_tools-btn.php"));
var variables:URLVariables = new URLVariables();
fbook.addEventListener(MouseEvent.MOUSE_DOWN, mouseClickfbook);
tweet.addEventListener(MouseEvent.MOUSE_DOWN, mouseClicktweet);
youtube.addEventListener(MouseEvent.MOUSE_DOWN, mouseClickyoutube);

function onLoaded(evt:Event):void
{
var data:URLVariables = new URLVariables(evt.target.data);
variables.fbook = data.fbook;
variables.twitter = data.tweet;
variables.utube = data.utube;
}

function mouseClicktweet(event:MouseEvent):void
{
navigateToURL(new URLRequest('http://www.twitter.com/'+variables.twitter),"_Self");

}

function mouseClickfbook(event:MouseEvent):void
{
navigateToURL(new URLRequest('http://www.facebook.com/'+variables.fbook),"_Self");

}

function mouseClickyoutube(event:MouseEvent):void
{
navigateToURL(new URLRequest('http://www.youtube.com/'+variables.utube),"_Self");

}

Он собирает все данные в порядке, но не распечатывает их правильно, он выводит все переменные в php по одной ссылке. Например:

Если я нажму на значок Facebook, меня перенаправят на http://www.facebook.com/facebooktweet=twitter-testutube=youtube-test Это также происходит с другими значками (Youtube и Twitter).

Есть идеи?

Спасибо!

Answer 1

Как насчет подходов по-другому?Когда вы запрашиваете данные из вашего php-файла из вашего приложения Flash, вы можете указать, какие именно данные вы хотите.Вот пример этого:

Main.mxml:

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark"
               xmlns:mx="library://ns.adobe.com/flex/mx"
               creationComplete="init(event)">

    <fx:Script>
        <![CDATA[
        import flash.events.Event;
        import flash.events.MouseEvent;
        import flash.net.URLLoader;
        import flash.net.URLRequest;
        import flash.net.URLRequestMethod;
        import flash.net.URLVariables;
        import mx.events.FlexEvent;
        import spark.components.Button;

        public function init(e:FlexEvent):void
        {
            facebookButton.addEventListener(MouseEvent.CLICK, onClick);
            twitterButton.addEventListener(MouseEvent.CLICK, onClick);
            youtubeButton.addEventListener(MouseEvent.CLICK, onClick);

        }// end function

        private function onClick(e:MouseEvent):void
        {
            var button:Button = e.target as Button;

            var requestString:String = "";

            switch(button)
            {
                case facebookButton: requestString = "facebook"; break;
                case twitterButton:  requestString = "twitter";  break;
                case youtubeButton:  requestString = "youtube";  break;

            }// end switch

            var urlVariables:URLVariables = new URLVariables();
            urlVariables.request = requestString;

            var urlRequest:URLRequest = new URLRequest("http://projects.flashdevelop/stackoverflow/GetDataFromPHP/bin/php/getData.php");
            urlRequest.data = urlVariables;
            urlRequest.method = URLRequestMethod.POST;

            var urlLoader:URLLoader = new URLLoader();
            urlLoader.addEventListener(Event.COMPLETE, onUrlLoaderComplete);
            urlLoader.load(urlRequest);

        }// end function

        private function onUrlLoaderComplete(e:Event):void
        {
            var urlLoader:URLLoader = e.target as URLLoader;
            var urlVariables:URLVariables = new URLVariables(urlLoader.data);

            trace(urlVariables.response);

        }// end function

        ]]>
    </fx:Script>

    <s:HGroup>
        <s:Button id="facebookButton" width="100" height="100">Facebook</s:Button>
        <s:Button id="twitterButton" width="100" height="100">Twitter</s:Button>
        <s:Button id="youtubeButton"  width="100" height="100">Youtube</s:Button>
    </s:HGroup>

</s:Application>

getData.php:

<?php

    $response = "";

    if (!empty($_POST))
    {
        switch($_POST["request"])
        {
            case "facebook" : $response = "response=facebook-data"; break;
            case "twitter"  : $response = "response=twitter-data"; break;
            case "youtube"  : $response = "response=youtube-data"; break;
            default         : $response = "response=error"; break;

        }// end switch
    }
    else
    {
        $response = "response=error";

    }// end else

    print $response;

?>

Answer 2

Необработанные данные, которые вы отправляете по проводам из PHP, выглядят примерно так:

fbook=facebook\n
tweet=twitter-test\n
utube=youtube-test\n

Если вы хотите использовать их с классом URLVariables, вам необходимо правильно закодировать свойства URL.Они должны выглядеть следующим образом:

fbook=facebook&tweet=twitter-test&utube=youtube-test

Измените ваш PHP-скрипт так, чтобы он выглядел следующим образом:

<?
print"fbook=facebook&tweet=twitter-test&utube=youtube-test";
?>

Тогда все должно быть настроено на стороне Flash.