XSL - сумма умножения элементов

Question

У меня есть несколько таких предметов:

<item type="goods">
    <quantity unit="pcs">172</quantity>
    <unit-price currency="PLN">420</unit-price>
    <VAT>7</VAT>
</item>

Я хочу напечатать сумму стоимости этих предметов.Итак, что математически:

sum(quantity*unit-price)

Как я могу сделать это с xsl?Я пробовал использовать переменные с for-each внутри цикла и обычным valye-of.но я все еще получаю некоторые странные результаты (я не буду добавлять этот код, потому что он просто плохой).

Answer 1

XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/root">
    <xsl:text>sum:</xsl:text>

    <xsl:call-template name="sum">
      <xsl:with-param name="nodes" select="item"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="sum">
    <xsl:param name="nodes" />
    <xsl:param name="sum" select="0" />

    <xsl:variable name="current" select="$nodes[1]" />

    <xsl:if test="$current"> 
      <xsl:call-template name="sum">
        <xsl:with-param name="nodes" select="$nodes[position() &gt; 1]" />
        <xsl:with-param name="sum" select="$sum + $current/quantity * $current/unit-price" />
      </xsl:call-template>
    </xsl:if>

    <xsl:if test="not($current)">
      <xsl:value-of select="$sum" />
    </xsl:if>

  </xsl:template>

</xsl:stylesheet>

Входной XML:

<root>
  <item type="goods">
    <quantity unit="pcs">1</quantity>
    <unit-price currency="PLN">2</unit-price>
    <VAT>7</VAT>
  </item>
  <item type="goods">
    <quantity unit="pcs">10</quantity>
    <unit-price currency="PLN">20</unit-price>
    <VAT>7</VAT>
  </item>
  <item type="goods">
    <quantity unit="pcs">100</quantity>
    <unit-price currency="PLN">200</unit-price>
    <VAT>7</VAT>
  </item>
</root>

Выход:

sum:20202

Answer 2

В дополнение к правильному ответу Кирилла:

I.Решение XPath 2.0 (XSLT 2.0) :

Используйте это единственное выражение XPath 2.0 для любого языка, на котором размещается XPath 2.0:

sum(/*/*/(quantity*unit-price))

Вот полный пример использования XSLT 2.0 в качестве хостаXPath 2.0:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:sequence select="sum(/*/*/(quantity*unit-price))"/>
 </xsl:template>
</xsl:stylesheet>

при применении к следующему документу XML :

<items>
    <item type="goods">
        <quantity unit="pcs">1</quantity>
        <unit-price currency="PLN">2</unit-price>
        <VAT>7</VAT>
    </item>
    <item type="goods">
        <quantity unit="pcs">10</quantity>
        <unit-price currency="PLN">20</unit-price>
        <VAT>7</VAT>
    </item>
    <item type="goods">
        <quantity unit="pcs">100</quantity>
        <unit-price currency="PLN">200</unit-price>
        <VAT>7</VAT>
    </item>
</items>

желаемый, правильный результат получается :

20202

---

II.Решение XSLT 1.0 с использованием шаблона / функции transform-and-sum FXSL 1.x

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/"
xmlns:func-transform="f f:func-transform"
exclude-result-prefixes="xsl func-transform"
>
   <xsl:import href="transform-and-sum.xsl"/>

   <!-- to be applied on testTransform-and-sum5.xml -->

   <xsl:output method="text"/>

   <func-transform:func-transform/>

    <xsl:template match="/">
      <xsl:call-template name="transform-and-sum">
        <xsl:with-param name="pFuncTransform" 
                        select="document('')/*/func-transform:*[1]"/>
        <xsl:with-param name="pList" select="/*/*"/>
      </xsl:call-template>
    </xsl:template>

    <xsl:template match="func-transform:*" mode="f:FXSL">
      <xsl:param name="arg1" select="0"/>
      <xsl:value-of select="$arg1/quantity * $arg1/unit-price "/>
    </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется ктот же XML-документ (выше), тот же правильный результат получается :

20202

Do note : при использовании FXSL не требуется реализовывать явную рекурсию "для N-говремя ", решение компактно, и потенциальные ошибки при написании рекурсии полностью устранены.

В целом общее время разработки, читаемость и гибкость значительно улучшены.