XSLT / Xpath: как удалить слой контейнера

Question

С учетом ввода типа

<a>
   <b>
      <c>everything below</c>
      <d></d>
   </b>
   <b>
      <c>everything below</c>
      <d></d>
   </b>
</a>

, есть хорошее решение Xpath для получения

<a>
   <c>everything below</c>
   <c>everything below</c>
</a>

, (так сказать «unwrap-remove-select-wrap»), или как бы я достиг этого наиболее комфортно?

Answer 1

Использование:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="a | c">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

Вывод:

<a>
  <c>everything below</c>
  <c>everything below</c>
</a>

Answer 2

Спасибо всем, я думаю, что смогу найти то, что я хочу, с помощью ваших ответов:

<xsl:for-each select="a">
    <xsl:copy>
       <xsl:copy-of select="./b/c|@*" />
    </xsl:copy>
</xsl:for-each>

... Я думаю, что делает то, что хотел, без использования дополнительных шаблонов, кратко и кратко.

Answer 3

Попробуйте

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output  method="xml" indent="yes"/>
    <xsl:template match="*">
        <a>
            <xsl:for-each select="//c">
                <xsl:copy-of select="." />
            </xsl:for-each>
        </a>
    </xsl:template>
</xsl:stylesheet>

Answer 4

Следующая модификация правила идентификации , вероятно, является самым простым и элегантным решением :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()[not(self::b or self::d)]|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к предоставленному документу XML :

<a>
    <b>
        <c>everything below</c>
        <d></d>
    </b>
    <b>
        <c>everything below</c>
        <d></d>
    </b>
</a>

желаемый, правильный результат получается :

<a>
   <c>everything below</c>
   <c>everything below</c>
</a>

Объяснение:

1. Эта модификация правила идентификации копирует каждый узел "как есть", за исключением любых элементов b или d.

2. Любые элементы b или d обрабатываются стандартным (встроенным) XSLT-шаблоном для элементов, который применяет шаблоны к своим дочерним элементам (у них их нет, поэтому желаемый эффект «удаления» достигнуто).

Answer 5

<xsl:template match="a">
  <xsl:copy>
    <xsl:apply-templates select="//c"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="c">
  <xsl:copy>
    <xsl:value-of select="."/>
  </xsl:copy>
</xsl:template>