Гиперссылка, только если веб-адрес присутствует ..?

Question

Ниже приведен пример XML-файла -

<?xml version="1.0" encoding="UTF-8"?>
<Catalog>
<Book>
   <AName>Steven Holzner</AName>
   <BName>Using XSLT</BName>
   <Pub>ABC Publication </Pub>
   <Web>http://www.ABCPub.com</Web>
</Book>
<Book>
   <AName>Steven Holzner</AName>
   <BName>Using HTML</BName>
   <Pub>XYZ Publication </Pub>
   <Web></Web>
</Book>
</Catalog>

Я хочу сделать гиперссылку на имя паба, если указан веб-адрес, в противном случае только имя паба без ссылки ...

Мой XSL-код здесь -

<xsl:template match="Catalog">
    <xsl:for-each select="Book">
    <p><a>
    <xsl:attribute name="href">
      <xsl:value-of select="Web"/>
    </xsl:attribute>

    <xsl:value-of select="Pub"/>
    </a></p>
    </xsl:for-each>
</xsl:template>

Я хочу подписаться на источник HTML -

ABC Publication

XYZ Publication

Правильно, этот XSL дает тег гиперссылки, даже если Web-адрес не указан .. Какой кусок кода сделает нужным ..?

хорошего дня - John

Answer 1

Это может быть достигнуто с помощью очень короткого и простого преобразования - нет <xsl:for-each>, нет <xsl:if>, <xsl:choose>, <xsl:when>, вообще нет <xsl:attribute> :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="Book[Web/text()]">
     <p>
      <a href="{Web}">
       <xsl:value-of select="Pub"/>
      </a>
     </p>
 </xsl:template>

 <xsl:template match="Book">
     <p>
       <xsl:value-of select="Pub"/>
     </p>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к предоставленному документу XML :

<Catalog>
    <Book>
        <AName>Steven Holzner</AName>
        <BName>Using XSLT</BName>
        <Pub>ABC Publication </Pub>
        <Web>http://www.ABCPub.com</Web>
    </Book>
    <Book>
        <AName>Steven Holzner</AName>
        <BName>Using HTML</BName>
        <Pub>XYZ Publication </Pub>
        <Web></Web>
    </Book>
</Catalog>

желаемый, правильный результат получается :

<p>
   <a href="http://www.ABCPub.com">ABC Publication </a>
</p>
<p>XYZ Publication </p>

Объяснение : Соответствие шаблонам.

Answer 2

Просто проверьте, заполнен ли Интернет выбором / когда / еще

<xsl:template match="Catalog">
    <xsl:for-each select="Book">
    <p><xsl:choose>
<xsl:when test="string(Web)"><a>
    <xsl:attribute name="href">
      <xsl:value-of select="Web"/>
    </xsl:attribute>

    <xsl:value-of select="Pub"/>
    </a>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="Pub"/>
</xsl:othwerwise>
</xsl:choose>
</p>
    </xsl:for-each>
</xsl:template>

Answer 3

<xsl:if test="Web != ''">
   <a> 
    <xsl:attribute name="href"> 
      <xsl:value-of select="Web"/> 
    </xsl:attribute>
    <xsl:value-of select="Pub"/> 
    </a>
</xsl:if>

^ Это будет отображать издателя, только если есть веб-адрес, что вы хотите XSL: выберите ...

<xsl:choose>
    <xsl:when test="Web != ''">
        <a> 
        <xsl:attribute name="href"> 
          <xsl:value-of select="Web"/> 
        </xsl:attribute>
        <xsl:value-of select="Pub"/> 
        </a>
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="Pub"/>
    </xsl:otherwise>
</xsl:choose>