Несколько каталогов под CMake

Question

В настоящее время я использую рекурсивные make и autotools и собираюсь перейти на CMake для проекта, который выглядит примерно так:

lx/ (project root)
    src/
        lx.c (contains main method)
        conf.c
        util/
            str.c
            str.h
            etc.c
            etc.h
        server/
            server.c
            server.h
            request.c
            request.h
        js/
            js.c
            js.h
            interp.c
            interp.h
    bin/
        lx (executable)

Как мне это сделать?

Answer 1

Если нет источника выше каталога lx / src, тогда файл lx / CMakeLists.txt не требуется.Если он есть, он должен выглядеть примерно так:

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(lx)

add_subdirectory(src)
add_subdirectory(dir1)
add_subdirectory(dir2)

# And possibly other commands dealing with things
# directly in the "lx" directory

... где подкаталоги добавляются в порядке зависимости библиотек.Сначала следует добавить библиотеки, которые не зависят ни от чего, а затем библиотеки, которые зависят от них и т. Д.

lx / src / CMakeLists.txt

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(lx_exe)

add_subdirectory(util)
add_subdirectory(js)
add_subdirectory(server)

set(lx_source_files conf.c lx.c)
add_executable(lx ${lx_source_files})

target_link_libraries(lx server)
  # also transitively gets the "js" and "util" dependencies

lx / src / util / CMakeLists.txt

set(util_source_files
  etc.c
  etc.h
  str.c
  str.h
)
add_library(util ${util_source_files})

lx / src / js / CMakeLists.txt

set(js_source_files
  interp.c
  interp.h
  js.c
  js.h
)
add_library(js ${js_source_files})

target_link_libraries(js util)

lx / src / server / CMakeLists.txt

set(server_source_files
  request.c
  request.h
  server.c
  server.h
)
add_library(server ${server_source_files})

target_link_libraries(server js)
  # also transitively gets the "util" dependency

Затем в командной строке:

mkdir lx/bin
cd lx/bin

cmake ..
  # or "cmake ../src" if the top level
  # CMakeLists.txt is in lx/src

make

По умолчанию исполняемый файл lx заканчивается вКаталог "lx / bin / src", использующий эту точную компоновку.Вы можете контролировать, в каком каталоге он находится, используя целевое свойство RUNTIME_OUTPUT_DIRECTORY и команду set_property.

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#prop_tgt:RUNTIME_OUTPUT_DIRECTORY

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#command:set_property

Обратитесь к библиотекам target_link_libraries либо с помощьюИмя цели CMake, если библиотека создается как цель CMake с помощью add_library или в противном случае указывается полный путь к файлу библиотеки.

См. Также вывод "cmake --help-command target_link_libraries" или любой другойдругая команда cmake и полная онлайн-документация для команд cmake, найденная здесь:

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#section_Commands

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#command:target_link_libraries