Автоматически сгенерированное статическое поле в классе / модуле F # предотвращает создание функции SQL CLR

Question

Я пытаюсь написать пользовательскую функцию CLR на F #, но CREATE ASSEMBLY выдает ошибку:

Не удалось создать CREATE ASSEMBLY, поскольку в безопасной сборке введите 'StringMetrics' MyNamespace.SqlServer.Text 'имеет статическое поле' field1776 @ '.Атрибуты статических полей в безопасных сборках должны быть помечены только для чтения в Visual C #, ReadOnly в Visual Basic или initonly в Visual C ++ и промежуточном языке.

Вот как это выглядит в Reflector.Это не поле, которое я явно создал.

[DebuggerBrowsable(DebuggerBrowsableState.Never)]
internal static <PrivateImplementationDetails$MyNamespace-SqlServer-Text>.T1775_18Bytes@ field1776@; // data size: 18 bytes

Я пытался использовать модуль и класс.Оба генерируют поле, просто в разных местах.Для чего это поле?Есть ли способ избежать его создания?Есть ли другой подход, который я должен использовать для создания функции CLR в F #?Это вообще возможно?

Полный код

namespace MyNamespace.SqlServer.Text

module StringMetrics =

    open System
    open System.Collections.Generic
    open System.Data
    open System.Data.SqlTypes

    [<CompiledName("FuzzyMatch")>]
    let fuzzyMatch (strA:SqlString) (strB:SqlString) =
        if strA.IsNull || strB.IsNull then SqlInt32.Zero
        else
            let comparer = StringComparer.OrdinalIgnoreCase

            let wordBoundaries = [|' '; '\t'; '\n'; '\r'; ','; ':'; ';'; '('; ')'|]

            let stringEquals a b = comparer.Equals(a, b)

            let isSubstring (search:string) (find:string) = find.Length >= search.Length / 2 && search.IndexOf(find, StringComparison.OrdinalIgnoreCase) >= 0

            let split (str:string) = str.Split(wordBoundaries)

            let score (strA:string) (strB:string)  =
                if stringEquals strA strB then strA.Length * 3
                else
                    let lenA, lenB = strA.Length, strB.Length
                    if strA |> isSubstring strB then lenA * 2
                    elif strB |> isSubstring strA then lenB * 2
                    else 0

            let arrA, arrB = split strA.Value, split strB.Value
            let dictA, dictB = Dictionary(), Dictionary()

            arrA |> Seq.iteri (fun i a ->
                arrB |> Seq.iteri (fun j b ->
                    match score a b with
                    | 0 -> ()
                    | s -> 
                        match dictB.TryGetValue(j) with
                        | true, (s', i') -> //'
                            if s > s' then //'
                                dictA.Add(i, j)
                                dictB.[j] <- (s, i)
                        | _ -> 
                            dictA.Add(i, j)
                            dictB.Add(j, (s, i))))

            let matchScore = dictB |> Seq.sumBy (function (KeyValue(_, (s, _))) -> s)
            let nonMatchA = 
                arrA
                |> Seq.mapi (fun i a -> i, a)
                |> Seq.fold (fun s (i, a) -> 
                    if dictA.ContainsKey(i) then s
                    else s + a.Length) 0
            let wordsB = HashSet(seq { for (KeyValue(i, _)) in dictB -> arrB.[i] }, comparer)
            let nonMatchB = 
                arrB |> Seq.fold (fun s b -> 
                    if wordsB.Add(b) then s + b.Length
                    else s) 0

            SqlInt32(matchScore - nonMatchA - nonMatchB)

Answer 1

Кажется, он генерируется массивом wordBoundaries.Если вы вместо этого выражаете его как список и преобразуете его в массив во время выполнения, это внутреннее статическое поле не генерируется:

let wordBoundaries = Array.ofList [' '; '\t'; '\n'; '\r'; ','; ':'; ';'; '('; ')']

Однако, похоже, что и сама функция представляется как статическая,не доступное только для чтения поле:

public static SqlInt32 fuzzyMatch(SqlString strA, SqlString strB);

Может быть, использование класса вместо модуля вылечит это.