Добавить текст на грани многогранника

Question

Можно ли автоматизировать добавление какого-либо текста к граням многогранника, как показано на графике, нарисованном вручную (нечетная схема нумерации примера не имеет значения):

Было достаточно легко обозначить вершины:

c = 1;
Show[{Graphics3D[
   Text[c++, #] & /@ PolyhedronData["Dodecahedron", "VertexCoordinates"]], 
   PolyhedronData["Dodecahedron"]},
   Boxed -> False]

(хотя часть текста помещается перед формой для скрытых вершинЭто, вероятно, разрешимо.)

Но когда я попытался сделать то же самое для лиц, ничего не получалось.PolyhedronData["Dodecahedron", "Faces"] возвращает GraphicsComplex, а не координаты.

Я пропускаю простое решение / вариант?

Редактировать: спасибо за эти ответы, они все блестящие.Если бы я мог совместить размещение текста ответа szabolcs с качеством текста belisarius ', идеальное решение в поле зрения!

Answer 1

Вот такой вот прикольный подход:

(* this function just transforms the polygon onto the [0,1] 2D square *)
vtc[face_, up_:{0,0,1}] := Module[{pts, pts2, centre, r, r2, topmost},
  pts = N@face;
  centre = Mean[pts];
  pts = (# - centre & /@ pts);
  r = SingularValueDecomposition[pts][[3]];

  (* these two lines ensure that the text on the outer face 
     of a convex polyhedron is not mirrored *)
  If[Det[r] < 0, r = -r];
  If[Last[centre.r] < 0, r = r.RotationMatrix[\[Pi], {1, 0, 0}]];

  pts2 = Most /@ (pts.r);
  topmost = Part[pts2, First@Ordering[up.# &  /@ pts, -1]];
  r2 = Transpose[{{#2, -#1} & @@ topmost, topmost}];
  r2 /= Norm[r2];
  Rescale[pts2.r2]
]

faces = First /@ First@Normal@PolyhedronData["Dodecahedron", "Faces"];

numbers = 
  Graphics[Text[
      Style[#, Underlined, FontFamily -> "Georgia", 
       FontSize -> Scaled[.3]]]] & /@ Range@Length[faces];

Graphics3D[
 MapThread[{Texture[#1], 
    Polygon[#2, VertexTextureCoordinates -> vtc[#2]]} &, {numbers, 
   faces}],
 Boxed -> False
 ]

Demoing a "SmallRhombicosidodecahedron":

Answer 2

a = PolyhedronData["Dodecahedron", "Faces"] /.    GraphicsComplex -> List;
c = 1;
Show[{Graphics3D[
   Text[c++, #] & /@ (Mean /@ (a[[1, #]] & /@ a[[2, 1]]))], 
    PolyhedronData["Dodecahedron"]}, Boxed -> False]

Редактировать

Возможно, лучше:

Show[{Graphics3D[
         MapIndexed[Text[#2, #1] &, 
             Mean /@ (PolyhedronData["Dodecahedron", "VertexCoordinates"][[#]] & /@ 
                      PolyhedronData["Dodecahedron", "FaceIndices"])]], 
         PolyhedronData["Dodecahedron"]}, Boxed -> False]

Редактировать

или

text = Style[#, 128] & /@ Range[12]
Graphics3D@
 Riffle[Texture /@ text, 
       (Append[#1, {VertexTextureCoordinates -> 
          With[{n = Length[First[#1]]}, Table[1/2 {Cos[2 Pi i/n], Sin[2 Pi i/n]}+ 
                                           {1/2, 1/2}, {i, 0, n - 1}]]}] &) /@ 
   Flatten[Normal[PolyhedronData["Dodecahedron", "Faces"]]]]