как заменить двойную кавычку на строку '\ "' в XSLT?

Question

У меня есть XML, в котором двойные кавычки должны быть заменены строкой \ ".

например: <root><statement1><![CDATA[<u>teset "message"here</u>]]></statement1></root>

, поэтому на выходе должно быть <root><statement1><![CDATA[<u>teset \"message\"here</u>]]></statement1></root>

Кто-нибудь может объяснить, как это сделать?

Answer 1

I.Решение XSLT 1.0 :

Это преобразование :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"
 cdata-section-elements="statement1"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pPattern">"</xsl:param>
 <xsl:param name="pReplacement">\"</xsl:param>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="statement1/text()" name="replace">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pPat" select="$pPattern"/>
  <xsl:param name="pRep" select="$pReplacement"/>

 <xsl:choose>
  <xsl:when test="not(contains($pText, $pPat))">
   <xsl:copy-of select="$pText"/>
  </xsl:when>
  <xsl:otherwise>
   <xsl:copy-of select="substring-before($pText, $pPat)"/>
   <xsl:copy-of select="$pRep"/>
   <xsl:call-template name="replace">
    <xsl:with-param name="pText" select=
         "substring-after($pText, $pPat)"/>
    <xsl:with-param name="pPat" select="$pPat"/>
    <xsl:with-param name="pRep" select="$pRep"/>
   </xsl:call-template>
  </xsl:otherwise>
 </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML :

<root>
    <statement1><![CDATA[<u>teset "message"here</u>]]></statement1>
</root>

дает желаемый, правильный результат :

<root>
   <statement1><![CDATA[<u>teset \"message\"here</u>]]></statement1>
</root>

II.Решение XSLT 2.0 :

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"
 cdata-section-elements="statement1"/>

 <xsl:param name="pPat">"</xsl:param>
 <xsl:param name="pRep">\\"</xsl:param>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

  <xsl:template match="statement1/text()">
   <xsl:sequence select="replace(.,$pPat, $pRep)"/>
  </xsl:template>
</xsl:stylesheet>

при применении к тому же документу XML (как указано выше), получается тот же правильный результат :

<root>
      <statement1><![CDATA[<u>teset \"message\"here</u>]]></statement1>
</root>

Answer 2

<?xml version='1.0'   ?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:fo="http://www.w3.org/1999/XSL/Format"
                version='1.0'>
<xsl:output method="xml"/>

<xsl:template match="/">
  <xsl:for-each select="//p">
    <xsl:value-of select="translate(text(), '&amp;x22;','#')"/>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

Это сработало для меня ....