Как создать интерактивную функцию elisp с необязательными аргументами

Question

Как написать функцию elisp, которая должна быть связана с нажатием клавиши, которая по умолчанию работает без запроса, но когда ей предшествует Ctrl-u, запрашивает у пользователя аргумент.Что-то похожее (неправильный синтаксис, но я надеюсь, вы поняли)?

 (defun my-message (&optional (print-message "foo"))
   (interactive "P")
   (message print-message))
 (global-set-key "\C-c\C-m" 'my-message)

Answer 1

Следующее использует функцию interactive, которая позволяет использовать код вместо строки.Этот код будет выполняться только тогда, когда функция вызывается в интерактивном режиме (что делает этот ответ другим по сравнению с предыдущим ответом).Код должен соответствовать списку, в котором элементы отображаются на параметры.

(defun my-test (&optional arg)
  (interactive (list (if current-prefix-arg
                         (read-from-minibuffer "MyPrompt: ")
                       nil)))
  (if arg
      (message arg)
    (message "NO ARG")))

Используя этот метод, эту функцию можно вызывать из кода, подобного (my-test) или (my-test "X"), без запроса пользователядля ввода.В большинстве случаев вы хотели бы разработать функции таким образом, чтобы они запрашивали ввод только при интерактивном вызове.

Answer 2

Если вы просто хотите использовать функцию в качестве интерактивной, этот код - все, что вам нужно:

(defun my-message (&optional ask)
  (interactive "P")
  (message (if ask
               (read-from-minibuffer "Message: ")
             "foo")))

Answer 3

Следуя той же реализации, что и в вашем примере, вы можете сделать что-то вроде этого:

(defun my-message (&optional arg)
  (interactive "P")
  (let ((msg "foo"))
    (when arg
      (setq msg (read-from-minibuffer "Message: ")))
    (message msg)))