Простые кнопки отображаются, но не активны на сцене

Question

Я написал класс с именем ButtonTile для расширения класса SimpleButton.Затем я создаю массив объектов ButtonTile и добавляю их на мой этап в построении сетки.

Когда я запускаю код, все объекты ButtonTile появляются на сцене, но на них нельзя щелкать, и их цвет не изменяется для их состояний «вверх» и «вниз».

Вот код для класса ButtonTile:

package com.shakti.gameState{

import flash.display.*;

public class ButtonTile extends SimpleButton {

    public var id:int;
    public var quizId:int;
    public var subjectId:int;
    public var points:int;
    public var questionTxt:String;
    public var order:int;
    public var option:Array;

    public function ButtonTile(newId:int, newQuizId:int, newSubId:int, newPoints:int, qtxt:String, newOrder:int, newOption:Array) {
        this.id=newId;
        this.quizId=newQuizId;
        this.subjectId=newSubId;
        this.points=newPoints;
        this.questionTxt=qtxt;
        this.order=newOrder;
        this.option=newOption;
        this.upState=TileColor(0);
        this.downState=TileColor(1);
        this.overState=TileColor(2);
        this.useHandCursor = true;
        this.enabled = true;
    }

    public function TileColor(stateFlag:int):Shape{

        var newShape:Shape=new Shape();
        if (stateFlag == 0){
            trace('hi');
            newShape.graphics.beginFill(0x000000);
        }
        else if (stateFlag == 1) {
            newShape.graphics.beginFill(0x00ff00);
        }
        else {
            newShape.graphics.beginFill(0x303030);
        }
        newShape.graphics.drawRect(0,0,70,50);
        newShape.graphics.endFill();
        return(newShape);
    }
}

, и это код, который создает массив объектов ButtonTile:

        public function MakeButtons():Array{

        var a:int = 0;

        for (var i:int = 0; i < quizState.subjects.length; ++i){

            for (var e:int = 0; e < quizState.subjects[i].quizQuestions.length; ++e){ 

                var id:int = quizState.subjects[i].quizQuestions[e].id;
                var quizId:int = quizState.subjects[i].quizQuestions[e].quizId;
                var subjectId:int = quizState.subjects[i].quizQuestions[e].subjectId;
                var points:int = quizState.subjects[i].quizQuestions[e].points;
                var questionTxt:String = quizState.subjects[i].quizQuestions[e].question;
                var order:int = quizState.subjects[i].quizQuestions[e].order;
                var option:Array = quizState.subjects[i].quizQuestions[e].option;

                tempTile = new ButtonTile(id, quizId, subjectId, points, questionTxt, order, option);                   

                buttons[a] = tempTile;
                ++a;
            }
        }
        return buttons;
    }

Добавлен прослушиватель событийкаждому объекту, добавленному на сцену.

for (var i:int = 0; i < buttons.length; ++i){
var tempTile:ButtonTile;
tempTile = buttons[i];
tempTile.x = boxPoints[i].x;
tempTile.y = boxPoints[i].y;
tempTile.addEventListener(MouseEvent.CLICK, PopQuest);
addChild(tempTile);

}

Спасибо за помощь !!!

Answer 1

Я полагаю, что вам просто не хватает свойства hitTestState в вашем классе ButtonTile:

this.hitTestState = TileColor(0);