создание нового пользователя ODBC DSN с Delphi - PullRequest
Новая
       23

создание нового пользователя ODBC DSN с Delphi

6 голосов
/ 04 марта 2012

AI пытается создать новую запись в пользовательском DSN в ODBC Data Source Administrator со следующим кодом: 

procedure TForm1.FormCreate(Sender: TObject);
var strAttributes: string;
    wideChars   : array[0..1000] of WideChar;
     pfErrorCode: DWORD;
     errMsg: PChar;

begin
 strAttributes := 'DSN=' + 'example_DSN' + Chr(0);
    strAttributes := strAttributes + 'DESCRIPTION=' + 'description' + Chr(0);
    strAttributes := strAttributes + 'SERVER=' + 'testserver' + Chr(0);
    strAttributes := strAttributes + 'DATABASE=' + 'somedatabase' + Chr(0);

  StringToWideChar(strAttributes, wideChars, 12);
  if not SqlConfigDataSource(0, ODBC_ADD_DSN, 'SQL Server', wideChars) then
  begin
    errMsg := AllocMem(SQL_MAX_MESSAGE_LENGTH);
    SQLInstallerError(1, @pfErrorCode, errMsg, SQL_MAX_MESSAGE_LENGTH, nil);
    MessageBox(0, errMsg, PChar('Add System DSN Error #' + IntToStr(pfErrorCode)), 0);
    FreeMem(errMsg);
  end;
end;

но часть SqlConfigDataSource не выполняет эту работу, а также возвращаемая ошибка вообще не подлежит восстановлению. Это не число и не описание ошибки. Может ли кто-нибудь помочь мне, где я совершил ошибку? Спасибо

Ответы [ 3 ]

7 голосов
/ 04 марта 2012

Вероятно, ваша ошибка или даже набор ошибок в неправильном переводе заголовков ODBC, который затем может быть использован для версии не-Unicode или Unicode Delphi.Например:

  • для Unicode Delphi вам скорее нужно использовать функции XxxW (UTF16) из ODBCCP32.DLL, чем Xxx (ANSI);
  • для неUnicode Delphi скорее Xxx функций.И тогда wideChars должен быть определен как array[..] of Char;
  • SqlConfigDataSource может быть определен как XxxW с PAnsiChar;
  • и т. Д.

Я хотел показать вам эту идею, потому что без полных источников я могу только строить догадки.Тогда у вас есть подозрительный звонок StringToWideChar(strAttributes, wideChars, 12);.Значение strAttributes намного длиннее 12 символов.

Следующий код хорошо работает в Delphi XE2: 

type
  SQLHWnd = LongWord;
  SQLChar = Char;
  PSQLChar = ^SQLChar;
  SQLBOOL = WordBool;
  UDword = LongInt;
  PUDword = ^UDword;
  SQLSmallint = Smallint;
  SQLReturn = SQLSmallint;

const
  SQL_MAX_MESSAGE_LENGTH = 4096;

  ODBC_ADD_DSN     = 1;         // Add data source
  ODBC_CONFIG_DSN  = 2;         // Configure (edit) data source
  ODBC_REMOVE_DSN  = 3;         // Remove data source

  ODBC_ADD_SYS_DSN    = 4;          // add a system DSN
  ODBC_CONFIG_SYS_DSN   = 5;        // Configure a system DSN
  ODBC_REMOVE_SYS_DSN   = 6;        // remove a system DSN
  ODBC_REMOVE_DEFAULT_DSN   = 7;    // remove the default DSN

function SQLConfigDataSource (
    hwndParent:     SQLHWnd;
    fRequest:       WORD;
    lpszDriver:     PChar;
    lpszAttributes: PChar
  ): SQLBOOL; {$IFDEF MSWINDOWS} stdcall {$ELSE} cdecl {$ENDIF};
  external 'odbccp32.dll' name 'SQLConfigDataSourceW';

function SQLInstallerError (
    iError:           WORD;
    pfErrorCode:      PUDword;
    lpszErrorMsg:     PChar;
    cbErrorMsgMax:    WORD;
    pcbErrorMsg:      PWORD
  ): SQLReturn; {$IFDEF MSWINDOWS} stdcall {$ELSE} cdecl {$ENDIF};
  external 'odbccp32.dll' name 'SQLInstallerErrorW';

procedure TForm616.Button1Click(Sender: TObject);
var
  strAttributes: string;
  pfErrorCode: UDword;
  errMsg: PChar;
begin
  strAttributes := 'DSN=' + 'example_DSN' + Chr(0);
  strAttributes := strAttributes + 'DESCRIPTION=' + 'description' + Chr(0);
  strAttributes := strAttributes + 'SERVER=' + 'testserver' + Chr(0);
  strAttributes := strAttributes + 'DATABASE=' + 'somedatabase' + Chr(0);
  if not SqlConfigDataSource(0, ODBC_ADD_DSN, 'SQL Server', PChar(strAttributes)) then begin
    errMsg := AllocMem(SQL_MAX_MESSAGE_LENGTH);
    SQLInstallerError(1, @pfErrorCode, errMsg, SQL_MAX_MESSAGE_LENGTH, nil);
    MessageBox(0, errMsg, PChar('Add System DSN Error #' + IntToStr(pfErrorCode)), 0);
    FreeMem(errMsg);
  end;
end;
1 голос
/ 12 августа 2016

Ответ правильный, но я должен сделать пометку.

Если вы не устанавливаете тестовый сервер с портом, окна помечают «ODBC SQL SERVER DRIVER DBNETLIB« Неверное соединение »» Он создает драйвер и подключается, но каждый раз отправляет эту ошибку, если вы не настроили тестовый сервер как:

TestServer, порт '

strAttributes := strAttributes + 'SERVER=' + 'testserver,port' + Chr(0);

Это даст лучший ответ, потому что это позволит избежать отправки этой ошибки.

0 голосов
/ 01 февраля 2019

для Delphi7 http://www.delphigroups.info/2/0b/29040.html

  function SQLConfigDataSource( 
      hwndParent: HWND; 
      fRequest: WORD; 
      lpszDriver: LPCSTR; 
      lpszAttributes: LPCSTR): BOOL; stdcall; external 'ODBCCP32.DLL';
...