XSLT: если проверить значение параметра

Question

Следующий код в xslt (я вырезал ненужные части, get-textblock намного длиннее и имеет много параметров, которые все передаются правильно):

<xsl:template name="get-textblock">
        <xsl:param name="style"/>

        <xsl:element name="Border">         
            <xsl:if test="$style='{StaticResource LabelText}'" >
                <xsl:attribute name="Background">#FF3B596E</xsl:attribute>
            </xsl:if>
            <xsl:attribute name="Background">#FF3B5940</xsl:attribute>              
        </xsl:element>

</xsl:template>

Параметром стиля может быть либо «{StaticResource LabelText}», либо «{StaticResource ValueText}», и фон границы зависит от этого значения.

Однако, если структура терпит неудачу, она всегда рисует границу FF3B5940 в моем файле output.xaml. Я называю шаблон так:

<xsl:call-template name="get-textblock">
    <xsl:with-param name="style">{StaticResource LabelText}</xsl:with-param>                    
</xsl:call-template>

Кто-нибудь видит, в чем может быть проблема? Спасибо.

Answer 1

Строка:

<xsl:attribute name="Background">#FF3B5940</xsl:attribute>

не защищена условной проверкой, поэтому она всегда будет выполняться.

Используйте это:

<xsl:if test="$style='{StaticResource LabelText}'">
    <xsl:attribute name="Background">#FF3B596E</xsl:attribute>
</xsl:if>
<xsl:if test="not($style='{StaticResource LabelText}')">
    <xsl:attribute name="Background">#FF3B5940</xsl:attribute>
</xsl:if>

Или xsl:choose

<xsl:choose>
    <xsl:when test="$style='{StaticResource LabelText}'">
        <xsl:attribute name="Background">#FF3B596E</xsl:attribute>
    </xsl:when>
    <xsl:otherwise>
        <xsl:attribute name="Background">#FF3B5940</xsl:attribute>
    </xsl:otherwise>
</xsl:choose>

Answer 2

Если вы используете <xsl:attribute/> несколько раз в контексте одного элемента, только последний будет применен к элементу результата.

Вы можете разделить <xsl:attribute/> инструкции, используя <xsl:choose/> или определить одну <xsl:attribute/> перед <xsl:if/> - она ​​будет использоваться по умолчанию:

<xsl:choose>
    <xsl:when test="$style='{StaticResource LabelText}'">
        <xsl:attribute name="Background">#FF3B596E</xsl:attribute>
    </xsl:when>
    <xsl:otherwise>
        <xsl:attribute name="Background">#FF3B5940</xsl:attribute>
    </xsl:otherwise>
</xsl:choose>

или

        <xsl:attribute name="Background">#FF3B5940</xsl:attribute>  
        <xsl:if test="$style='{StaticResource LabelText}'" >
            <xsl:attribute name="Background">#FF3B596E</xsl:attribute>
        </xsl:if>

Answer 3

В XSLT 2.0:

<xsl:template name="get-textblock">
   <xsl:param name="style"/>   
   <Border Background="{if ($style='{StaticResource LabelText}') 
                        then '#FF3B596E' 
                        else '#FF3B5940'}"/>         

</xsl:template>