Grails - findAll Посты, созданные сегодня пользователем

Question

У меня есть объект домена.

class Post {
  User user
  String subject
  String body
  Date dateCreated
}

Как мне это сделать? Является ли прямой GORM, HQL или критерии лучшим способом? Я не знал, какие манипуляции с датами («сегодня eq») будут работать в критериях.

Answer 1

Я бы, вероятно, сделал именованный запрос

class Post {
  User user
  String subject
  String body
  Date dateCreated

     static namedQueries = {
       todaysPosts {
          def now = new Date().clearTime()
          between('dateCreated', now, now+1)
       }
   }
}

Тогда вы можете использовать его как:

Post.todaysPosts.count()

или

Post.todaysPosts.list()
Post.todaysPosts.list(max: 10, offset: 5)

, который вы можете даже сделать

Post.todaysPosts.findAllByUser(user)

Здесь больше по именованным запросам

Answer 2

Вот пример критерия:

// assuming future posts are disallowed
def posts = Post.withCriteria {
    eq('user', user)
    ge('dateCreated', new Date().clearTime())
}

// if you must accommodate future posts
def today = new Date().clearTime()
def posts = Post.withCriteria {
    eq('user', user)
    ge('dateCreated', today)
    lt('dateCreated', today.plus(1))
}

Answer 3

Я бы использовал Grails Dynamic Finders для этого:

Post.findAllByUserAndDateCreatedGreaterThanEquals(currentUser, new Date().clearTime())

Где "currentUser" - это экземпляр текущего пользователя

Answer 4

Для полноты изложения этот запрос написан на HQL:

def yourUser = User.get(1)
def results = Post.executeQuery( "select * from Post a where a.user = :user and a.dateCreated >= :dateCreated", [user : yourUser , dateCreated : new Date().clearTime()] );

@ Tyndall: на этот вопрос есть много ответов, просто выберите тот, который вам удобнее.

Answer 5

String sqlQuery = "SELECT * FROM Post p WHERE p.dateCreated  = NOW()"
def e = Post.executeQuery(sqlQuery)