XSLT: как разделить исключенные значения на уникальные элементы

Question

Я работаю в базе данных, которая на самом деле не поддерживает субэлементы. Чтобы обойти это, мы использовали волнистые скобки }} в строке значений, чтобы указать разделение между подэлементами. Когда мы экспортируем в xml, это выглядит примерно так:

<geographicSubject>
   <data>Mexico }} tgn }} 123456</data>
   <data>Mexico City }} tgn }} 7891011</data>
   <data>Main Street }} tgn }} 654321</data>
</geographicSubject>

Мой вопрос: как мне создать наш XSLT, чтобы он разбивал строки в <data> на отдельные подэлементы с уникальными именами, например:

<data>
   <location>Mexico</location>
   <source>tgn</source>
   <id>123456</id>
</data>

Первый }} указывает на начало «источника», второй }} указывает на начало «id». Спасибо всем, кто хочет помочь!

Answer 1

Составьте токенизатор:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:e="http://localhost">
    <e:e>location</e:e>
    <e:e>source</e:e>
    <e:e>id</e:e>
    <xsl:variable name="vElement" select="document('')/*/e:*"/>
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="data/text()" name="tokenizer">
        <xsl:param name="pString" select="string()"/>
        <xsl:param name="pPosition" select="1"/>
        <xsl:if test="$pString">
            <xsl:element name="{$vElement[$pPosition]}">
                <xsl:value-of
                 select="normalize-space(
                            substring-before(concat($pString,'}}'),'}}')
                         )"/>
            </xsl:element>
            <xsl:call-template name="tokenizer">
                <xsl:with-param name="pString"
                                select="substring-after($pString,'}}')"/>
                <xsl:with-param name="pPosition" select="$pPosition + 1"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Выход:

<geographicSubject>
    <data>
        <location>Mexico</location>
        <source>tgn</source>
        <id>123456</id>
    </data>
    <data>
        <location>Mexico City</location>
        <source>tgn</source>
        <id>7891011</id>
    </data>
    <data>
        <location>Main Street</location>
        <source>tgn</source>
        <id>654321</id>
    </data>
</geographicSubject>