Как использовать hsc2hs для привязки к константам, функциям и структурам данных? - PullRequest
Новая
       47

Как использовать hsc2hs для привязки к константам, функциям и структурам данных?

8 голосов
/ 19 мая 2011

Мне нужен пример, как использовать hsc2hs, я подумал, что когда я пишу файл заголовка, например: 

// foo.h
#define PI 3.14159

typedef struct {
    int i1;
    int i2;
} foo;

struct foo2 {
    int i1;
    int i2;
};

int fooFkt(foo f);

, а затем создаю файл hsc, например: 

import Foreign
import Foreign.C

#include "foo.h"

usehsc2hs: 

{-# INCLUDE "foo.h" #-}
{-# LINE 1 "test.hsc" #-}
import Foreign
{-# LINE 2 "test.hsc" #-}
import Foreign.C


{-# LINE 5 "test.hsc" #-}

Я не понимаю этого, я думал, что hsc2hs импортирует все необходимые мне вещи, как PI

, кто может дать мне лучший пример?

Ответы [ 2 ]

9 голосов
/ 19 мая 2011

После RWH ch 17 вам нужно ввести нечто, связывающее значение C PI с символом в Haskell.

Например: 

{-# LANGUAGE ForeignFunctionInterface #-}
{-# LANGUAGE CPP                      #-}

import Foreign
import Foreign.C

-- helpers
import Control.Applicative
import Control.Monad

#include "foo.h"

-- binding a symbol

-- Note that hsc2hs can't marshal floating point CPP values, so this will be "3"
-- c_pi :: CInt
-- c_pi = #const PI

-- Instead, bind to a function that returns a CFloat
pi' :: Float
pi' = realToFrac c_pi

foreign import ccall unsafe "my_pi" c_pi :: CFloat

И пока мы здесь, мы также можем упорядочить структуру в и из Хаскелла: 

-- Marshalling for the struct foo

data Foo = Foo { i1, i2 :: Int }
    deriving Show

-- Define how to marshal foo structs

instance Storable Foo where
    sizeOf    _ = #{size foo}

    alignment _ = alignment (undefined :: CInt)

    poke p foo  = do
        #{poke foo, i1} p $ i1 foo
        #{poke foo, i2} p $ i2 foo

    peek p = return Foo
              `ap` (#{peek foo, i1} p)
              `ap` (#{peek foo, i2} p)

И привязка к fooFkt функции: 

-- Import the function too

foreign import ccall "foo.h fooFkt"
    c_fooFkt :: Ptr Foo -> IO CInt

-- Marshal data to and from C

fooFkt :: Foo -> IO Int
fooFkt f = fromIntegral <$> with f c_fooFkt

Готово.

2 голосов
/ 19 мая 2011

Это работает, если вы действительно используете некоторые определения из foo.h: 

import Foreign
import Foreign.C

#include "foo.h"

pi = #const PI

дает 

{-# INCLUDE "foo.h" #-}
{-# LINE 1 "test.hsc" #-}
import Foreign
{-# LINE 2 "test.hsc" #-}
import Foreign.C


{-# LINE 5 "test.hsc" #-}

pi = 3
{-# LINE 7 "test.hsc" #-}

Вот пример реального использования сетевого пакета: https://github.com/haskell/network/blob/master/Network/Socket/ByteString/MsgHdr.hsc

...