Как объявить и перебрать массив в XSLT?

Question

Мое требование - использование XSLT- для отображения выпадающего списка со штатами США и print 'selected' для одного конкретного объекта, который объявлен в XML, который будет использовать мою таблицу стилей.

Я думал о том, чтобы объявить массив с состояниями и повторить его, но я не знаю, как это сделать.

ПРИМЕЧАНИЕ: больше идей приветствуются;)

Answer 1

Один из способов сделать это - встроить данные состояния в саму таблицу стилей и получить доступ к документу таблицы стилей с помощью document(''), как показано ниже:

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:my="whatever"
  exclude-result-prefixes="my">

  <xsl:output indent="yes"/>

  <!-- The value of the state you want to select, supplied in the input XML -->
  <xsl:variable name="selected-state" select="/xpath/to/state/value"/>

  <!-- You have to use a namespace, or the XSLT processor will complain -->
  <my:states>
    <option>Alabama</option>
    <option>Alaska</option>
    <!-- ... -->
    <option>Wisconsin</option>
    <option>Wyoming</option>
  </my:states>

  <xsl:template match="/">
    <!-- rest of HTML -->
    <select name="state">
      <!-- Access the embedded document as an internal "config" file -->
      <xsl:apply-templates select="document('')/*/my:states/option"/>
    </select>
    <!-- rest of HTML -->
  </xsl:template>

          <!-- Copy each option -->
          <xsl:template match="option">
            <xsl:copy>
              <!-- Add selected="selected" if this is the one -->
              <xsl:if test=". = $selected-state">
                <xsl:attribute name="selected">selected</xsl:attribute>
              </xsl:if>
              <xsl:value-of select="."/>
            </xsl:copy>
          </xsl:template>

</xsl:stylesheet>

Дайте мне знать, если у вас есть какие-либо вопросы.

Answer 2

В идеале вы должны хранить список состояний в вашем XML-файле и просто использовать XSLT для их итерации.

Обновление: Если вы не можете редактировать XML, вы можете использовать функцию документа для загрузки данных из второго файла данных: