Ограничение числа токенов в команде FOR в пакетном скрипте Windows

Question

Я пытался обработать текстовый файл в пакетном скрипте Windows, и натолкнулся на что-то, что выглядит как ограничение до 31 токена в цикле FOR. Я выделил проблему в коде ниже:

@ECHO OFF
SET DATA=01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35

FOR /F "tokens=31* delims= " %%i IN ("%DATA%") DO (
    ECHO [%%i]
    ECHO [%%j]
)
ECHO.
FOR /F "tokens=32* delims= " %%i IN ("%DATA%") DO (
    ECHO [%%i]
    ECHO [%%j]
)

Вывод:

[31]
[32 33 34 35]

[01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35]
[%j]

и я ожидал этого:

[31]
[32 33 34 35]

[32]
[33 34 35]

Надеясь, что я не сделал что-то не так, я не смог найти это ограничение, документированное в справке для команды FOR. Я использую Windows XP. Знаете ли вы какой-нибудь обходной путь для этого, кроме обрезания частей данных?

Спасибо.

Answer 1

Я придумал решение. Это не элегантно, но решает мою проблему. Когда интерпретатор строки команды не может идти дальше с токенами, я передаю обработку данных команде CALL: label Вот пример:

@ECHO OFF

SET DATA=01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100

FOR /F "tokens=1,31* delims= " %%i IN ("%DATA%") DO (
    ECHO  1st token: %%i
    ECHO 31th token: %%j
    CALL :processdatatokens32-62 %%k
)

:processdatatokens32-62
SET DATA=%*
FOR /F "tokens=1,31* delims= " %%i IN ("%DATA%") DO (
    ECHO 32nd token: %%i
    ECHO 62th token: %%j
    CALL :processdatatokens63-83 %%k
)
GOTO :EOF

:processdatatokens63-83
SET DATA=%*
FOR /F "tokens=1,31* delims= " %%i IN ("%DATA%") DO (
    ECHO 63th token: %%i
    ECHO 93th token: %%j
)
GOTO :EOF

Вывод:

 1st token: 01
31th token: 31
32nd token: 32
62th token: 62
63th token: 63
93th token: 93

Answer 2

С for /?:

% я явно объявлен в заявление и% J и% K являются неявно объявлено через токены = вариант. Вы можете указать до 26 токены через линию токенов = при условии это не вызывает попытки объявить переменную выше, чем буква «z» или «Z». Помните, ЗА переменные состоят из одной буквы, регистр чувствительный, глобальный, и вы не можете иметь более 52 активных время.

Answer 3

Я создал функцию пишущей машинки для партии (просто для удовольствия) и также столкнулся с этим ограничением. Ниже урезанная версия, чтобы показать вам, как я решил проблему. Вы можете использовать до 8191 символа, включая разделители пробелов при выполнении из командной строки. При использовании переменной максимальная длина составляет 32 767.

@echo off
::#############################################################################
 :_typeWriter <stringVariable> <skipLinefeed>
::#############################################################################
::
:: Copyleft Denny Lenselink 2018
::

%= Set local environment =%
( call ) & 2>nul setlocal EnableDelayedExpansion || exit /b 99

:: Set vars
set "_CNT=0" && set "_LEN=0" && set "_STR= %~1" && set "_TOT=0"

:_typeWriter_Loop
set /a "_CNT+=1"

:: 31 tokens limit fix. Cut the used part of the string and set counter to 1
if !_CNT! equ 32 ( set "_CNT=1" && set "_STR=!_STR:~%_TOT%!" && set "_TOT=0" )

:: Go through string (seeking words)
for /f "tokens=%_CNT% delims= " %%* in ( "%_STR%" ) do (

    :: Set word var
    set "_WRD=#%%*"

    :: Calculate word length
    for /l %%I in ( 12, -1, 0 ) do (

        set /a "_LEN|=1<<%%I"

        for %%J in ( !_LEN! ) do ( if "!_WRD:~%%J,1!"=="" set /a "_LEN&=~1<<%%I" )
    )

    :: Strip first char (used before to calculate correct word length)
    set "_WRD=!_WRD:~1!"

    :: Count chars including spaces
    set /a "_TOT=!_TOT!+!_LEN!+1"

    :: Type word or use echo
    <nul set /p "=!_WRD! "

    :: Do a loop
    goto _typeWriter_Loop
)

:: No linefeed when specified
if "%~2"=="" echo.

endlocal
exit /b

Выполнить: C: \ Temp> typewriter "this is a test that works"

Результат:

this is a test that works

Изменение строки <nul set /p "=!_WRD! " на echo !_WRD! приведет к:

this
is
a
test
that
works

Answer 4

Существует несколько способов перебрать массив DATA:

@ECHO OFF
setlocal ENABLEDELAYEDEXPANSION
SET DATA=01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101

for /l %%a in (0,3,150) do @echo %%a data: !data:~%%a,2!

Это возможно только из-за двухсимвольных переменных в массиве% DATA%. Как вы увидите, ограничение теперь составляет 99 символов, а не 31. Когда вы добираетесь до 100-го и выше, число усекается.

Rob

Answer 5

Токен - это наименьшая единица синтаксиса, которая считается одним чанком. И командная строка Batch в Windows 95/98 / ME имеет максимальный лимит 64 токенов. Больше, и командная строка выдаст ошибку Bad command or file name.

, поэтому в DATA вы, вероятно, ограничены 31.