Получить идентификатор таблицы после вставки с ColdFusion и MySQL

Question

Мой обычный процесс вставки в одну таблицу и последующего получения идентификатора, чтобы я мог вставить ее в другую таблицу, похож на MSSQL:

DECLARE @transactionKey uniqueidentifier
SET @transactionKey = NEWID()

INSERT INTO transactions(transactionKey, transactionDate, transactionAmount)
    VALUES(@transactionKey, '#transactionDate#', '#transactionAmount#')

DECLARE @transactionID int
SELECT @transactionID = transactionID
    FROM transactions
    WHERE transactionKey = @transactionKey


INSERT INTO transactionItems(transactionID, itemID, itemAmount)
    VALUES(@transactionID, '#itemID#', '#itemAmount#')


SELECT @transactionID as transactionID

Мой вопрос состоит из 2 частей. Во-первых, это лучший способ сделать это? Я прочитал, что есть вероятность, что GUID изменится на меня, и я получаю неправильный GUID во второй таблице. Я предполагаю, что шансы на это очень малы, и я занимался этим в течение многих лет в различных проектах и ​​никогда не имел проблем.

Вторая часть моего вопроса: работает ли что-то подобное в MySQL? Я начинаю работать над новым проектом с использованием MySQL, и я не совсем уверен, лучший способ сделать это. Обычно я работал только над MSSQL в прошлом.

Я использую CF9 и MySQL в этом новом проекте.

Любая помощь в этом была бы великолепна.

Заранее спасибо.

Answer 1

Часть 1: Лично я бы не собирал несколько операторов в одном запросе, чтобы снизить риск внедрения SQL-кода.Это параметр в вашем источнике данных для администратора ColdFusion.Выполнение хранимой процедуры, которая может быть тем, чем вы занимаетесь (?), Это еще одна история, но вам следует перефразировать ваш вопрос в «Получить первичный ключ после вставки с помощью хранимой процедуры MySQL», если это ваше намерение.

Часть 2: ColdFusion, как и многие другие вещи, делает получение первичного ключа для вновь вставленной записи очень простым - даже если вы используете ключи автоинкремента, GUID или что-то вроде Oracle ROWNUM.Это будет работать практически с любой базой данных, поддерживаемой Adobe ColdFusion, включая MSSQL или MySQL.Единственным исключением является версия базы данных - например, MySQL 3 не будет поддерживать это;однако MySQL 4+ будет.

<cfquery result="result">
  INSERT INTO myTable (
      title
  ) VALUES (
    <cfqueryparam value="Nice feature!" cfsqltype="cf_sql_varchar">
  )
</cfquery>

<--- get the primary key of the inserted record --->
<cfset NewPrimaryKey = result.generatedkey>

Начиная с CF9 +, вы можете получить доступ к новому идентификатору (для любой базы данных), используя имя общего ключа:

result.GENERATEDKEY    // All databases

Для CF8, другойбазы данных будут иметь разные ключи в пределах значения результатов.Вот простая таблица, которую я помог скопировать из документации cfquery .

result.identitycol    // MSSQL
result.rowid          // Oracle
result.sys_identity   // Sybase
result.serial_col     // Informix
result.generated_key  // MySQL

Если у вас есть какие-либо вопросы, вы можете увидеть симпатичный дамп следующим образом:

<cfdump var="#result#" />

Answer 2

Согласно ответу @ aaron-greenlee, переменная результата запросов INSERT содержит пару ключ-значение, которая является автоматически генерируемым идентификатором вставленной строки; доступно только для баз данных, поддерживающих эту функцию.

А ниже приведен возможный способ вернуть вставленную запись для всех баз данных.

<cfquery result="result">
   INSERT INTO myTable (
      title
   )
   OUTPUT INSERTED.*
   VALUES (
   <cfqueryparam value="Nice feature!" cfsqltype="cf_sql_varchar">
   )
</cfquery>

В результате вы получите вставленные данные записи.

Надеюсь, это поможет. Спасибо.

Answer 3

Вот быстрое решение для MSSQL.Он использует функцию SCOPE_IDENTITY (), которая возвращает идентификатор последней строки, вставленной в предыдущий оператор вставки.

http://msdn.microsoft.com/en-us/library/ms190315.aspx

<cfquery>
    DECLARE @iNewGeneratedID INT

    INSERT INTO transactions
        (
            transactionDate,
            transactionAmount
        )
    VALUES
       (
            <cfqueryparam value="#transactionDate#" type="cf_sql_date">,
            <cfqueryparam value="#transactionAmount#" type="cf_sql_integer">
       )

    SET @iNewGeneratedID = SCOPE_IDENTITY()

    INSERT INTO transactionItems
        (
            transactionID,
            itemID,
            itemAmount
        )
    VALUES
        (
            @iNewGeneratedID,
           <cfqueryparam value="#itemID#" type="cf_sql_integer">,
           <cfqueryparam value="#itemAmount#" type="cf_sql_integer">
        )

    SELECT @iNewGeneratedID AS iNewGeneratedID
</cfquery>

Answer 4

Функция getGeneratedKey на cflib.org может использоваться с большинством баз данных:

Пример:

<cfquery name="insertArtist" datasource="cfartgallery" result="r">
    insert into artists (firstName, lastName)
    values('todd','sharp')
</cfquery>
<cfquery name="getArtists" datasource="cfartgallery">
    select *
    from   artists
</cfquery>
<cfdump var="#getArtists#">
<cfoutput>#getGeneratedKey(r)#</cfoutput>

<cffunction name="getGeneratedKey" 
    hint="I normalize the key returned from cfquery" output="false">

      <cfargument name="resultStruct" hint="the result struct returned from cfquery" />
      <cfif structKeyExists(arguments.resultStruct, "IDENTITYCOL")>
          <cfreturn arguments.resultStruct.IDENTITYCOL />
      <cfelseif structKeyExists(arguments.resultStruct, "ROWID")>
          <cfreturn arguments.resultStruct.ROWID />
      <cfelseif structKeyExists(arguments.resultStruct, "SYB_IDENTITY")>
          <cfreturn arguments.resultStruct.SYB_IDENTITY />
      <cfelseif structKeyExists(arguments.resultStruct, "SERIAL_COL")>
          <cfreturn arguments.resultStruct.SERIAL_COL />  
      <cfelseif structKeyExists(arguments.resultStruct, "GENERATED_KEY")>
          <cfreturn arguments.resultStruct.GENERATED_KEY />
      <cfelse>
          <cfreturn />
      </cfif>
</cffunction>