выборочная печать между регулярными выражениями

Question

Мне нужно перехватить CSV-часть текстового файла из REGEXP до второй пустой строки.Пример ниже:

garbage garbage
garbage garbage
garbage garbage

REGEXP

data,data,data
data,data,data

garbage garbage
garbage garbage
garbage garbage

Будем весьма благодарны за любые идеи, как это сделать в sed или perl.

Answer 1

perl -00 -ne 'print, print(scalar <>), exit if /REGEXP/' file.txt

Answer 2

perl -ne '$on=1 if /REGEXP/; if ($on) { print; $blank++ if /^\s*$/; last if $blank == 2 }' file.csv

Будет отображаться:

    REGEXP

data,data,data
data,data,data

Если вы не хотите отображать REGEXP:

perl -ne '$on=1 and next if /REGEXP/; if ($on) { print; $blank++ if /^\s*$/; last if $blank == 2 }' file.csv

Answer 3

Использование разделителя ввода записей для захвата блоков, заканчивающихся двойными символами новой строки.Это только печатает раздел данных.Если вы хотите распечатать часть REGEXP, раскомментируйте say;

$/ = "";
while (<>) {
    next unless /^REGEXP/;
    #say;  # Uncomment to print header
    chomp($_ = <>);
    say;
}

Answer 4

Примерно так:

#!/usr/bin/perl

use warnings; use strict;

while (<DATA>) {
    /^REGEXP/ and last;
}

my $csv_line;

while ($csv_line = <DATA>) {
    $csv_line =~ /,/ and last;
}

while (defined($csv_line) and $csv_line =~ /\S/) {
    process_csv($csv_line);
    $csv_line = <DATA>;
}

sub process_csv {
    my ($line) = @_;
    print $line;
}


__DATA__
garbage garbage
garbage garbage
garbage garbage

REGEXP

data,data,data
data,data,data

garbage garbage
garbage garbage
garbage garbage